//+------------------------------------------------------------------+
//| DRAW_HISTOGRAM2.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "DRAW_HISTOGRAM2를 시연하기 위한 지표"
#property description "각 막대의 시가 및 종가 사이에 세그먼트를 그립니다"
#property description "색상, 너비 및 스타일이 임의로 변경됩니다"
#property description "모든 N 틱 후"
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots 1
//--- Histogram_2 플롯
#property indicator_label1 "Histogram_2"
#property indicator_type1 DRAW_HISTOGRAM2
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- 매개변수 입력
input int N=5; // 히스토그램을 변경할 틱
//--- 지표 버퍼
double Histogram_2Buffer1[];
double Histogram_2Buffer2[];
//--- 지표가 플롯되지 않은 요일
int invisible_day;
//--- 색상을 저장할 배열
color colors[]={clrRed,clrBlue,clrGreen};
//--- 선 스타일을 저장할 배열
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| 사용자 지정 지표 초기화 함수 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 지표 버퍼 맵핑
SetIndexBuffer(0,Histogram_2Buffer1,INDICATOR_DATA);
SetIndexBuffer(1,Histogram_2Buffer2,INDICATOR_DATA);
//--- 빈 값 설정
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- 0 ~ 5 사이의 난수 가져오기
invisible_day=MathRand()%6;
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| 사용자 지정 지표 반복 함수 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 틱을 계산하여 선의 스타일, 색상 및 너비 변경
ticks++;
//--- 틱의 임계 수가 누적된 경우
if(ticks>=N)
{
//--- 선 속성 변경
ChangeLineAppearance();
//--- 틱 카운터를 0으로 재설정
ticks=0;
}
//--- 지표 값 계산
int start=0;
//--- 각 막대의 시가별 요일을 가져오기 위해
MqlDateTime dt;
//--- 이전 OnCalculate 시작 중에 이미 계산된 경우
if(prev_calculated>0) start=prev_calculated-1; // 계산의 시작을 단 하나의 막대로 설정
//--- 지표 버퍼에 값을 입력
for(int i=start;i<rates_total;i++)
{
TimeToStruct(time[i],dt);
if(dt.day_of_week==invisible_day)
{
Histogram_2Buffer1[i]=0;
Histogram_2Buffer2[i]=0;
}
else
{
Histogram_2Buffer1[i]=open[i];
Histogram_2Buffer2[i]=close[i];
}
}
//--- 함수의 다음 호출에 대해 prev_calculated 값을 반환
return(rates_total);
}
//+------------------------------------------------------------------+
//| 지표에 있는 선의 모양을 변경 |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- 라인 속성에 대한 정보를 구성하기 위한 문자열
string comm="";
//--- 선 색상 변경 블록
int number=MathRand(); // 임의 숫자 가져오기
//--- 제수는 colors[] 배열의 크기와 같습니다
int size=ArraySize(colors);
//--- 정수 나눗셈의 나머지의 새로운 색상을 선택할 인덱스를 가져오기
int color_index=number%size;
//--- 색상을 PLOT_LINE_COLOR 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- 선 색상 쓰기
comm=comm+"\r\n"+(string)colors[color_index];
//--- 선 너비 변경 블록
number=MathRand();
//--- 정수 나눗셈의 나머지 너비 가져오기
int width=number%5; // 너비는 0 ~ 4로 설정됩니다
//--- 선 너비 설정
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 선 너비 쓰기
comm=comm+"\r\nWidth="+IntegerToString(width);
//--- 선의 스타일을 변경하기 위한 블록
number=MathRand();
//--- 제수는 스타일 배열의 크기와 같습니다
size=ArraySize(styles);
//--- 정수 나눗셈의 나머지 항목으로 새 스타일을 선택할 인덱스를 가져오기
int style_index=number%size;
//--- 선 스타일 설정
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 선 스타일 쓰기
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- 계산에 생략된 날짜에 대한 정보 추가
comm="\r\nNot plotted day - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- 설명을 사용하여 차트에 정보 표시
Comment(comm);
}
|