MQL5 RiferimentoIndicatori PersonalizzatiStili Indicatore negli EsempiDRAW_HISTOGRAM2

DRAW_HISTOGRAM2

Lo stile DRAW_HISTOGRAM2 disegna un istogramma di un colore specificato - segmenti verticali utilizzano i valori di due buffer indicatore. La larghezza, il colore e lo stile dei segmenti possono essere specificati come per lo stile DRAW_LINE - utilizzando le direttive del compilatore o in modo dinamico utilizzando la funzione PlotIndexSetInteger(). Cambiamenti dinamici delle proprietà di plotting permettono di cambiare l'aspetto dell'istogramma sulla base della situazione attuale.

Lo stile DRAW_HISTOGRAM2 può essere utilizzato in una sottofinestra separata di un grafico e nella sua finestra principale. Per i valori vuoti nulla viene tracciato, tutti i valori nei buffer indicatore devono essere impostati in modo esplicito. I buffer non vengono inizializzati con un valore zero.

Il numero di buffer necessari per tracciare DRAW_HISTOGRAM2 è 2.

Un esempio di indicatore che traccia un segmento verticale del colore specificato e la larghezza tra i prezzi Open e Close di ogni barra. Il colore, la larghezza e lo stile di tutte le colonne dell'istogramma cambiano in modo casuale ogni N ticks. Durante l'inizio dell'indicatore, nella funzione OnInit(), il numero del giorno della settimana per il quale non sarà disegnato l'istogramma - invisible_day - è impostato in modo casuale. A questo scopo viene impostato un valore vuoto PLOT_EMPTY_VALUE=0:

//--- Imposta un valore vuoto
PlotIndexSetDouble(index_of_plot_DRAW_SECTION,PLOT_EMPTY_VALUE,0);

Un esempio di DRAW_HISTOGRAM2

Notare che inizialmente per Plot1 con DRAW_HISTOGRAM2 le proprietà vengono impostate utilizzando la direttiva del compilatore #property, e poi nella funzione OnCalculate() queste tre proprietà sono impostate in modo casuale. Il parametro N è impostato in parametri esterni dell'indicatore per la possibilità di configurazione manuale (la scheda Parametri nella finestra Proprietà del indicatore).

//+--------------------------------------------------------------------------------+
//|                                                            DRAW_HISTOGRAM2.mq5 |
//|                                      Copyright 2011, MetaQuotes Software Corp. |
//|                                                           https://www.mql5.com |
//+--------------------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#property description "Un indicatore per dimostrare DRAW_HISTOGRAM2"
#property description "Disegna un segmento tra Open e Close su ciascuna barra"
#property description "Il colore, lo spessore e lo stile vengono cambiati casualmente"
#property description "dopo ogni N ticks"

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   1
//--- plot Histogram_2
#property indicator_label1  "Histogram_2"
#property indicator_type1   DRAW_HISTOGRAM2
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- parametri di input
input int      N=5;              // Il numero di ticks che cambiano l'istogramma
//--- buffers indicatore
double         Histogram_2Buffer1[];
double         Histogram_2Buffer2[];
//--- Il giorno della settimana per il quale l'indicatore non viene tracciato
int invisible_day;
//--- Un array per salvare i colori
color colors[]={clrRed,clrBlue,clrGreen};
//--- Un array per memorizzare gli stili di linea
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+--------------------------------------------------------------------------------+
//| Funzione di inizializzazione Indicatore Personalizzato                         |
//+--------------------------------------------------------------------------------+
int OnInit()
  {
//--- mappatura buffers indicatore
   SetIndexBuffer(0,Histogram_2Buffer1,INDICATOR_DATA);
   SetIndexBuffer(1,Histogram_2Buffer2,INDICATOR_DATA);
//--- Imposta un valore vuoto
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- Ottiene un numero casuale da 0 a 5
   invisible_day=MathRand()%6;
//---
   return(INIT_SUCCEEDED);
  }
//+--------------------------------------------------------------------------------+
//| Funzione di iterazione indicatore personalizato                                |
//+--------------------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Calcola i ticks per cambiare lo stile, il colore e lo spessore della linea
   ticks++;
//--- Se un numero critico di ticks è stato accumulato
   if(ticks>=N)
     {
      //--- Cambia le proprietà della linea
      ChangeLineAppearance();
      //--- Resetta il contatore dei ticks a zero
      ticks=0;
     }

//--- Calcola i valori dell'indicatore
   int start=0;
//--- Per ottenere il giorno della settimana per il prezzo di apertura di ogni barra
   MqlDateTime dt;
//--- Se già calcolato nelle precedenti starts di OnCalculate
   if(prev_calculated>0) start=prev_calculated-1; // imposta l'inizio del calcolo con la penultima barra
//--- Compila il buffer di indicatore con valori
   for(int i=start;i<rates_total;i++)
     {
      TimeToStruct(time[i],dt);
      if(dt.day_of_week==invisible_day)
        {
         Histogram_2Buffer1[i]=0;
         Histogram_2Buffer2[i]=0;
        }
      else
        {
         Histogram_2Buffer1[i]=open[i];
         Histogram_2Buffer2[i]=close[i];
        }
     }
//--- Restituisce il valore prev_calculated per la successiva chiamata della funzione
   return(rates_total);
  }
//+--------------------------------------------------------------------------------+
//| Cambia l'apparenza delle linee nell'indicatore                                 |
//+--------------------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Una stringa per la formazione di informazioni sulle proprietà di linea
   string comm="";
//--- Un blocco del cambiamento del colore della linea
   int number=MathRand(); // Ottiene un numero casuale
//--- Il divisore è uguale alla grandezza dell'array colors []
   int size=ArraySize(colors);
//--- Ottiene l'indice per selezionare un nuovo colore, come il resto della divisione intera
   int color_index=number%size;
//--- Imposta il colore come la proprietà PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- Scrive il colore della linea
   comm=comm+"\r\n"+(string)colors[color_index];

//--- Un blocco per modificare la larghezza della linea
   number=MathRand();
//--- Ottiene la larghezza del resto della divisione intera
   int width=number%5;   // La larghezza è impostata da 0 a 4
//--- Imposta lo spessore della linea
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Scrive lo spessore della linea
   comm=comm+"\r\nWidth="+IntegerToString(width);

//--- Un blocco per cambiare lo stile della linea
   number=MathRand();
//--- Il divisore è uguale alla grandezza dell'array styles
   size=ArraySize(styles);
//--- Ottiene l'indice per selezionare un nuovo stile, come resto della divisione intera
   int style_index=number%size;
//--- Imposta lo stile della linea
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Scrive lo stile della linea
   comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- Aggiunge le informazioni sul giorno che viene omesso nei calcoli
   comm="\r\nNot plotted day - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- Imposta le informazioni del grafico usando un commento
   Comment(comm);
  }

DRAW_HISTOGRAM

DRAW_ARROW