DatabaseImport

long  DatabaseImport(
   int           database,          // хендл базы данных, полученный в DatabaseOpen
   const string  table,             // имя таблицы для вставки данных
   const string  filename,          // имя файла для импорта данных
   uint          flags,             // комбинация флагов
   const string  separator,         // разделитель данных 
   ulong         skip_rows,         // сколько первых строк пропустить 
   const string  skip_comments      // строка символов, которые определяют комментарии
   );

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
 {
  string csv_filename;
//--- получим имена текстовых файлов для загрузки из общей папки клиентских терминалов
  string filenames[];
  if(FileSelectDialog("Выберите CSV-файл для загрузки таблицы", NULL,
                      "Text files (*.csv)|*.csv",
                      FSD_WRITE_FILE|FSD_COMMON_FOLDER, filenames, "data.csv")>0)
   {
    //--- выведем имя каждого выбранного файла
    if(ArraySize(filenames)==1)
      csv_filename=filenames[0];
    else
     {
      Print("Неизвестная ошибка при выборе файла. Код ошибки ", GetLastError());
      return;
     }
   }
  else
   {
    Print("CSV-файл не выбран");
    return;
   }
//--- создадим или откроем базу данных
  string db_filename="test.sqlite";
  int db=DatabaseOpen(db_filename, DATABASE_OPEN_READWRITE|DATABASE_OPEN_CREATE);
//--- проверим наличие таблицы TEST
  if(DatabaseTableExists(db, "TEST"))
   {
    //--- удалим таблицу TEST
    if(!DatabaseExecute(db, "DROP TABLE IF EXISTS TEST"))
     {
      Print("Failed to drop the TEST table with code ", GetLastError());
      DatabaseClose(db);
      return;
     }
   }
  //--- импортируем записи из файла в таблицу TEST
  long imported=DatabaseImport(db, "TEST", csv_filename, DATABASE_IMPORT_HEADER|DATABASE_IMPORT_COMMON_FOLDER|DATABASE_IMPORT_APPEND, ";", 0, NULL);
  if(imported>0)
   {
    Print(imported," lines imported in table TEST");
    DatabasePrint(db,"SELECT * FROM TEST",DATABASE_PRINT_NO_INDEX);
   }
  else
    {
     Print("DatabaseImport() failed. Error ",GetLastError());
    }
//--- закроем файл с базой данных и сообщим об этом
  DatabaseClose(db);
  PrintFormat("Database: %s closed", db_filename);
 }