对象可见性

void OnStart()
  {
//---
   string highlevel="PreviousDayHigh";
   string lowlevel="PreviousDayLow";
   double prevHigh;           // 前一天最高价
   double prevLow;            // 前一天最低价
   double highs[],lows[];     // 最高和最低价数组
 
//--- 重置上一个错误
   ResetLastError();
//--- 获得日常时间表最近的2个最高值
   int highsgot=CopyHigh(Symbol(),PERIOD_D1,0,2,highs);
   if(highsgot>0) // 如果复制成功
     {
      Print("High prices for the last 2 days were obtained successfully");
      prevHigh=highs[0]; // 前一天最高价
      Print("prevHigh = ",prevHigh);
      if(ObjectFind(0,highlevel)<0) // 没有找到名为highlevel物件
        {
         ObjectCreate(0,highlevel,OBJ_HLINE,0,0,0); // 创建水平线物件
        }
      //--- 为高位线价格平面设置值
      ObjectSetDouble(0,highlevel,OBJPROP_PRICE,0,prevHigh);
      //--- 仅设置PERIOD_M10和PERIOD_H4的可见性
      ObjectSetInteger(0,highlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else
     {
      Print("Could not get High prices over the past 2 days, Error = ",GetLastError());
     }
 
//--- 重置上一个错误
   ResetLastError();
//--- 获得日常时间表最近的2个最低值
   int lowsgot=CopyLow(Symbol(),PERIOD_D1,0,2,lows);
   if(lowsgot>0) // 如果复制成功
     {
      Print("Low prices for the last 2 days were obtained successfully");
      prevLow=lows[0]; // 前一天最低价
      Print("prevLow = ",prevLow);
      if(ObjectFind(0,lowlevel)<0) // 没有找到名为lowlevel物件
        {
         ObjectCreate(0,lowlevel,OBJ_HLINE,0,0,0); // 创建水平线物件
        }
      //--- 为低位线价格平面设置值
      ObjectSetDouble(0,lowlevel,OBJPROP_PRICE,0,prevLow);
      //--- 仅设置PERIOD_M10和PERIOD_H4的可见性
      ObjectSetInteger(0,lowlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else Print("Could not get Low prices for the last 2 days, Error = ",GetLastError());
 
   ChartRedraw(0); // 强制重画图表
  }