ДокументацияРазделы
Справочник MQL5Пользовательские индикаторыСтили индикаторов в примерахDRAW_COLOR_ARROW 

DRAW_COLOR_ARROW

Стиль DRAW_COLOR_ARROW рисует на графике цветом стрелки (символы из набора Wingdings) по значению индикаторного буфера. В отличие от стиля DRAW_ARROW, в нем можно для каждого символа задавать цвет из предопределенного набора цветов, задаваемых свойством indicator_color1.

Толщину и цвет символов можно задавать так же, как и для стиля DRAW_ARROW – директивами компилятора или динамически с помощью функции PlotIndexSetInteger(). Динамическое изменение свойств графического построения позволяет изменять вид индикатора в зависимости от  текущей ситуации.

Код символа для вывода на график задается с помощью свойства PLOT_ARROW.

//--- зададим код символа из шрифта Wingdings для отрисовки в PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,code);

По умолчанию значение PLOT_ARROW=159 (кружок).

Каждая стрелка фактически представляет собой символ, который имеет высоту и точку привязки, и может закрывать собою некоторую важную информацию на графике (например, цену закрытия на баре). Поэтому можно дополнительно  указать вертикальное смещение в пикселях, которое не зависит от масштаба графика. На это указанное количество пикселей стрелки будут визуально смещены по вертикали, хотя сами значения индикатора останутся те же самые:

//--- зададим cмещение стрелок по вертикали в пикселях
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);

Отрицательное значение PLOT_ARROW_SHIFT означает смещение стрелок вверх, положительно значения смещает стрелки вниз.

Стиль DRAW_COLOR_ARROW можно использовать как в отдельном подокне графика, так и в главном окне. Пустые значения не отрисовываются и не отображаются в "Окне данных", все значения в индикаторных буферах нужно устанавливать явным образом. Инициализация буферов пустым значением не производится.

//--- установим пустое значение
   PlotIndexSetDouble(индекс_построения_DRAW_COLOR_ARROW,PLOT_EMPTY_VALUE,0);

Количество требуемых буферов для построения DRAW_COLOR_ARROW — 2:

  • один буфер для хранения  значения цены, по которой рисуется символ (плюс смещение в пикселях, задаваемое свойством PLOT_ARROW_SHIFT);
  • один буфер для хранения индекса цвета, которым рисуется стрелка (имеет смысл задавать только для непустых значений).

Пример индикатора, рисующего стрелки на каждом баре, у которого цена закрытия Close больше цены закрытия предыдущего бара. Толщина, смещение и код символа всех стрелок меняются случайным образом каждые N тиков. Цвет символа зависит от номера бара, на котором он нарисован.

Пример стиля DRAW_COLOR_ARROW

В примере первоначально для графического построения plot1 со стилем DRAW_COLOR_ARROW свойства, цвет и размер задаются с помощью директивы компилятора #property, а затем в функции OnCalculate() свойства случайным образом меняются. Параметр N вынесен во внешние параметры индикатора для возможности ручной установки (закладка "Параметры" в окне свойств индикатора).

Обратите внимание, первоначально задается 8 цветов с помощью директивы компилятора #property, а затем в функции OnCalculate() цвет выбирается случайным образом из 14 цветов, хранящихся в массиве colors[].

//+------------------------------------------------------------------+
//|                                             DRAW_COLOR_ARROW.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Индикатор для демонстрации DRAW_COLOR_ARROW"
#property description "Рисует на графике разным цветом стрелки, задаваемые символами Unicode"
#property description "Цвет, размер, смещение и код символа стрелки меняется"
#property description " случайным образом через каждые N тиков"
#property description "Параметр code задает базовое значение: код=159 (кружок)"
 
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   1
//--- plot ColorArrow
#property indicator_label1  "ColorArrow"
#property indicator_type1   DRAW_COLOR_ARROW
//--- зададим 8 цветов для раскраски гистограммы (они хранятся в специальном массиве)
#property indicator_color1  clrRed,clrBlue,clrSeaGreen,clrGold,clrDarkOrange,clrMagenta,clrYellowGreen,clrChocolate
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
 
//--- input параметры
input int      N=5;         // кол-во тиков для изменения 
input ushort   code=159;    // код символа для отрисовки в DRAW_ARROW
int            color_sections;
//--- индикаторный буфер для построения 
double         ColorArrowBuffer[];
//--- буфер для хранения индексов цвета
double         ColorArrowColors[];
//--- массив для хранения цветов содержит 14 элементов
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
  };
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,ColorArrowBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,ColorArrowColors,INDICATOR_COLOR_INDEX);
//--- зададим код символа для отрисовки в PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,code);
//--- зададим cмещение стрелок по вертикали в пикселях 
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,5);
//--- установим в качестве пустого значения 0
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);   
//---- количество цветов для раскраски синусоиды
   color_sections=8;   //  см. комментарий к свойству #property indicator_color1 
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- считаем тики для изменения цвета, размера, смещения и кода стрелки
   ticks++;
//--- если накопилось критическое число тиков
   if(ticks>=N)
     {
      //--- меняем свойства стрелок
      ChangeLineAppearance();
      //--- меняем цвета, которыми рисуются гистограмма
      ChangeColors(colors,color_sections);
      //--- сбрасываем счетчик тиков в ноль
      ticks=0;
     }
 
//--- блок расчета значений индикатора
   int start=1;
   if(prev_calculated>0) start=prev_calculated-1;
//--- цикл расчета
   for(int i=1;i<rates_total;i++)
     {
      //--- если текущая цена Close больше предыдущей, ставим стрелку
      if(close[i]>close[i-1])
         ColorArrowBuffer[i]=close[i];
      //--- в противном случае указываем нулевое значение
      else
         ColorArrowBuffer[i]=0;
      //--- цвет стрелки
      int index=i%color_sections;
      ColorArrowColors[i]=index;
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Изменяет цвет участков линии                                     |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- количество цветов 
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- для каждого цветового индекса зададим новый цвет случайным образом
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- получим случайное число
      int number=MathRand();
      //--- получим индекс в массиве col[] как остаток от целочисленного деления
      int i=number%size;
      //--- установим цвет для каждого индекса как свойство PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  номер графического стиля
                          PLOT_LINE_COLOR,      //  идентификатор свойства
                          plot_color_ind,       //  индекс цвета, куда запишем цвет
                          cols[i]);             //  новый цвет
      //--- запишем цвета
      comm=comm+StringFormat("ArrowColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| Изменяет внешний вид отображаемой линии в индикаторе             |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- строка для формирования информации о свойствах линии
   string comm="";
//--- блок изменения толщины линии
   int number=MathRand();
//--- получим толщину как остаток от целочисленного деления
   int width=number%5; // толщина задается от о до 4
//--- установим цвет как свойство PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- запишем толщину линии
   comm=comm+" Width="+IntegerToString(width);
   
//--- блок изменения кода стрелки (PLOT_ARROW)
   number=MathRand();
//--- получим остаток от целочисленного деления для вычисления нового кода стрелки (от 0 до 19)
   int code_add=number%20;
//--- установим новый код символа как сумму code+code_add
   PlotIndexSetInteger(0,PLOT_ARROW,code+code_add);
//--- запишем код символа PLOT_ARROW
   comm="\r\n"+"PLOT_ARROW="+IntegerToString(code+code_add)+comm;   
 
//--- блок изменения смещения стрелок по вертикали в пикселях
   number=MathRand();
//--- получим смещение как остаток от целочисленного деления
   int shift=20-number%41;
//--- установим новое смещение
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);
//--- запишем смещение PLOT_ARROW_SHIFT
   comm="\r\n"+"PLOT_ARROW_SHIFT="+IntegerToString(shift)+comm;
 
//--- выведем информацию на график через комментарий
   Comment(comm);
  }