下载MetaTrader 5

DRAW_FILLING

DRAW_FILLING 样式在两个指标缓冲区之间标图颜色区域。实际上,该样式绘制两条线,以指定颜色二选一,填充它们之间的空间。它用于创建绘制通道的指标。缓冲区不会只包含空值,因为在这种情况下,不会标图。

您可以设置两种填充颜色:

  • 第一个颜色用于第一个缓冲区的值比第二个指标缓冲区的值大的区域;
  • 第二个颜色用于第二个缓冲区的值大于第一个指标缓冲区的值大的区域。

填充颜色的设置可以使用 编译程序指令 或动态使用PlotIndexSetInteger() 函数。动态改变标图属性允许 "激活" 指标,以便于可以根据当前状况改变其外观。

该指标用于计算所有的柱,因此两个指标缓冲区的值既不等于0也不等于空值。若要指定哪个值应被视为“空”,请在 PLOT_EMPTY_VALUE 属性设定该值:

   #define INDICATOR_EMPTY_VALUE -1.0
   ...
//--- INDICATOR_EMPTY_VALUE (空值) 将不参与计算 
   PlotIndexSetDouble (DRAW_FILLING_creation_index,PLOT_EMPTY_VALUE,INDICATOR_EMPTY_VALUE);

不参与指标计算的柱形绘制将取决于指标缓冲区的值:

  • 两个指标缓冲区的值都等于0的柱形,不参与绘制指标。这意味着零值的区域不填充。

DRAW_FILLING_without_drawing

  • 指标缓冲区的值等于"空值"的柱形,参与绘制指标。空值区域将被填充,以便连接有重要值的区域。

DRAW_FILLING_with_drawing

应该注意,如果"空值"等于零,不参与指标计算的柱形也会被填充。

标图DRAW_FILLING 所需的缓冲区的数量是 2。

在独立窗口以不同的平均周期在两个MAs之间绘制通道的指标示例。在移动平均数视觉交叉的颜色变化显示了向上向下趋势的变化。每N 个订单号都会随机变化一次颜色。 N 参数设置在指标的 外部参数 ,使手动配置成为可能(指标属性窗口的参数标签)。

DRAW_FILLING

请注意,最初DRAW_FILLING属性的plot1 使用编译程序指令#property设置,然后在 OnCalculate()函数新颜色随机设置。

//+------------------------------------------------------------------+
//|                                                 DRAW_FILLING.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "An indicator to demonstrate DRAW_FILLING"
#property description "It draws a channel between two MAs in a separate window"
#property description "The fill color is changed randomly"
#property description "after every N ticks"
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   1
//--- 标图交集
#property indicator_label1  "Intersection"
#property indicator_type1   DRAW_FILLING
#property indicator_color1  clrRed,clrBlue
#property indicator_width1  1
//--- 输入参数
input int      Fast=13;          // 快速MA的周期
input int      Slow=21;          // 慢速MA的周期
input int      shift=1;          // 向未来的MAs转移(正值)
input int      N=5;              // 改变订单号数量 
//--- 指标缓冲区
double         IntersectionBuffer1[];
double         IntersectionBuffer2[];
int fast_handle;
int slow_handle;
//--- 存储颜色的数组0到5的
color colors[]={clrRed,clrBlue,clrGreen,clrAquamarine,clrBlanchedAlmond,clrBrown,clrCoral,clrDarkSlateGray};
//+------------------------------------------------------------------+
//| 自定义指标初始化函数                                                |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- 指标缓冲区映射
   SetIndexBuffer(0,IntersectionBuffer1,INDICATOR_DATA);
   SetIndexBuffer(1,IntersectionBuffer2,INDICATOR_DATA);
//---
   PlotIndexSetInteger(0,PLOT_SHIFT,shift);
//---
   fast_handle=iMA(_Symbol,_Period,Fast,0,MODE_SMA,PRICE_CLOSE);
   slow_handle=iMA(_Symbol,_Period,Slow,0,MODE_SMA,PRICE_CLOSE);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| 自定义指标迭代函数                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- 计算订单号改变样式,颜色和线型宽度
   ticks++;
//--- 如果足够数量的订单号被积累
   if(ticks>=N)
     {
      //--- 改变线型属性
      ChangeLineAppearance();
      //--- 重置0计数器
      ticks=0;
     }
 
//--- 指标的第一次计算,或数据变化,需要一次完全重新计算
   if(prev_calculated==0)
     {
      //--- 复制所有指标值至相应的缓冲区
      int copied1=CopyBuffer(fast_handle,0,0,rates_total,IntersectionBuffer1);
      int copied2=CopyBuffer(slow_handle,0,0,rates_total,IntersectionBuffer2);
     }
   else // 仅填充那些更新的数据
     {
      //--- 获得OnCalculate()当前和之前启动之间的柱形不同
      int to_copy=rates_total-prev_calculated;
      //--- 如果没有不同,我们仍然会复制一个值 - 在零柱
      if(to_copy==0) to_copy=1;
      //--- 复制_copy 值到指标缓冲区的最末端
      int copied1=CopyBuffer(fast_handle,0,0,to_copy,IntersectionBuffer1);
      int copied2=CopyBuffer(slow_handle,0,0,to_copy,IntersectionBuffer2);
     }
//--- 返回 prev_calculated值以便下次调用函数
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| 改变通道填充颜色                                                   |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- 形成线型属性信息的字符串
   string comm="";
//--- 改变线型颜色的模块
   int number=MathRand(); // 获得随机数
//--- 除数等于colors[]数组的大小
   int size=ArraySize(colors);
 
//--- 获得选择新颜色作为整数除法余数的标引
   int color_index1=number%size;
//--- 设置第一个颜色为PLOT_LINE_COLOR 属性
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,0,colors[color_index1]);
//--- 写下第一个颜色
   comm=comm+"\r\nColor1 "+(string)colors[color_index1];
 
//--- 获得选择新颜色作为整数除法余数的标引
   number=MathRand(); // 获得随机数
   int color_index2=number%size;
//--- 设置第二个颜色为PLOT_LINE_COLOR 属性
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,colors[color_index2]);
//---写下第二个颜色
   comm=comm+"\r\nColor2 "+(string)colors[color_index2];
//--- 使用注释在图表上显示信息
   Comment(comm);
  }

 


更新: 2015.12.03