DatabaseImport

long  DatabaseImport(
   int           database,          // identificador de banco de dados recebido em DatabaseOpen
   const string  table,             // nome da tabela para inserir dados
   const string  filename,          // nome do arquivo para importar dados
   uint          flags,             // combinação de sinalizadores
   const string  separator,         // separador de dados 
   ulong         skip_rows,         // quantas primeiras linhas ignorar
   const string  skip_comments      // strings de símbolos que definem comentários
   );

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
 {
  string csv_filename;
//--- obtemos os nomes dos arquivos de texto a serem carregados da pasta comum dos terminais do cliente
  string filenames[];
  if(FileSelectDialog("Selecione o arquivo CSV para carregamento da tabela", NULL,
                      "Text files (*.csv)|*.csv",
                      FSD_WRITE_FILE|FSD_COMMON_FOLDER, filenames, "data.csv")>0)
   {
    //--- exibimos o nome de cada arquivo selecionado
    if(ArraySize(filenames)==1)
      csv_filename=filenames[0];
    else
     {
      Print("Erro desconhecido durante a seleção do arquivo. Código de erro ", GetLastError());
      return;
     }
   }
  else
   {
    Print("arquivo CSV não selecionado");
    return;
   }
//--- criamos ou abrimos um banco de dados
  string db_filename="test.sqlite";
  int db=DatabaseOpen(db_filename, DATABASE_OPEN_READWRITE|DATABASE_OPEN_CREATE);
//--- verificamos a presença da tabela TEST
  if(DatabaseTableExists(db, "TEST"))
   {
    //--- removemos a tabela TEST
    if(!DatabaseExecute(db, "DROP TABLE IF EXISTS TEST"))
     {
      Print("Failed to drop the TEST table with code ", GetLastError());
      DatabaseClose(db);
      return;
     }
   }
  //--- importamos os registros desde um arquivo para uma tabela TEST
  long imported=DatabaseImport(db, "TEST", csv_filename, DATABASE_IMPORT_HEADER|DATABASE_IMPORT_COMMON_FOLDER|DATABASE_IMPORT_APPEND, ";", 0, NULL);
  if(imported>0)
   {
    Print(imported," lines imported in table TEST");
    DatabasePrint(db,"SELECT * FROM TEST",DATABASE_PRINT_NO_INDEX);
   }
  else
    {
     Print("DatabaseImport() failed. Error ",GetLastError());
    }
//--- fechamos o arquivo do banco de dados e relatamos isso
  DatabaseClose(db);
  PrintFormat("Database: %s closed", db_filename);
 }