DatabaseImport

long  DatabaseImport(
   int           database,          // DatabaseOpen에서 수신된 데이터베이스 핸들
   const string  table,             // 데이터를 삽입할 테이블의 이름
   const string  filename,          // 데이터를 가져욜 파일의 이름
   uint          flags,             // 플래그의 조합
   const string  separator,         // 데이터 분리자 
   ulong         skip_rows,         // 생략할 초기 문자열 수 
   const string  skip_comments      // 설명 정의 문자 문자열
   );

/+------------------------------------------------------------------+
//| 프로그램 시작 함수 스크립트                                        |
/+------------------------------------------------------------------+
void OnStart()
 {
  string csv_filename;
//--- 클라이언트 터미널의 공통 폴더에서 다운로드할 텍스트 파일의 이름을 가져옵니다.
  string filenames[];
  if(FileSelectDialog("Select a CSV file to download a table", NULL,
                      "Text files (*.csv)|*.csv",
                      FSD_WRITE_FILE|FSD_COMMON_FOLDER, filenames, "data.csv")>0)
   {
 //--- 선택한 각 파일의 이름 표시
    if(ArraySize(filenames)==1)
      csv_filename=filenames[0];
    else
     {
      Print("Unknown error while selecting file. Error code ", GetLastError());
      return;
     }
   }
  else
   {
    Print("CSV file not selected");
    return;
   }
//--- 데이터 베이스 생성 혹은 열기
  string db_filename="test.sqlite";
  int db=DatabaseOpen(db_filename, DATABASE_OPEN_READWRITE|DATABASE_OPEN_CREATE);
//--- TEST 테이블이 존재하는지 확인
  if(DatabaseTableExists(db, "TEST"))
   {
    //--- TEST 테이블 제거
    if(!DatabaseExecute(db, "DROP TABLE IF EXISTS TEST"))
     {
      Print("Failed to drop the TEST table with code ", GetLastError());
      DatabaseClose(db);
      return;
     }
   }
 //--- 파일에서 TEST 테이블로 항목 가져오기
  long imported=DatabaseImport(db, "TEST", csv_filename, DATABASE_IMPORT_HEADER|DATABASE_IMPORT_COMMON_FOLDER|DATABASE_IMPORT_APPEND, ";", 0, NULL);
  if(imported>0)
   {
    Print(imported," lines imported in table TEST");
    DatabasePrint(db,"SELECT * FROM TEST",DATABASE_PRINT_NO_INDEX);
   }
  else
    {
     Print("DatabaseImport() failed. Error ",GetLastError());
    }
//--- 데이터 베이스 파일을 닫고 알리기
  DatabaseClose(db);
  PrintFormat("Database: %s closed", db_filename);
 }