CDouble & CDoubleVector - MetaTrader 5程序库

用于 MQL 开发的常用舍入方法函数库，用于类型 (double) 的元初包装类和 CDouble 对象的向量。 MQL5 和 MQL4 兼容！

CDouble

CDouble 类在对象中包装元初类型 double 的值。 此外，该类为 舍入双精度 和双精度类型的数组/集合提供了 若干种方法 和静态方法。

声明

class CDouble : public CObject

标题

#include <Double.mqh>

继承层次结构

• CObject
  • CDouble

虚拟方法从 CObject 类: Type，Load，Save，Compare 实现/覆盖的。

类型为 CDouble 的对象包含五个数据字段:

string

m_symbol

double

m_value

uchar

m_step

uchar

m_digits

ENUM_PRECISION

m_mode

在我们进一步深入研究文档之前，这里有一个包装类的快速实际示例:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   CDouble  price = tick.ask - 0.0087263487676283476,
            sl    = price - 500*_Point,
            tp    = price + 500*_Point,
            lots  = 5.25 / 3.78789;
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = price.AsRoundedTick();
   r.sl    = sl.AsRoundedTick();
   r.tp    = tp.AsRoundedTick();
   r.volume= lots.AsRoundedLots();
...

另一个使用静态库方法的示例:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask - 0.0087263487676283476,
   r.sl    = price - 500*_Point,
   r.tp    = price + 500*_Point,
   r.volume= 5.25 / 3.78789;
   ...
   CDouble::RoundTradeRequest(r);
   //自动将价格字段舍入为逐笔尺寸
   //和交易量步幅

静态方法摘要

注意: 使用此函数库时没有必要了解 OOP 或使用一个包装类实例。 所有人要做的就是用 CD25 范解析调用静态函数。 语法如下:

type variable_name = CDouble::Method(args);

static bool

IsEqual
(double number1,
 double number2,
 double step);

static bool

IsEqual
(double number1,
 double number2,
 int digits);

static int

Compare
(double number1,
 double number2,
 double step)

static double

RoundToStep
(const double number, 
 double step)

static double

RoundToDigit
(const double number, 
 int digits)

static double

RoundToStepUp
(const double number, 
 double step)

static double

RoundToStepDown
(const double number, 
 double step)

static double

RoundToTick
(const double number, 
 string symbol=NULL)

static double

RoundToLots
(const double number,
 string symbol=NULL,
 bool always_return_valid=true)

static void (MQL5)

RoundTradeRequest
(MqlTradeRequest &request)

static void

RoundArrayToStep
(double &arr[],
 double step = NULL)

static void

RoundArrayToStep
(CArrayDouble &arr,
 double step = NULL)

static int

GetDigits
(double floating_point)

static double 

GetPoint
(int digits)

static string

ToString
(double number,
 int digits)

示例:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   double rnd_by_step   = CDouble::RoundToStep(tick.bid*1.052565465,_Point);
   double rnd_by_digits = CDouble::RoundToDigit(tick.bid*1.052565465,_Digits);
   double by_lot_step   = CDouble::RoundToLots(0.123423,_Symbol);
   double by_tick_size  = CDouble::RoundToTick(tick.ask-100*_Point,_Symbol);
   double roundup       = CDouble::RoundToStepUp(3.999999999,_Point);
   double rounddn       = CDouble::RoundToStepDown(3.999999999,_Point);
   int    digits        = CDouble::GetDigits(0.0000025);
   double point         = CDouble::GetPoint(10);
   bool   equal         = CDouble::IsEqual(tick.bid,tick.bid+0.00000009,_Point);
   string tostr         = CDouble::ToString(3.1399999999999999);
   int    compare       = CDouble::Compare(tick.ask,tick.bid);
   
#ifdef __MQL5__
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask+0.000089849847658759198199999;
   r.sl    = r.price - 503 * _Point;
   r.tp    = r.price + 503 * _Point;
   r.volume= 1.127984984;
   
   CDouble::RoundTradeRequest(r);
#endif 

构造函数摘要

CDouble
(const ENUM_PRECISION mode = PRECISION_DEFAULT,
 const string symbol = NULL)

CDouble
(const CDouble &other)

示例:

CDouble num;
CDouble bid(PRECISION_TICK_SIZE, _Symbol);
CDouble ask(bid)
CDouble ask2 = bid;
CDouble lots(PRECISION_LOT_STEP, _Symbol);

赋值摘要 - 重载的赋值运算符

void

Set(const double value)

void

Set(const CDouble &other)

void

注意: 赋值符 = 可以在声明的同一行调用。

示例:

CDouble bid;
bid.Set(tick.bid);
CDouble ask = tick.ask;

CDouble pi = 3.14;
CDouble factor = 2;
pi*=factor;
Print(pi.ToString());
//6.28

重载的算术运算符摘要

double

注意: 仅 一个 算术运算符可以用于每条语句。

运算符算术重载的语法:

type_double_result <-- CDouble_object <-- operator <-- double
//CDouble 对象始终位于操作符的左侧

type_double_result <-- CDouble_object1 <-- operator <-- CDouble_object2
//使用两个 CDouble 对象时顺序无关紧要。

示例:

CDouble foo    = 3.14;
CDouble bar    = 10;
CDouble foobar = bar + foo;          //13.14
CDouble err    = bar + foo + foobar; //错误 - 非法使用操作符

double var = bar / foo;

重载比较运算符摘要

bool

示例:

CDouble foo = 3.14, bar = 3.139999999999999999999;
   
   Print(foo == bar); //true
   Print(foo <= bar); //true
   Print(foo >  bar); //false

实例方法摘要

精度控制 (默认): 小数位 = 8; 步幅 = 1e-08

• 控制精度有三种方法: Step, Digits, 或 PrecisionMode(ENUM_PRECISION)。 对这两种 setter 方法的任何调用都将覆盖以前的设置。
• Step 即可为 _Point 亦或 LOT_STEP 或 TickSize; 表示为浮点数 (即 0.00001, 0.025, 等等)。
• 由于 RoundToTick 和 RoundToLot 自动使用相应的步幅值进行舍入返回，因此无需设置步幅。

void

PrecisionMode
(const ENUM_PRECISION mode)

ENUM_PRECISION

PrecisionMode()

void

Step
(const double step_or_point)

double

Step()

void

Digits
(const int digits)

int

Digits()

double

AsRawDouble()

double

AsRounded()

double

AsRoundedUp()

double

AsRoundedDown()

double

AsRoundedTick()

double

AsRoundedLots
(bool always_return_valid = true)

int

ToInt()

long

ToLong()

string

ToStringPrecision()

string

ToString()

string

Symbol()

string

Symbol(const string symbol)

示例:

CDouble pi2 = 3.14159265359;
   
   // 获得数值...... 
   double raw_double             = pi2.AsRawDouble();
   double round_double_to_step   = pi2.AsRounded();
   double tick_size_double       = pi2.AsRoundedTick();
   double lot_step_double        = pi2.AsRoundedLots();
   double rounded_up             = pi2.AsRoundedUp();
   double rounded_down           = pi2.AsRoundedDown();
   int    double_to_int          = pi2.ToInt();
   long   double_to_long         = pi2.ToLong();
   string precision_str          = pi2.ToStringPrecision();
   pi2 = 3.140000000009;
   pi2.Digits(8);
   string truncated_str          = pi2.ToString();

虚方法摘要

从 CObject 覆盖的方法:

virtual int

Compare
(const CObject *node,
 const int mode=0)

virtual int

Type()

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

有关示例，请参阅下面的 CDoubleVector。

CDoubleVector

CDoubleVector 类是专门用于 CDouble 动态实例的对象指针集合。

声明

class CDoubleVector : public CArrayObj

标题

#include <Double.mqh>

继承层次结构

• CObject
  • CArray
    • CArrayObj
      • CDoubleVector

来自类 CArrayObj 中 实现/覆盖 的虚拟方法: CreateElement.

实例方法摘要

**参阅 CArrayObj 对于继承的公有方法。

CDouble*

operator[]
(const int index)

bool

Add(const double value)

bool

AssignDoubleArray
(const double &array[])

bool

CopyOut(double &arr[])

bool

CopyOut(CArrayDouble &arr)

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

示例:

CDoubleVector *vect = new CDoubleVector;
   
   double dubs[]={3.14,1.21,55.555};
   vect.AssignDoubleArray(dubs);
   vect.Add(tick.bid);
   
   //按照索引调用 CDouble 对象
   Print(vect[vect.Total()-1].ToString());
   
   //添加一个新的 CDouble 对象
   CDouble *lot = new CDouble(PRECISION_LOT_STEP);
   lot = 1.22;
   vect.Add(lot);
   
   //矢量升序排序
   vect.Sort();
   
   int total = vect.Total();
   
   //将向量保存到文件，包括 CDouble 对象状态和值
   string f = "testdub.bin";
   int    h = FileOpen(f,FILE_WRITE|FILE_BIN);
   if(vect.Save(h))
      Print("save successful");
   FileClose(h);
   delete vect;
   
   //从文件加载矢量
   CDoubleVector vect_reborn;
   h=FileOpen(f,FILE_READ|FILE_BIN);
   if(vect_reborn.Load(h))
      Print("load successful");
   FileClose(h);
   total = vect_reborn.Total();
   Print("Total vector size = ",sizeof(vect_reborn)," bytes");
   for(int i=0;i<vect_reborn.Total();i++)
      Print(vect_reborn[i].ToString());
      
   //复制到双精度数组
   double arr2[];
   vect_reborn.CopyOut(arr2);
   Print(ArraySize(arr2));