TextGetSize

bool  TextGetSize(
   const string       text,          // cadena del texto
   uint&               width,        // ancho del búfer en píxeles
   uint&               height        // alto del búfer en píxeles
   );

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#define   COORD_X    200
#define   COORD_Y    100
#define   OBJ_NAME   "TestTextGetSizeBitmapLabel"
#define   RES_NAME   "TestTextGetSizeResource"
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- preparamos tres cadenas de texto para mostrar en el gráfico
   string text1="This is the first line of text";
   string text2="The second line also contains text";
   string text3="Each word in each line has its own size";
   
   string text_array1[];   // array para obtener el conjunto de palabras de la cadena 1
   string text_array2[];   // array para obtener el conjunto de palabras de la cadena 2
   string text_array3[];   // array para obtener el conjunto de palabras de la cadena 3
   
//--- rellenamos tres arrays de palabras
   if(!SplitTextIntoWords(text1, text_array1) || !SplitTextIntoWords(text2, text_array2) || !SplitTextIntoWords(text3, text_array3))
      return;
      
//--- identificador del gráfico actual
   long   chart_id= ChartID();
   
//--- declaramos los parámetros del recurso gráfico
   uint   rc_width =(int)ChartGetInteger(chart_id, CHART_WIDTH_IN_PIXELS); 
   uint   rc_height=(int)ChartGetInteger(chart_id, CHART_HEIGHT_IN_PIXELS); 
   uint   rc_data[]; 
   uint   rc_size=rc_width*rc_height;
  
//--- creamos un recurso gráfico para la muestra de texto
   if(!CreateResource(chart_id, rc_data, rc_width, rc_height))
      return;
   
//--- obtenemos el tamaño de la anchura y la altura del carácter "espacio"
   int space_w=0, space_h=0;
   if(!TextGetSize(" ", space_w, space_h))
     {
      PrintFormat("%s: TextGetSize() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return; 
     }
   
//--- aumentamos la separación vertical entre líneas a 2 y dibujamos los textos de los tres arrays
   space_h+=2;
   TextArrayToChart(1, text_array1, COORD_X, COORD_Y+space_h*0, space_w, rc_data, rc_width, rc_height);
   TextArrayToChart(2, text_array2, COORD_X, COORD_Y+space_h*1, space_w, rc_data, rc_width, rc_height);
   TextArrayToChart(3, text_array3, COORD_X, COORD_Y+space_h*2, space_w, rc_data, rc_width, rc_height);
   
//--- después de mostrar todos los textos, actualizaremos los datos de los recursos
   Update(RES_NAME, rc_data, rc_width, rc_height, true);
   
//--- esperamos cinco segundos, luego liberamos el recurso y eliminamos el objeto gráfico
   Sleep(5000);
   ResourceFree(RES_NAME);
   ObjectDelete(chart_id, OBJ_NAME);
   /*
   como resultado del funcionamiento del script, se mostrarán tres líneas de texto en el gráfico
   cada palabra individual en cada línea se mostrará a una distancia de la palabra anterior
   igual a la anchura de la palabra anterior obtenida con la ayuda de la función TextGetSize();
   el diario imprimirá todas las palabras de cada línea con sus dimensiones:
   Text array 1:
   [0] word: "This", width=29, height=18
   [1] word: "is", width=12, height=18
   [2] word: "the", width=21, height=18
   [3] word: "first", width=25, height=18
   [4] word: "line", width=24, height=18
   [5] word: "of", width=13, height=18
   [6] word: "text", width=24, height=18
   Text array 2:
   [0] word: "The", width=26, height=18
   [1] word: "second", width=51, height=18
   [2] word: "line", width=24, height=18
   [3] word: "also", width=29, height=18
   [4] word: "contains", width=58, height=18
   [5] word: "text", width=24, height=18
   Text array 3:
   [0] word: "Each", width=36, height=18
   [1] word: "word", width=34, height=18
   [2] word: "in", width=12, height=18
   [3] word: "each", width=34, height=18
   [4] word: "line", width=24, height=18
   [5] word: "has", width=25, height=18
   [6] word: "its", width=16, height=18
   [7] word: "own", width=28, height=18
   [8] word: "size", width=28, height=18
   */ 
  }
//+------------------------------------------------------------------+
//| Divide la línea en un array de palabras según                    |
//| el separador "espacio" (" ")                                     |
//+------------------------------------------------------------------+
bool SplitTextIntoWords(const string text, string &array[])
  {
   ResetLastError();
   if(StringSplit(text, StringGetCharacter(" ", 0), array)<0)
     {
      PrintFormat("%s: StringSplit() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return(false); 
     }
   return(true);
  }
//+------------------------------------------------------------------+
//| Muestra el texto del array en el gráfico                         |
//+------------------------------------------------------------------+
void TextArrayToChart(int array_num, string &array[], const int text_x, const int text_y, int space_w, uint &pixel_data[], const uint res_width, const uint res_height)
  {
   int width=0, height=0;  // anchura y altura del texto
   int x=text_x;           // coordenada X del texto mostrado
   
//--- imprimimos el encabezado con el nombre del array de palabras procesado
   Print("Text array ", array_num,":");
   
//--- en un ciclo por el array de palabras
   int total=(int)array.Size();
   for(int i=0; i<total; i++)
     {
      //--- obtenemos la siguiente palabra y la enviamos al gráfico (dibujamos en el array de píxeles del recurso)
      string word=array[i];
      TextOut(word, x, text_y, ANCHOR_LEFT_UPPER, pixel_data, res_width, res_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
      
      //--- obtenemos el tamaño del texto de la palabra actual
      ResetLastError();
      if(!TextGetSize(word, width, height))
        {
         PrintFormat("%s: TextGetSize(\"%s\") failed. Error code %d",__FUNCTION__, word, GetLastError()); 
         continue; 
        }
      //--- imprimimos los datos del texto en el diario: la palabra, su anchura y su altura,
      //--- a continuación, aumentamos la coordenada X de la siguiente palabra en un valor (anchura de la palabra) + (anchura del espacio)
      PrintFormat("[%d] word: \"%s\", width=%d, height=%d",i, word, width, height);
      x+=width+space_w;
     }
  }
//+------------------------------------------------------------------+
//| Crea un recurso gráfico para todo el gráfico                     |
//+------------------------------------------------------------------+
bool CreateResource(const long chart_id, uint &pixel_data[], const uint width, const uint height)
  {
//--- establecemos el tamaño del array de píxeles
   ResetLastError(); 
   uint size=width*height;
   if(ArrayResize(pixel_data, size)!=size) 
     { 
      PrintFormat("%s: ArrayResize() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return(false); 
     } 
//--- rellenamos el array de píxeles con un color transparente y creamos un recurso gráfico basado en él
   ArrayInitialize(pixel_data, 0x00FFFFFF); 
   if(!ResourceCreate(RES_NAME, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE)) 
     { 
      PrintFormat("%s: ResourceCreate() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return(false); 
     } 
  
//--- creamos un objeto "Etiqueta Gráfica" en las coordenadas de la esquina superior izquierda del gráfico
   if(!ObjectCreate(0, OBJ_NAME, OBJ_BITMAP_LABEL, 0, 0, 0)) 
     { 
      PrintFormat("%s: ObjectCreate() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return(false); 
     } 
//--- establecemos una anchura y altura del objeto de dibujo creado iguales a la anchura y altura del recurso gráfico.
//--- establecemos el punto de anclaje del objeto en su centro.
   if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_XSIZE, width))
     {
      PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return(false); 
     }
   if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_YSIZE, height))
     {
      PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return(false); 
     }
//--- para el objeto de imagen, especificamos como archivo de imagen el recurso gráfico creado previamente
//--- en este caso, para especificar el nombre del recurso gráfico utilizado, deberemos escribir antes de su nombre "::"
   if(!ObjectSetString(chart_id, OBJ_NAME, OBJPROP_BMPFILE, "::"+RES_NAME))
     {
      PrintFormat("%s: ObjectSetString() failed. Error code %d",__FUNCTION__, GetLastError()); 
      return(false); 
     }
    
//--- todo ha tenido éxito
   return(true);
  }
//+------------------------------------------------------------------+ 
//| Actualiza los datos del recurso gráfico                          |
//+------------------------------------------------------------------+ 
void Update(const string res_name, const uint &pixel_data[], const uint width, const uint height, const bool redraw) 
  { 
//--- si se ha transferido un tamaño cero, salimos
   if(width==0 || height==0) 
      return; 
//--- actualizamos los datos de recursos y redibujamos el gráfico
   if(ResourceCreate(res_name, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE) && redraw) 
      ChartRedraw(); 
  }