CDouble & CDoubleVector - librería para MetaTrader 5

Librería para ejecutar los métodos comunes del redondeo utilizados en el desarrollo de las aplicaciones MQL, clase-envoltorio primitiva para los valores tipo double y vector para los objetos CDouble. ¡Está compatible con MQL5 y MQL4!

CDouble

La clase CDouble envuelve el valor del tipo primitivo double en el objeto. Además, esta clase proporciona varios métodos y métodos estáticos para redondear los números tipo double y los arrays/colecciones tipo double.

Descripción

class CDouble : public CObject

Encabezado

#include <Double.mqh>

Jerarquía de herencia

• CObject
  • CDouble

Métodos virtuales usados/redefinidos desde la clase CObject: Type, Load, Save, Compare.

El objeto tipo CDouble contiene cinco campos de datos:

string

m_symbol

double

m_value

uchar

m_step

uchar

m_digits

ENUM_PRECISION

m_mode

Antes de centrarnos en la documentación, vamos a mostrar un rápido ejemplo práctico de la clase del envoltorio (wrapper):

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   CDouble  price = tick.ask - 0.0087263487676283476,
            sl    = price - 500*_Point,
            tp    = price + 500*_Point,
            lots  = 5.25 / 3.78789;
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = price.AsRoundedTick();
   r.sl    = sl.AsRoundedTick();
   r.tp    = tp.AsRoundedTick();
   r.volume= lots.AsRoundedLots();
...

Es otro ejemplo con el uso de los métodos estáticos de la librería:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask - 0.0087263487676283476,
   r.sl    = price - 500*_Point,
   r.tp    = price + 500*_Point,
   r.volume= 5.25 / 3.78789;
   ...
   CDouble::RoundTradeRequest(r);
   // redondea automáticamente los campos del precio hasta el tamaño del tick
   // y el volumen hasta el paso del lote

Descripción breve de métodos estáticos

Nota: para usar esta librería, no es necesario conocer la POO o aplicar la instancia de la clase-envoltorio. Lo único que es necesario hacer, es llamar a las funciones estáticas con la resolución del contexto CDouble. La sintaxis es la siguiente:

type variable_name = CDouble::Method(args);

static bool

IsEqual
(double number1,
 double number2,
 double step);

static bool

IsEqual
(double number1,
 double number2,
 int digits);

static int

Compare
(double number1,
 double number2,
 double step)

static double

RoundToStep
(const double number, 
 double step)

static double

RoundToDigit
(const double number, 
 int digits)

static double

RoundToStepUp
(const double number, 
 double step)

static double

RoundToStepDown
(const double number, 
 double step)

static double

RoundToTick
(const double number, 
 string symbol=NULL)

static double

RoundToLots
(const double number,
 string symbol=NULL,
 bool always_return_valid=true)

static void (MQL5)

RoundTradeRequest
(MqlTradeRequest &request)

static void

RoundArrayToStep
(double &arr[],
 double step = NULL)

static void

RoundArrayToStep
(CArrayDouble &arr,
 double step = NULL)

static int

GetDigits
(double floating_point)

static double 

GetPoint
(int digits)

static string

ToString
(double number,
 int digits)

Ejemplos:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   double rnd_by_step   = CDouble::RoundToStep(tick.bid*1.052565465,_Point);
   double rnd_by_digits = CDouble::RoundToDigit(tick.bid*1.052565465,_Digits);
   double by_lot_step   = CDouble::RoundToLots(0.123423,_Symbol);
   double by_tick_size  = CDouble::RoundToTick(tick.ask-100*_Point,_Symbol);
   double roundup       = CDouble::RoundToStepUp(3.999999999,_Point);
   double rounddn       = CDouble::RoundToStepDown(3.999999999,_Point);
   int    digits        = CDouble::GetDigits(0.0000025);
   double point         = CDouble::GetPoint(10);
   bool   equal         = CDouble::IsEqual(tick.bid,tick.bid+0.00000009,_Point);
   string tostr         = CDouble::ToString(3.1399999999999999);
   int    compare       = CDouble::Compare(tick.ask,tick.bid);
   
#ifdef __MQL5__
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask+0.000089849847658759198199999;
   r.sl    = r.price - 503 * _Point;
   r.tp    = r.price + 503 * _Point;
   r.volume= 1.127984984;
   
   CDouble::RoundTradeRequest(r);
#endif 

Descripción breve del constructor

static double
(const ENUM_PRECISION mode = PRECISION_DEFAULT,
 const string symbol = NULL)

CDouble
(const CDouble &other)

Ejemplos:

CDouble num;
CDouble bid(PRECISION_TICK_SIZE, _Symbol);
CDouble ask(bid)
CDouble ask2 = bid;
CDouble lots(PRECISION_LOT_STEP, _Symbol);

Descripción breve de la asignación - Operadores sobrecargados de la asignación

void

Set(const double value)

void

Set(const CDouble &other)

void

Nota: el operador de la asignación = puede ser invocado en la misma línea que la declaración.

Ejemplos:

CDouble bid;
bid.Set(tick.bid);
CDouble ask = tick.ask;

CDouble pi = 3.14;
CDouble factor = 2;
pi*=factor;
Print(pi.ToString());
//6.28

Descripción breve de los operadores aritméticos sobrecargados

double

Nota: Sólo un operador aritmético puede usarse en cada instrucción.

Sintaxis de los operadores aritméticos sobrecargados:

type_double_result <-- CDouble_object <-- operator <-- double
// objeto tipo CDouble siempre se encuentra a la izquierda del operador

type_double_result <-- CDouble_object1 <-- operator <-- CDouble_object2
// cuando se usan dos objetos CDouble, la orden no importa.

Ejemplos:

CDouble foo    = 3.14;
CDouble bar    = 10;
CDouble foobar = bar + foo;          //13.14
CDouble err    = bar + foo + foobar; // error - uso inválido del operador

double var = bar / foo;

Descripción breve de los operadores de comparación sobrecargados

bool

Ejemplos:

CDouble foo = 3.14, bar = 3.139999999999999999999;
   
   Print(foo == bar); //true
   Print(foo <= bar); //true
   Print(foo >  bar); //false

Descripción breve del método de la instancia

Precisión del redondeo (por defecto): digits = 8; step = 1e-08

• Hay tres modos de controlar la precisión: Step, Digits o PrecisionMode(ENUM_PRECISION). La llamada a cualquiera de estos métodos redefine los ajustes anteriores.
• Step puede ser igual a _Point, LOT_STEP o TickSize; se representa como un número con coma flotante (por ejemplo, 0,00001, 0,025 etc.)
• No es necesario establecer el paso puesto que RoundToTick y RoundToLot usan automáticamente los pasos correspondientes para devolver el valor redondeado.

void

PrecisionMode
(const ENUM_PRECISION mode)

ENUM_PRECISION

PrecisionMode()

void

Step
(const double step_or_point)

double

Step()

void

Digits
(const int digits)

int

Digits()

double

AsRawDouble()

double

AsRounded()

double

AsRoundedUp()

double

AsRoundedDown()

double

AsRoundedTick()

double

AsRoundedLots
(bool always_return_valid = true)

int

ToInt()

long

ToLong()

string

ToStringPrecision()

string

ToString()

string

Symbol()

string

Symbol(const string symbol)

Ejemplos:

CDouble pi2 = 3.14159265359;
   
   // obtención del valor como... 
   double raw_double             = pi2.AsRawDouble();
   double round_double_to_step   = pi2.AsRounded();
   double tick_size_double       = pi2.AsRoundedTick();
   double lot_step_double        = pi2.AsRoundedLots();
   double rounded_up             = pi2.AsRoundedUp();
   double rounded_down           = pi2.AsRoundedDown();
   int    double_to_int          = pi2.ToInt();
   long   double_to_long         = pi2.ToLong();
   string precision_str          = pi2.ToStringPrecision();
   pi2 = 3.140000000009;
   pi2.Digits(8);
   string truncated_str          = pi2.ToString();

Descripción breve de métodos virtuales

Son los métodos redefinidos desde CObject:

virtual int

Compare
(const CObject *node,
 const int mode=0)

virtual int

Type()

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Vea los ejemplos en la sección CDoubleVector.

CDoubleVector

Clase CDoubleVector representa una colección de punteros a los objetos que sirve para las instancias dinámicas de CDouble.

Descripción

class CDoubleVector : public CArrayObj

Encabezado

#include <Double.mqh>

Jerarquía de herencia

• CObject
  • CArray
    • CArrayObj
      • CDoubleVector

Métodos virtuales usados/redefinidos desde la clase CArrayObj: CreateElement.

Descripción breve del método de la instancia

**Vea la descripción de los métodos públicos heredados en la página de CArrayObj.

CDouble*

operator[]
(const int index)

bool

Add(const double value)

bool

AssignDoubleArray
(const double &array[])

bool

CopyOut(double &arr[])

bool

CopyOut(CArrayDouble &arr)

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Ejemplos:

CDoubleVector *vect = new CDoubleVector;
   
   double dubs[]={3.14,1.21,55.555};
   vect.AssignDoubleArray(dubs);
   vect.Add(tick.bid);
   
   // llamada al objeto CDouble por el índice
   Print(vect[vect.Total()-1].ToString());
   
   // добавление нового объекта CDouble
   CDouble *lot = new CDouble(PRECISION_LOT_STEP);
   lot = 1.22;
   vect.Add(lot);
   
   // ordenamiento del vector en orden ascendiente
   vect.Sort();
   
   int total = vect.Total();
   
   // guardado del vector en el archivo incluyendo los estados y los valores de objetos CDouble
   string f = "testdub.bin";
   int    h = FileOpen(f,FILE_WRITE|FILE_BIN);
   if(vect.Save(h))
      Print("save successful");
   FileClose(h);
   delete vect;
   
   // cargando el vector desde el archivo
   CDoubleVector vect_reborn;
   h=FileOpen(f,FILE_READ|FILE_BIN);
   if(vect_reborn.Load(h))
      Print("load successful");
   FileClose(h);
   total = vect_reborn.Total();
   Print("Total vector size = ",sizeof(vect_reborn)," bytes");
   for(int i=0;i<vect_reborn.Total();i++)
      Print(vect_reborn[i].ToString());
      
   // copiando al array double
   double arr2[];
   vect_reborn.CopyOut(arr2);
   Print(ArraySize(arr2));