DocumentationSections
Référence MQL5Fonctions sur les ObjetsObjectsTotal 

ObjectsTotal

Rend le nom de l'objet correspondant au chart indiqué, dans la sous-fenêtre indiquée de chart indiqué, du type indiqué.

int  ObjectsTotal(
   long  chart_id,           // identificateur du graphique
   int   sub_window=-1,      // index de la fenêtre
   int   type=-1             // type de l'objet     
   );

Paramètres

chart_id

[in]  L'identificateur du graphique. 0 signifie le graphique courant.

sub_window=-1

[in] Le numéro de la sous-fenêtre du graphique. 0 signifie la fenêtre principale du graphique, -1 signifie toutes les sous-fenêtres du graphique, y compris la fenêtre principale.

type=-1

[in]   Le type de l'objet. La valeur peut être une des valeurs de l'énumération ENUM_OBJECT. -1 signifie tous les types.

Valeur de Retour

Le nombre d'objets.

Note

La fonction utilise un appel synchrone, ce qui signifie que la fonction attend la fin de l'exécution de toutes les commandes présentes dans la queue de ce graphique avant cet appel. C'est pourquoi cette fonction peut être consommatrice en terme de temps. Cette caractéristique doit être prise en compte lors de l'utilisation d'un grand nombre d'objets sur un graphique.

 

Exemple :

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- identifiant du graphique
   long chart_id=ChartID();
   
//--- obtient le nombre de sous-fenêtres du graphique ainsi que la fenêtre principale
   long wnd=0;
   ResetLastError();
   if(!ChartGetInteger(chart_id, CHART_WINDOWS_TOTAL, 0, wnd))
     {
      Print("ChartGetInteger() failed. Error ", GetLastError());
      return;
     }
   
//--- récupère et affiche dans le journal le nombre d'objets graphiques pour chaque sous-fenêtre du graphique
   for(int i=0; i<(int)wnd; i++)
     {
      int objects=ObjectsTotal(chart_id, i);
      string wnd_head=(i==0 ? "The main chart window" : StringFormat("The window with index %d of the chart", i));
      PrintFormat("%s contains %d graphic objects", wnd_head, objects);
     }
   /*
   résultat pour la fenêtre principale avec deux sous-fenêtres,
   où la fenêtre principale contient des étiquettes de transactions,
   et 2 objets graphiques sont dans les sous-fenêtres :
   The main chart window contains 656 graphic objects
   The window with index 1 of the chart contains 2 graphic objects 
   The window with index 2 of the chart contains 2 graphic objects
   */
  }