DatabaseImport

long  DatabaseImport(
   int           database,          // manejador de base de datos recibido en DatabaseOpen
   const string  table,             // nombre del recuadro para insertar los datos
   const string  filename,          // nombre del archivo para importar los datos
   uint          flags,             // combinación de banderas
   const string  separator,         // separador de datos 
   ulong         skip_rows,         // cuantas primeras líneas se omiten 
   const string  skip_comments      // línea de símbolos que determinan los comentarios
   );

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
 {
  string csv_filename;
//--- obtenemos los nombres de los archivos de texto para realizar la carga desde la carpeta general de los terminales de cliente
  string filenames[];
  if(FileSelectDialog("Seleccione el archivo CSV para cargar el recuadro", NULL,
                      "Text files (*.csv)|*.csv",
                      FSD_WRITE_FILE|FSD_COMMON_FOLDER, filenames, "data.csv")>0)
   {
    //--- mostramos el nombre de cada archivo seleccionado
    if(ArraySize(filenames)==1)
      csv_filename=filenames[0];
    else
     {
      Print("Error desconocido al seleccionar el archivo. Código de error ", GetLastError());
      return;
     }
   }
  else
   {
    Print("Archivo CSV no seleccionado");
    return;
   }
//--- creamos o abrimos la base de datos
  string db_filename="test.sqlite";
  int db=DatabaseOpen(db_filename, DATABASE_OPEN_READWRITE|DATABASE_OPEN_CREATE);
//--- comprobamos la presencia del recuadro TEST
  if(DatabaseTableExists(db, "TEST"))
   {
    //--- eliminamos el recuadro TEST
    if(!DatabaseExecute(db, "DROP TABLE IF EXISTS TEST"))
     {
      Print("Failed to drop the TEST table with code ", GetLastError());
      DatabaseClose(db);
      return;
     }
   }
  //--- importamos la entrada desde el archivo al recuadro TEST
  long imported=DatabaseImport(db, "TEST", csv_filename, DATABASE_IMPORT_HEADER|DATABASE_IMPORT_COMMON_FOLDER|DATABASE_IMPORT_APPEND, ";", 0, NULL);
  if(imported>0)
   {
    Print(imported," lines imported in table TEST");
    DatabasePrint(db,"SELECT * FROM TEST",DATABASE_PRINT_NO_INDEX);
   }
  else
    {
     Print("DatabaseImport() failed. Error ",GetLastError());
    }
//--- cerramos el archivo con la base de datos y comunicamos este hecho
  DatabaseClose(db);
  PrintFormat("Database: %s closed", db_filename);
 }