Скачать MetaTrader 5

DRAW_LINE

Стиль DRAW_LINE рисует заданным цветом линию по значениям индикаторного буфера. Толщину, цвет и стиль отображения линии можно задавать как директивами компилятора, так и динамически с помощью функции PlotIndexSetInteger(). Динамическое изменение свойств графического построения позволяет создавать "живые" индикаторы, которые меняют свой вид в зависимости от  текущей ситуации.

Количество требуемых буферов для построения DRAW_LINE — 1.

Пример индикатора, рисующего линию ценам закрытия баров Close. Цвет, толщина и стиль линии меняются случайным образом каждые N=5 тиков.

Пример стиля DRAW_LINE

Обратите внимание, первоначально для графического построения plot1 со стилем DRAW_LINE свойства задаются с помощью директивы компилятора #property, а затем в функции OnCalculate() эти три свойства задаются случайным образом. Параметр N вынесен во внешние параметры индикатора для возможности ручной установки (закладка "Параметры" в окне свойств индикатора).

//+------------------------------------------------------------------+
//|                                                    DRAW_LINE.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Индикатор для демонстрации DRAW_LINE"
#property description "Рисует линию заданным цветом по ценам Close"
#property description "Цвет, толщина и стиль линии меняется случайным образом"
#property description "через каждые N тиков"
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- свойства линии заданы с помощью директив компилятора
#property indicator_label1  "Line"      // название построения для "Окна данных"
#property indicator_type1   DRAW_LINE   // тип графического построения - линия
#property indicator_color1  clrRed      // цвет линии
#property indicator_style1  STYLE_SOLID // стиль линии
#property indicator_width1  1           // толщина линии
//--- input параметр
input int      N=5;         // кол-во тиков для изменения 
//--- индикаторный буфер для построения 
double         LineBuffer[];
//--- массив для хранения цветов
color colors[]={clrRed,clrBlue,clrGreen};
//--- массив для хранения стилей отрисовки линии
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- связывание массива и индикаторного буфера
   SetIndexBuffer(0,LineBuffer,INDICATOR_DATA);
//--- инициализация генератора псевдослучайных чисел
   MathSrand(GetTickCount());
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- считаем тики для изменения стиля, цвета и толщины линии
   ticks++;
//--- если накопилось критическое число тиков
   if(ticks>=N)
     {
      //--- меняем свойства линии
      ChangeLineAppearance();
      //--- сбрасываем счетчик тиков в ноль
      ticks=0;
     }
 
//--- блок расчета значений индикатора
   for(int i=0;i<rates_total;i++)
     {
      LineBuffer[i]=close[i];
     }
 
//--- вернем значение prev_calculated для следующего вызова функции
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Изменяет внешний вид отображаемой линии в индикаторе             |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- строка для формирования информации о свойствах линии
   string comm="";
//--- блок изменения цвета линии
//--- получим случайное число
   int number=MathRand();
//--- делитель числа равен размеру массива colors[]
   int size=ArraySize(colors);
//--- получим индекс для выбора нового цвета как остаток от целочисленного деления
   int color_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- запишем цвет линии
   comm=comm+(string)colors[color_index];
 
//--- блок изменения толщины линии
   number=MathRand();
//--- получим толщину как остаток от целочисленного деления
   int width=number%5; // толщина задается от о до 4
//--- установим цвет как свойство PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- запишем толщину линии
   comm=comm+", Width="+IntegerToString(width);
 
//--- блок изменения стиля линии
   number=MathRand();
//--- делитель числа равен размеру массива styles
   size=ArraySize(styles);
//--- получим индекс для выбора нового стиля как остаток от целочисленного деления
   int style_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- запишем стиль линии
   comm=EnumToString(styles[style_index])+", "+comm;
//--- выведем информацию на график через комментарий
   Comment(comm);
  }