DRAW_COLOR_HISTOGRAM2

//+------------------------------------------------------------------+
//|                                        DRAW_COLOR_HISTOGRAM2.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link     "https://www.mql5.com"
#property version   "1.00"
 
#property description "An indicator to demonstrate DRAW_COLOR_HISTOGRAM2"
#property description "It draws a segment between Open and Close on each bar"
#property description "The color, width and style are changed randomly"
#property description "after every N ticks"
 
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots   1
//--- ColorHistogram_2 をプロットする
#property indicator_label1 "ColorHistogram_2"
#property indicator_type1   DRAW_COLOR_HISTOGRAM2
//--- 曜日のヒストグラムに色を塗るための（特別な配列に格納された）5色を定義する
#property indicator_color1 clrRed,clrBlue,clrGreen,clrYellow,clrMagenta
#property indicator_style1 STYLE_SOLID
#property indicator_width1  1
 
//--- 入力パラメータ
input int     N=5;             // ヒストグラムを変更するティック数
int            color_sections;
//--- 値バッファ
double         ColorHistogram_2Buffer1[];
double         ColorHistogram_2Buffer2[];
//--- カラーインデックを格納するバッファ
double         ColorHistogram_2Colors[];
//--- 色を格納する14 要素の配列
color colors[]=
 {
  clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
  clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
 };
//--- 線のスタイルを格納する配列
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
int OnInit()
 {
//--- 指標バッファマッピング
  SetIndexBuffer(0,ColorHistogram_2Buffer1,INDICATOR_DATA);
  SetIndexBuffer(1,ColorHistogram_2Buffer2,INDICATOR_DATA);
  SetIndexBuffer(2,ColorHistogram_2Colors,INDICATOR_COLOR_INDEX);
//--- 空の値を設定
  PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//----正弦波を塗る色の数
  color_sections=8;   //   #property indicator_color1 コメントを参照 
//---
  return(INIT_SUCCEEDED);
 }
//+------------------------------------------------------------------+
//| カスタム指標の反復関数                                                |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
 {
  static int ticks=0;
//--- 線のスタイル、色、及び幅を変更するティックを計算する
  ticks++;
//--- 充分なティックの数が蓄積されている場合
  if(ticks>=N)
    {
    //--- 線のプロパティを変更する
     ChangeLineAppearance();
    //--- ヒストグラムを描画する色を変更する
     ChangeColors(colors,color_sections);      
    //--- ティックカウンタをゼロにリセットする
     ticks=0;
    }
 
//--- 指標値を計算する
  int start=0;
//--- 各足の始値で曜日を取得する
  MqlDateTime dt;
//--- すでにOnCalculate の前回の開始時に算出した場合
  if(prev_calculated>0) start=prev_calculated-1; // 最後から2 つ目のバーから計算する
//--- 指標バッファに値を記入する
  for(int i=start;i<rates_total;i++)
    {
    TimeToStruct(time[i],dt);
    //--- 値
     ColorHistogram_2Buffer1[i]=high[i];
     ColorHistogram_2Buffer2[i]=low[i];
    //--- 曜日に応じて色のインデックスを設定する
    int day=dt.day_of_week;
     ColorHistogram_2Colors[i]=day;
    }
//--- prev_calculated 値を次の関数呼び出しのために返す
  return(rates_total);
 }
//+------------------------------------------------------------------+
//| 線分の色を変更する                                                   |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
 {
//--- 色の数
  int size=ArraySize(cols);
//---
  string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- それぞれのカラーインデックに新しい色をランダムに定義する
  for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
    {
    //--- 乱数を取得
    int number=MathRand();
    //--- 整数除算の余りから col[] 配列のインデックスを取得
    int i=number%size;
    //--- 各インデックスの色をPLOT_LINE_COLOR として設定する
    PlotIndexSetInteger(0,                   //  グラフィックスタイルの番号
                        PLOT_LINE_COLOR,     //  プロパティの識別子
                         plot_color_ind,       //  色を書き込む色インデックス
                         cols[i]);             //  新しい色
    //--- 色を書く
     comm=comm+StringFormat("HistogramColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
    ChartSetString(0,CHART_COMMENT,comm);
    }
//---
 }
//+------------------------------------------------------------------+
//| 指標に表示された線の外観を変更する                                       |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
 {
//--- 線のプロパティに関する情報を形成するための文字列
  string comm="";
//--- 線の幅を変更するブロック
  int number=MathRand();
//--- 整数除算の余りの幅を取得
  int width=number%5; // 幅は 0〜4 に設定される
//--- 色を PLOT_LINE_WIDTH プロパティに設定
  PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 線の幅を書く
  comm=comm+" Width="+IntegerToString(width);
 
//--- 線のスタイルを変更するブロック
  number=MathRand();
//--- 除数は、スタイルの配列の大きさに等しい
  int size=ArraySize(styles);
//--- 新しいスタイルを選択するためのインデックスを整数除算の余りから取得
  int style_index=number%size;
//--- 色をPLOT_LINE_COLOR プロパティとして設定
  PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 線のスタイルを書く
  comm=EnumToString(styles[style_index])+", "+comm;
//--- コメントを使用して、チャート上の情報を表示する
  Comment(comm);
 }