OnCalculate

int  OnCalculate(
   const int        rates_total,       // размер массива price[]
   const int        prev_calculated,   // количество обработанных баров на предыдущем вызове
   const int        begin,             // номер индекса в массиве price[], с которого начинаются значимые данные
   const double&    price[]            // массив значений для расчета
   );

int  OnCalculate(
   const int        rates_total,       // размер входных таймсерий
   const int        prev_calculated,   // количество обработанных баров на предыдущем вызове
   const datetime&  time[],            // массив Time
   const double&    open[],            // массив Open
   const double&    high[],            // массив High
   const double&    low[],             // массив Low
   const double&    close[],           // массив Close
   const long&      tick_volume[],     // массив Tick Volume
   const long&      volume[],          // массив Real Volume
   const int&       spread[]           // массив Spread
   );

//+------------------------------------------------------------------+
//|                                           OnCalculate_Sample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Пример вычисления индикатора Momentum"
 
//---- indicator settings
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
#property indicator_type1   DRAW_LINE
#property indicator_color1  Blue
//---- входные параметры
input int MomentumPeriod=14; // Период для расчета
//---- индикаторный буфер
double    MomentumBuffer[];
//--- глобальная переменная для хранения периода расчетов
int       IntPeriod;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- проверим входной параметр 
   if(MomentumPeriod<0)
     {
      IntPeriod=14;
      Print("параметр Период имеет неправльное значение. Для расчетов будет использовано значение ",IntPeriod);
     }
   else
      IntPeriod=MomentumPeriod;
//---- буферы  
   SetIndexBuffer(0,MomentumBuffer,INDICATOR_DATA);
//---- имя индикатора для показа в DataWindow и в подокне
   IndicatorSetString(INDICATOR_SHORTNAME,"Momentum"+"("+string(IntPeriod)+")");
//--- установим номер бара, с которого будет идти отрисовка
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,IntPeriod-1);
//--- установим 0.0 в качестве пустого значения, которое не отрисовывается
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//--- с какой точностью показывать значения индикатора
   IndicatorSetInteger(INDICATOR_DIGITS,2);
  }
//+------------------------------------------------------------------+
//|  Расчет индикатора Momentum                                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,     // размер массива price[] 
                const int prev_calculated, // сколько баров обработано ранее
                const int begin,           // откуда начинаются значимые данные 
                const double &price[])     // массив для значения для обработки
  {
//--- стартовая позиция для вычислений
   int StartCalcPosition=(IntPeriod-1)+begin;
//---- если недостаточно данных для расчета
   if(rates_total<StartCalcPosition)
      return(0);  // выходим с нулевым значением - индикатор не рассчитан
//--- correct draw begin
   if(begin>0)
      PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartCalcPosition+(IntPeriod-1));
//--- начинаем расчеты, вычислим позицию начала
   int pos=prev_calculated-1;
   if(pos<StartCalcPosition)
      pos=begin+IntPeriod;
//--- основной цикл вычислений
   for(int i=pos;i<rates_total && !IsStopped();i++)
      MomentumBuffer[i]=price[i]*100/price[i-IntPeriod];
//--- выполенение OnCalculate завершено. Вернем новое значение prev_calculated для последующего вызова
   return(rates_total);
  }