DRAW_NONE

Стиль DRAW_NONE предназначен для тех случаев, когда значения буфера необходимо рассчитывать и показывать в "Окне данных", но само отображение на графике не требуется. Для настройки точности отображения используйте в функции OnInit() выражение IndicatorSetInteger(INDICATOR_DIGITS,количество_знаков):

int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,InvisibleBuffer,INDICATOR_DATA);
//--- установим точность, с которой значение будет показываться в Окне данных
   IndicatorSetInteger(INDICATOR_DIGITS,0);
//---
   return(INIT_SUCCEEDED);
  }

Количество требуемых буферов для построения DRAW_NONE — 1.

Пример индикатора, который показывает в "Окне данных" номер бара, на котором находится мышка. Нумерация соответствует таймсерии, то есть текущий незавершенный бар имеет нулевой индекс, а самый старый бар имеет самый большой индекс.

Пример стиля DRAW_NONE

Обратите внимание, что несмотря на то, что для графического построения №1 указан красный цвет отображения, индикатор ничего не рисует на графике.

//+------------------------------------------------------------------+
//|                                                    DRAW_NONE.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plot Invisible
#property indicator_label1  "Bar Index"
#property indicator_type1   DRAW_NONE
#property indicator_style1  STYLE_SOLID
#property indicator_color1  clrRed
#property indicator_width1  1
//--- indicator buffers
double         InvisibleBuffer[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- связывание массива и индикаторного буфера
   SetIndexBuffer(0,InvisibleBuffer,INDICATOR_DATA);
//--- установим точность, с которой значение будет показываться в "Окне данных"
   IndicatorSetInteger(INDICATOR_DIGITS,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static datetime lastbar=0;
//--- если это первый расчет индикатора
   if(prev_calculated==0)
     {
      //--- перенумеруем бары в первый раз
      CalcValues(rates_total,close);
      //--- запомним время открытия текущего бара в lastbar
      lastbar=(datetime)SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE);
     }
   else
     {
      //--- если появился новый бар, время его открытия не совпадает с lastbar
      if(lastbar!=SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE))
        {
         //--- перенумеруем бары заново
         CalcValues(rates_total,close);
         //--- обновим время открытия текущего бара в lastbar
         lastbar=(datetime)SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE);
        }
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Нумерует бары как в таймсерии                                    |
//+------------------------------------------------------------------+
void CalcValues(int total,double const  &array[])
  {
//--- зададим индикаторному буферу индексацию как в таймсерии
   ArraySetAsSeries(InvisibleBuffer,true);
//--- заполним каждому бару его номер
   for(int i=0;i<total;i++) InvisibleBuffer[i]=i;
  }