Справочник MQL5Пользовательские индикаторыСтили индикаторов в примерахDRAW_COLOR_BARS

DRAW_COLOR_BARS

Стиль DRAW_COLOR_BARS рисует бары по значениям четырех индикаторных буферов, в которых содержатся цены Open, High, Low и Close. Этот стиль является продвинутой версией стиля DRAW_BARS и позволяет задавать для каждого бара свой цвет из заранее предопределенного набора цветов. Предназначен для создания собственных индикаторов в виде баров, в том числе в отдельном подокне графика и по другим финансовым инструментам.

Цвет баров можно задавать директивами компилятора или динамически с помощью функции PlotIndexSetInteger(). Динамическое изменение свойств графического построения позволяет "оживить" индикаторы, чтобы они меняли свой вид в зависимости от текущей ситуации.

Индикатор рисуется только для тех баров, для которых заданы непустые значения всех четырех индикаторных буферов. Чтобы указать, какое значение следует считать "пустым", установите это значение в свойстве PLOT_EMPTY_VALUE:

//--- значение 0 (пустое значение) не будет участвовать в отрисовке
PlotIndexSetDouble(индекс_построения_DRAW_COLOR_BARS,PLOT_EMPTY_VALUE,0);

Всегда явно заполняйте значениями индикаторные буферы, на пропускаемых барах указывайте в буфере пустое значение.

Количество требуемых буферов для построения DRAW_COLOR_BARS — 5:

четыре буфера для хранения значений Open, High, Low и Close;
один буфер для хранения индекса цвета, которым рисуется бар (имеет смысл задавать только отрисовываемых баров).

Все буферы для построения должны идти последовательно один за другим в заданном порядке: Open, High, Low, Close и буфер цвета. Ни один из ценовых буферов не может содержать только пустые значения, так как в этом случае отрисовка не происходит.

Пример индикатора, рисующего в отдельном окне бары по указанному финансовому инструменту. Цвет баров меняется случайным образом каждые N тиков. Параметр N вынесен во внешние параметры индикатора для возможности ручной установки (закладка "Параметры" в окне свойств индикатора).

Пример стиля DRAW_COLOR_BARS

Обратите внимание, первоначально для графического построения plot1 со стилем DRAW_COLOR_BARS задается 8 цветов с помощью директивы компилятора #property, а затем в функции OnCalculate() цвет выбирается случайным образом из 14 цветов, хранящихся в массиве colors[].

//+------------------------------------------------------------------+
//|                                              DRAW_COLOR_BARS.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#property description "Индикатор для демонстрации DRAW_COLOR_BARS"
#property description "Рисует в отдельном окне разным цветом бары по выбранному символу"
#property description "Цвет и толщина баров, а также символ, меняются случайным "
#property description "образом через каждые N тиков"

#property indicator_separate_window
#property indicator_buffers 5
#property indicator_plots   1
//--- plot ColorBars
#property indicator_label1  "ColorBars"
#property indicator_type1   DRAW_COLOR_BARS
//--- зададим 8 цветов для раскраски баров (они хранятся в специальном массиве)
#property indicator_color1  clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- input параметры
input int      N=5;              // количество тиков для смены вида
input int      bars=500;         // сколько баров показывать
input bool     messages=false;   // вывод сообщений в лог "Эксперты"
//--- индикаторные буферы
double         ColorBarsBuffer1[];
double         ColorBarsBuffer2[];
double         ColorBarsBuffer3[];
double         ColorBarsBuffer4[];
double         ColorBarsColors[];
//--- имя символа
string symbol;
int    bars_colors;
//--- массив для хранения цветов содержит 14 элементов
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrMagenta,clrCyan,clrMediumPurple
  };
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,ColorBarsBuffer1,INDICATOR_DATA);
   SetIndexBuffer(1,ColorBarsBuffer2,INDICATOR_DATA);
   SetIndexBuffer(2,ColorBarsBuffer3,INDICATOR_DATA);
   SetIndexBuffer(3,ColorBarsBuffer4,INDICATOR_DATA);
   SetIndexBuffer(4,ColorBarsColors,INDICATOR_COLOR_INDEX);
//---- количество цветов для раскраски баров
   bars_colors=8;   //  см. комментарий к свойству #property indicator_color1
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- считаем тики для изменения стиля, цвета и толщины бара
   ticks++;
//--- если накопилось достаточное число тиков
   if(ticks>=N)
     {
      //--- выберем новый символ из окна "Обзор рынка"
      symbol=GetRandomSymbolName();
      //--- меняем свойства линии
      ChangeLineAppearance();
      //--- меняем цвета, которыми рисуются бары
      ChangeColors(colors,bars_colors);
      int tries=0;
      //--- сделаем 5 попыток заполнить буферы ценами из symbol
      while(!CopyFromSymbolToBuffers(symbol,rates_total,bars_colors) && tries<5)
        {
         //--- счетчик вызовов функции CopyFromSymbolToBuffers()
         tries++;
        }
      //--- сбрасываем счетчик тиков в ноль
      ticks=0;
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Заполняем индикаторные буферы ценами                             |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,int total,int bar_colors)
  {
//--- в массив rates[] будем копировать цены Open, High, Low и Close
   MqlRates rates[];
//--- счетчик попыток
   int attempts=0;
//--- сколько скопировано
   int copied=0;
//--- делаем 25 попыток получить таймсерию по нужному символу
   while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
     {
      Sleep(100);
      attempts++;
      if(messages) PrintFormat("%s CopyRates(%s) attempts=%d",__FUNCTION__,name,attempts);
     }
//--- если не удалось скопировать достаточное количество баров
   if(copied!=bars)
     {
      //--- сформируем строку сообщения
      string comm=StringFormat("Для символа %s удалось получить только %d баров из %d затребованных",
                               name,
                               copied,
                               bars
                               );
      //--- выведем сообщение в комментарий на главное окно графика
      Comment(comm);
      //--- выводим сообщения
      if(messages) Print(comm);
      return(false);
     }
   else
     {
      //--- установим отображение символа
      PlotIndexSetString(0,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
      IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_COLOR_BARS("+name+")");
     }
//--- инициализируем буферы пустыми значениями
   ArrayInitialize(ColorBarsBuffer1,0.0);
   ArrayInitialize(ColorBarsBuffer2,0.0);
   ArrayInitialize(ColorBarsBuffer3,0.0);
   ArrayInitialize(ColorBarsBuffer4,0.0);

//--- копируем цены в буферы
   for(int i=0;i<copied;i++)
     {
      //--- вычислим соответствующий индекс для буферов
      int buffer_index=total-copied+i;
      //--- записываем цены в буферы
      ColorBarsBuffer1[buffer_index]=rates[i].open;
      ColorBarsBuffer2[buffer_index]=rates[i].high;
      ColorBarsBuffer3[buffer_index]=rates[i].low;
      ColorBarsBuffer4[buffer_index]=rates[i].close;
      //---
      ColorBarsColors[buffer_index]=i%bar_colors;
     }
   return(true);
  }
//+------------------------------------------------------------------+
//| Возвращает случайным образом символ из Market Watch              |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
  {
//--- количество символов, показываемых в окне "Обзор рынка"
   int symbols=SymbolsTotal(true);
//--- позиция символа в списке - случайное число от 0 до symbols
   int number=MathRand()%symbols;
//--- вернем имя символа по указанной позиции
   return SymbolName(number,true);
  }
//+------------------------------------------------------------------+
//| Изменяет цвет отрезков зигзага                                   |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- количество цветов
   int size=ArraySize(cols);
//---
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";

//--- для каждого цветового индекса зададим новый цвет случайным образом
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- получим случайное число
      int number=MathRand();
      //--- получим индекс в массиве col[] как остаток от целочисленного деления
      int i=number%size;
      //--- установим цвет для каждого индекса как свойство PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  номер графического стиля
                          PLOT_LINE_COLOR,      //  идентификатор свойства
                          plot_color_ind,       //  индекс цвета, куда запишем цвет
                          cols[i]);             //  новый цвет
      //--- запишем цвета
      comm=comm+StringFormat("BarColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| Изменяет внешний вид баров                                       |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- строка для формирования информации о свойствах баров
   string comm="";

//--- блок изменения толщины баров
   int number=MathRand();
//--- получим толщину как остаток от целочисленного деления
   int width=number%5;   // толщина задается от о до 4
//--- установим цвет как свойство PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- запишем толщину линии
   comm=comm+"\r\nWidth="+IntegerToString(width);

//--- запишем имя символа
   comm="\r\n"+symbol+comm;

//--- выведем информацию на график через комментарий
   Comment(comm);
  }

DRAW_COLOR_ZIGZAG

DRAW_COLOR_CANDLES