CDouble & CDoubleVector - библиотека для MetaTrader 5

Библиотека для проведения общих методов округления, используемых в разработке MQL-приложений, примитивный класс-оболочка для значений типа double и вектор для объектов CDouble. Совместима с MQL5 и MQL4!

CDouble

Класс CDouble обертывает значение примитивного типа double в объект. Кроме того, этот класс предоставляет несколько методов и статических методов для округления чисел типа double и массивов/коллекций типа double.

Описание

class CDouble : public CObject

Заголовок

#include <Double.mqh>

Иерархия наследования

• CObject
  • CDouble

Виртуальные методы, используемые/переопределенные из класса CObject: Type, Load, Save, Compare.

Объект типа CDouble содержит пять полей данных:

string

m_symbol

double

m_value

uchar

m_step

uchar

m_digits

ENUM_PRECISION

m_mode

Прежде чем углубиться в документацию, рассмотрим быстрый практический пример класса оболочки:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   CDouble  price = tick.ask - 0.0087263487676283476,
            sl    = price - 500*_Point,
            tp    = price + 500*_Point,
            lots  = 5.25 / 3.78789;
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = price.AsRoundedTick();
   r.sl    = sl.AsRoundedTick();
   r.tp    = tp.AsRoundedTick();
   r.volume= lots.AsRoundedLots();
...

Другой пример с использованием статических методов библиотеки:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask - 0.0087263487676283476,
   r.sl    = price - 500*_Point,
   r.tp    = price + 500*_Point,
   r.volume= 5.25 / 3.78789;
   ...
   CDouble::RoundTradeRequest(r);
   // автоматически округляет поля цены до размера тика
   // и объем до шага лота

Краткое описание статических методов

Примечание: для использования этой библиотеки не требуется знание ООП или применение экземпляра класса-оболочки. Все, что нужно сделать, это вызвать статические функции с разрешением контекста CDouble. Синтаксис выглядит следующим образом:

type variable_name = CDouble::Method(args);

static bool

IsEqual
(double number1,
 double number2,
 double step);

static bool

IsEqual
(double number1,
 double number2,
 int digits);

static int

Compare
(double number1,
 double number2,
 double step)

static double

RoundToStep
(const double number, 
 double step)

static double

RoundToDigit
(const double number, 
 int digits)

static double

RoundToStepUp
(const double number, 
 double step)

static double

RoundToStepDown
(const double number, 
 double step)

static double

RoundToTick
(const double number, 
 string symbol=NULL)

static double

RoundToLots
(const double number,
 string symbol=NULL,
 bool always_return_valid=true)

static void (MQL5)

RoundTradeRequest
(MqlTradeRequest &request)

static void

RoundArrayToStep
(double &arr[],
 double step = NULL)

static void

RoundArrayToStep
(CArrayDouble &arr,
 double step = NULL)

static int

GetDigits
(double floating_point)

static double 

GetPoint
(int digits)

static string

ToString
(double number,
 int digits)

Примеры:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   double rnd_by_step   = CDouble::RoundToStep(tick.bid*1.052565465,_Point);
   double rnd_by_digits = CDouble::RoundToDigit(tick.bid*1.052565465,_Digits);
   double by_lot_step   = CDouble::RoundToLots(0.123423,_Symbol);
   double by_tick_size  = CDouble::RoundToTick(tick.ask-100*_Point,_Symbol);
   double roundup       = CDouble::RoundToStepUp(3.999999999,_Point);
   double rounddn       = CDouble::RoundToStepDown(3.999999999,_Point);
   int    digits        = CDouble::GetDigits(0.0000025);
   double point         = CDouble::GetPoint(10);
   bool   equal         = CDouble::IsEqual(tick.bid,tick.bid+0.00000009,_Point);
   string tostr         = CDouble::ToString(3.1399999999999999);
   int    compare       = CDouble::Compare(tick.ask,tick.bid);
   
#ifdef __MQL5__
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask+0.000089849847658759198199999;
   r.sl    = r.price - 503 * _Point;
   r.tp    = r.price + 503 * _Point;
   r.volume= 1.127984984;
   
   CDouble::RoundTradeRequest(r);
#endif 

Краткое описание конструктора

CDouble
(const ENUM_PRECISION mode = PRECISION_DEFAULT,
 const string symbol = NULL)

CDouble
(const CDouble &other)

Примеры:

CDouble num;
CDouble bid(PRECISION_TICK_SIZE, _Symbol);
CDouble ask(bid)
CDouble ask2 = bid;
CDouble lots(PRECISION_LOT_STEP, _Symbol);

Краткое описание присваивания - Перегруженные операторы присваивания

void

Set(const double value)

void

Set(const CDouble &other)

void

Примечание: оператор присваивания = можно вызывать в той же строке, что и объявление.

Примеры:

CDouble bid;
bid.Set(tick.bid);
CDouble ask = tick.ask;

CDouble pi = 3.14;
CDouble factor = 2;
pi*=factor;
Print(pi.ToString());
//6.28

Краткое описание перегруженных арифметических операторов

double

Примечание: В каждой инструкции может использоваться только один арифметический оператор.

Синтаксис для перегруженных арифметических операторов:

type_double_result <-- CDouble_object <-- operator <-- double
// объект типа CDouble всегда стоит с левой стороны оператора

type_double_result <-- CDouble_object1 <-- operator <-- CDouble_object2
// при использовании двух объектов CDouble порядок не имеет значения.

Примеры:

CDouble foo    = 3.14;
CDouble bar    = 10;
CDouble foobar = bar + foo;          //13.14
CDouble err    = bar + foo + foobar; // ошибка - недопустимое использование оператора

double var = bar / foo;

Краткое описание перегруженных операторов сравнения

bool

Примеры:

CDouble foo = 3.14, bar = 3.139999999999999999999;
   
   Print(foo == bar); //true
   Print(foo <= bar); //true
   Print(foo >  bar); //false

Краткое описание метода экземпляра

Точность округления (по умолчанию): digits = 8; step = 1e-08

• Имеется три способа контроля точности: Step, Digits или PrecisionMode(ENUM_PRECISION). Вызов любой из этих методов переопределяет предыдущие настройки.
• Step может быть равен _Point, LOT_STEP или TickSize; представлен в виде числа с плавающей запятой (например, 0.00001, 0.025 и т.д.)
• Нет необходимости устанавливать шаг, поскольку RoundToTick и RoundToLot автоматически используют соответствующие значения шага для возврата округленного значения.

void

PrecisionMode
(const ENUM_PRECISION mode)

ENUM_PRECISION

PrecisionMode()

void

Step
(const double step_or_point)

double

Step()

void

Digits
(const int digits)

int

Digits()

double

AsRawDouble()

double

AsRounded()

double

AsRoundedUp()

double

AsRoundedDown()

double

AsRoundedTick()

double

AsRoundedLots
(bool always_return_valid = true)

int

ToInt()

long

ToLong()

string

ToStringPrecision()

string

ToString()

string

Symbol()

string

Symbol(const string symbol)

Примеры:

CDouble pi2 = 3.14159265359;
   
   // получение значения в виде... 
   double raw_double             = pi2.AsRawDouble();
   double round_double_to_step   = pi2.AsRounded();
   double tick_size_double       = pi2.AsRoundedTick();
   double lot_step_double        = pi2.AsRoundedLots();
   double rounded_up             = pi2.AsRoundedUp();
   double rounded_down           = pi2.AsRoundedDown();
   int    double_to_int          = pi2.ToInt();
   long   double_to_long         = pi2.ToLong();
   string precision_str          = pi2.ToStringPrecision();
   pi2 = 3.140000000009;
   pi2.Digits(8);
   string truncated_str          = pi2.ToString();

Краткое описание виртуальных методов

Методы, переопределенные из CObject:

virtual int

Compare
(const CObject *node,
 const int mode=0)

virtual int

Type()

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Примеры приведены в разделе CDoubleVector.

CDoubleVector

Класс CDoubleVector представляет собой коллекцию указателей на объекты, предназначенный для динамических экземпляров CDouble.

Описание

class CDoubleVector : public CArrayObj

Заголовок

#include <Double.mqh>

Иерархия наследования

• CObject
  • CArray
    • CArrayObj
      • CDoubleVector

Виртуальные методы, используемые/переопределенные из класса CArrayObj: CreateElement.

Краткое описание метода экземпляра

**Описание унаследованных публичных методов смотрите на странице CArrayObj.

CDouble*

operator[]
(const int index)

bool

Add(const double value)

bool

AssignDoubleArray
(const double &array[])

bool

CopyOut(double &arr[])

bool

CopyOut(CArrayDouble &arr)

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Примеры:

CDoubleVector *vect = new CDoubleVector;
   
   double dubs[]={3.14,1.21,55.555};
   vect.AssignDoubleArray(dubs);
   vect.Add(tick.bid);
   
   // вызов объекта CDouble по индексу
   Print(vect[vect.Total()-1].ToString());
   
   // добавление нового объекта CDouble
   CDouble *lot = new CDouble(PRECISION_LOT_STEP);
   lot = 1.22;
   vect.Add(lot);
   
   // сортировка вектора по возрастанию
   vect.Sort();
   
   int total = vect.Total();
   
   // сохранение вектора в файл, включая состояния и значения объектов CDouble
   string f = "testdub.bin";
   int    h = FileOpen(f,FILE_WRITE|FILE_BIN);
   if(vect.Save(h))
      Print("save successful");
   FileClose(h);
   delete vect;
   
   // загрузка вектора из файла
   CDoubleVector vect_reborn;
   h=FileOpen(f,FILE_READ|FILE_BIN);
   if(vect_reborn.Load(h))
      Print("load successful");
   FileClose(h);
   total = vect_reborn.Total();
   Print("Total vector size = ",sizeof(vect_reborn)," bytes");
   for(int i=0;i<vect_reborn.Total();i++)
      Print(vect_reborn[i].ToString());
      
   // копирование в массив double
   double arr2[];
   vect_reborn.CopyOut(arr2);
   Print(ArraySize(arr2));