下载MetaTrader 5

DRAW_COLOR_BARS

DRAW_COLOR_BARS 样式绘制四个指标缓冲区值的柱形,包括开盘价,最高价,最低价和收盘价。该样式是DRAW_BARS 的提高版,允许为每个柱形指定来自预定义颜色的独立颜色。它用于创建自定义指标为柱形,包括单独的图表子窗口中和其他金融工具上的指标。

柱形颜色的设置可以使用 编译程序指令 或动态使用 PlotIndexSetInteger() 函数。动态改变标图属性允许 "激活" 指标,以便于可以根据当前状况改变其外观。

指标仅向那些柱形绘制,为此,设置所有四个指标缓冲区的非空值。 若要指定哪个值应被视为“空”,请在 PLOT_EMPTY_VALUE 属性设定该值:

//--- 0(空)值将不参与绘制
   PlotIndexSetDouble(index_of_plot_DRAW_COLOR_BARS,PLOT_EMPTY_VALUE,0);

始终明确填写指标缓冲区的值,在缓冲区设置空值跳过柱形。

标图DRAW_COLOR_BARS 所需的缓冲区的数量是5:

  • 存储开盘价,最高价,最低价和收盘价值的四个缓冲区;
  • 存储颜色标引的一个缓冲区,它被用于绘制柱形 (它使得仅设置将被绘制的柱形有意义)。

标图的所有缓冲区都应该按照给定的顺序一个接一个地进行:开盘价,最高价,最低价,收盘价和颜色缓冲区。价格缓冲区不会只包含null值,因为在这种情况下,不会标图。

在单独窗口的选定金融工具上绘制柱形的指标示例。柱形颜色每 N个订单号都会随机变化一次。 N 参数设置在指标的 外部参数 ,使手动配置成为可能(指标属性窗口的参数标签)。

DRAW_COLOR_BARS样式的示例

请注意,DRAW_COLOR_BARS样式的plot1 ,使用编译程序指令#property设置8个颜色,然后在OnCalculate() 函数随机选择来自存储在colors[] 数组的14种颜色的颜色。

//+------------------------------------------------------------------+
//|                                              DRAW_COLOR_BARS.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "An indicator to demonstrate DRAW_COLOR_BARS"
#property description "It draws different-color bars of a selected symbol in a separate window"
#property description "The color and width of bars, as well as the symbol are changed randomly"
#property description "every N ticks"
 
#property indicator_separate_window
#property indicator_buffers 5
#property indicator_plots   1
//--- 标图 ColorBars
#property indicator_label1  "ColorBars"
#property indicator_type1   DRAW_COLOR_BARS
//--- 定义8种用于填充柱形的颜色(它们存储在指定数组)
#property indicator_color1  clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- 输入参数
input int      N=5;              // 改变类型的订单号数量
input int      bars=500;         // 显示的柱形数量
input bool     messages=false;   // 在"EA交易"日志显示信息
//--- 指标缓冲区
double         ColorBarsBuffer1[];
double         ColorBarsBuffer2[];
double         ColorBarsBuffer3[];
double         ColorBarsBuffer4[];
double         ColorBarsColors[];
//--- 交易品种名称
string symbol;
int    bars_colors;
//--- 存储颜色的数组包含14种元素
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrMagenta,clrCyan,clrMediumPurple
  };
//+------------------------------------------------------------------+
//| 自定义指标初始化函数                                                |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- 指标缓冲区映射
   SetIndexBuffer(0,ColorBarsBuffer1,INDICATOR_DATA);
   SetIndexBuffer(1,ColorBarsBuffer2,INDICATOR_DATA);
   SetIndexBuffer(2,ColorBarsBuffer3,INDICATOR_DATA);
   SetIndexBuffer(3,ColorBarsBuffer4,INDICATOR_DATA);
   SetIndexBuffer(4,ColorBarsColors,INDICATOR_COLOR_INDEX);
//---- 为柱形填充颜色的颜色数量
   bars_colors=8;   // 请见注释#property indicator_color1 属性
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| 自定义指标迭代函数                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- 计算订单号改变样式,颜色和柱形宽度
   ticks++;
//--- 如果足够数量的订单号被积累
   if(ticks>=N)
     {
      //--- 选择来自市场报价窗口的新交易品种
      symbol=GetRandomSymbolName();
      //--- 改变线型属性
      ChangeLineAppearance();
      //--- 改变用于绘制蜡烛图的颜色
      ChangeColors(colors,bars_colors);
      int tries=0;
      //--- 试图5 次填充缓冲区的交易品种价格
      while(!CopyFromSymbolToBuffers(symbol,rates_total,bars_colors) && tries<5)
        {
         //--- CopyFromSymbolToBuffers() 函数调用的计数器
         tries++;
        }
      //--- 重置0计数器
      ticks=0;
     }
//--- 返回 prev_calculated值以便下次调用函数
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| 填充指标缓冲区的价格                                                |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,int total,int bar_colors)
  {
//--- 在rates[] 数组中,我们将复制开盘价,最高价,最低价和收盘价
   MqlRates rates[];
//--- 尝试计数器
   int attempts=0;
//--- 已复制多少
   int copied=0;
//--- 试图25次获得所需交易品种的时间帧
   while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
     {
      Sleep(100);
      attempts++;
      if(messagesPrintFormat("%s CopyRates(%s) attempts=%d",__FUNCTION__,name,attempts);
     }
//--- 如果复制足够数量的柱形失败
   if(copied!=bars)
     {
      //--- 形成信息字符串
      string comm=StringFormat("For the symbol %s, managed to receive only %d bars of %d requested ones",
                               name,
                               copied,
                               bars
                               );
      //--- 在主图表窗口的注释中显示信息
      Comment(comm);
      //--- 显示信息
      if(messagesPrint(comm);
      return(false);
     }
   else
     {
      //--- 设置交易品种的展示
      PlotIndexSetString(0,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
      IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_COLOR_BARS("+name+")");
     }
//--- 初始化空值缓冲区
   ArrayInitialize(ColorBarsBuffer1,0.0);
   ArrayInitialize(ColorBarsBuffer2,0.0);
   ArrayInitialize(ColorBarsBuffer3,0.0);
   ArrayInitialize(ColorBarsBuffer4,0.0);
 
//--- 复制缓冲区的价格
   for(int i=0;i<copied;i++)
     {
      //--- 计算缓冲区相应的标引
      int buffer_index=total-copied+i;
      //--- 写下缓冲区的价格
      ColorBarsBuffer1[buffer_index]=rates[i].open;
      ColorBarsBuffer2[buffer_index]=rates[i].high;
      ColorBarsBuffer3[buffer_index]=rates[i].low;
      ColorBarsBuffer4[buffer_index]=rates[i].close;
      //---
      ColorBarsColors[buffer_index]=i%bar_colors;
     }
   return(true);
  }
//+------------------------------------------------------------------+
//| 随机返回来自市场报价的交易品种                                       |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
  {
//--- 市场报价窗口中显示的交易品种数量
   int symbols=SymbolsTotal(true);
//--- 列表中的交易品种位置 - 从0到交易品种的随机号
   int number=MathRand()%symbols;
//--- 返回指定位置的交易品种名称
   return SymbolName(number,true);
  }
//+------------------------------------------------------------------+
//| 改变zigzag节段的颜色                                               |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- 颜色数
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- 为每个颜色标引随机定义一个新的颜色
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- 获得随机数
      int number=MathRand();
      //--- 获得col[]数组的标引作为整数除法的余数
      int i=number%size;
      //--- 设置每个标引的颜色为 PLOT_LINE_COLOR属性
      PlotIndexSetInteger(0,                    //  图形样式数量
                          PLOT_LINE_COLOR,      //  属性标识符
                          plot_color_ind,       //  颜色标引,我们在这里编写颜色
                          cols[i]);             // 新颜色
      //--- 编写颜色
      comm=comm+StringFormat("BarColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| 改变柱形的外观                                                     |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- 形成柱形属性信息的字符串
   string comm="";
 
//--- 改变柱形宽度的模块
   int number=MathRand();
//--- 获得整数除法余数的宽度
   int width=number%5;   // 宽度设置从 0 到 4
//--- 设置颜色为PLOT_LINE_WIDTH属性
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 写下线型宽度
   comm=comm+"\r\nWidth="+IntegerToString(width);
 
//--- 写下交易品种名称
   comm="\r\n"+symbol+comm;
 
//--- 使用注释在图表上显示信息
   Comment(comm);
  }

 


更新: 2015.12.03