//+------------------------------------------------------------------+
//| DRAW_HISTOGRAM2.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "An indicator to demonstrate DRAW_HISTOGRAM2"
#property description "It draws a segment between Open and Close on each bar"
#property description "The color, width and style are changed randomly"
#property description "after every N ticks"
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots 1
//--- Histogram_2 をプロットする
#property indicator_label1 "Histogram_2"
#property indicator_type1 DRAW_HISTOGRAM2
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- 入力パラメータ
input int N=5; // ヒストグラムを変更するティック数
//--- 指標バッファ
double Histogram_2Buffer1[];
double Histogram_2Buffer2[];
//--- 指標がプロットされない曜日
int invisible_day;
//--- 色を格納する配列
color colors[]={clrRed,clrBlue,clrGreen};
//--- 線のスタイルを格納する配列
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 指標バッファマッピング
SetIndexBuffer(0,Histogram_2Buffer1,INDICATOR_DATA);
SetIndexBuffer(1,Histogram_2Buffer2,INDICATOR_DATA);
//--- 空の値を設定
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- ０〜 5 の乱数を取得
invisible_day=MathRand()%6;
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| カスタム指標の反復関数 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 線のスタイル、色、及び幅を変更するティックを計算する
ticks++;
//--- 充分なティックの数が蓄積されている場合
if(ticks>=N)
{
//--- 線のプロパティを変更する
ChangeLineAppearance();
//--- ティックカウンタをゼロにリセットする
ticks=0;
}
//--- 指標値を計算する
int start=0;
//--- 各足の始値で曜日を取得する
MqlDateTime dt;
//--- すでにOnCalculate の前回の開始時に算出した場合
if(prev_calculated>0) start=prev_calculated-1; // 最後から2 つ目のバーから計算する
//--- 指標バッファに値を記入する
for(int i=start;i<rates_total;i++)
{
TimeToStruct(time[i],dt);
if(dt.day_of_week==invisible_day)
{
Histogram_2Buffer1[i]=0;
Histogram_2Buffer2[i]=0;
}
else
{
Histogram_2Buffer1[i]=open[i];
Histogram_2Buffer2[i]=close[i];
}
}
//--- prev_calculated 値を次の関数呼び出しのために返す
return(rates_total);
}
//+------------------------------------------------------------------+
//| 指標での線の外観を変更する |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- 線のプロパティに関する情報を形成するための文字列
string comm="";
//--- 線の色を変更するブロック
int number=MathRand(); // 乱数を取得
//--- 除数は colors[] 配列のサイズと同じ
int size=ArraySize(colors);
//--- 新しい色を選択するためのインデックスを整数除算の余りから取得
int color_index=number%size;
//--- 色をPLOT_LINE_COLOR プロパティとして設定
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- 線の色を書く
comm=comm+"\r\n"+(string)colors[color_index];
//--- 線の幅を変更するブロック
number=MathRand();
//--- 整数除算の余りの幅を取得
int width=number%5; // 幅は 0〜4 に設定される
//--- 線の幅を設定
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 線の幅を書く
comm=comm+"\r\nWidth="+IntegerToString(width);
//--- 線のスタイルを変更するブロック
number=MathRand();
//--- 除数は、スタイルの配列の大きさに等しい
size=ArraySize(styles);
//--- 新しいスタイルを選択するためのインデックスを整数除算の余りから取得
int style_index=number%size;
//--- 線のスタイルを設定
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 線のスタイルを書く
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- 計算では省略された日についての情報を追加する
comm="\r\nNot plotted day - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- コメントを使用して、チャート上の情報を表示する
Comment(comm);
}
|
