MQL5 リファレンスカスタム指標指標スタイルの例DRAW_COLOR_ARROW

DRAW_COLOR_ARROW

DRAW_COLOR_ARROW スタイルは指標バッファの値に基づいて色付きの矢印（ Wingdings フォントシンボルのセットを描画します。このスタイルでは DRAW_ARROW と異なり各シンボルのindicator_color1 プロパティで指定された色の所定のセットでの色の設定が可能です。

シンボルの幅と色は DRAW_ARROW スタイルの様にコンパイラディレクティブまたは動的に PlotIndexSetInteger() 関数を使用して指定することが出来ます。プロットプロパティの動的な変更は、現在の状況に基づいての指標の外観の変更を可能にします。

シンボルコードは PLOT_ARROW プロパティを使用して設定されます。

//--- PLOT_ARROW の描画のためにWingdings フォントからのシンボルコードを定義する
PlotIndexSetInteger(0,PLOT_ARROW,code);

PLOT_ARROW=159（丸）がデフォルトです。

矢印は、実際には、高さとアンカーポイントを持つシンボルであり、チャート上のいくつかの重要な情報（例えばバーの終値）をカバーすることが出来ます。従って、チャートの規模に依存しないピクセル単位での垂直シフトの指定が可能です。指標値はそのままですが、矢印が特定のピクセル数だけ下に移動します。

//--- 矢印の垂直シフトをピクセル単位で設定する
PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);

PLOT_ARROW_SHIFT の負の値は矢印の上向きのシフト、正の値は矢印の下向きのシフトを意味します。

DRAW_COLOR_ARROW スタイルはチャートの別々のサブウィンドウとメインウィンドウで使用することが出来ます。空の値は描画されず「データウィンドウ」に表示されません。指標バッファ内の全ての値は明示的に設定する必要があります。バッファはゼロで初期化されません。

//--- 空の値を設定
PlotIndexSetDouble(DRAW_COLOR_ARROW_plot_index,PLOT_EMPTY_VALUE,0);

DRAW_COLOR_ARROW のプロットに必要なバッファの数は 2 です。

（PLOT_ARROW_SHIFT プロパティで指定されたピクセル単位でのシフトとともに）記号を描画するために使用される価格の値を格納するバッファ
矢印の描画に使用されるカラーインデックスを格納するバッファ（空値以外が必要）

前のバーの終値よりも高い終値で各足の矢印を描画する指標の例です。矢印の幅、シフトとシンボルコードは全て N ティックごとにランダムに変更されます。記号の色は、描画されたバーの数に依存します。

DRAW_COLOR_ARROW スタイルの例

この例では、DRAW_COLOR_ARROW スタイルを持つplot1 では、プロパティ、色とサイズは #property コンパイラディレクティブを使用して指定され、プロパティは OnCalculate() 関数でランダムに設定されます。N パラメータは手動設定の可能性を持って（指標の「プロパティ」ウィンドウの「パラメータ」タブ）指標外部パラメータに設定されています。

初めに8つの色が #property コンパイラディレクティブによって指定された後、OnCalculate() 関数で、colors[] 配列に格納された 14の色からランダムに設定されることにご注意ください。

//+------------------------------------------------------------------+
//| DRAW_COLOR_ARROW.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"

#property description "An indicator to demonstrate DRAW_COLOR_ARROW"
#property description "Draws different-color arrows set by Unicode characters, on a chart"
#property description "The color, size, shift and symbol code of the arrow are changed"
#property description " randomly every N ticks"
#property description "The code parameter sets the base value: code=159 (a circle)"

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots 1
//--- ColorArrowt をプロットする
#property indicator_label1 "ColorArrow"
#property indicator_type1 DRAW_COLOR_ARROW
//--- ヒストグラムを塗るために（特殊な配列に格納されている）8 色を定義する
#property indicator_color1 clrRed,clrBlue,clrSeaGreen,clrGold,clrDarkOrange,clrMagenta,clrYellowGreen,clrChocolate
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1

//--- 入力パラメータ
input int N=5; // 変化をもたらすティックの数
input ushort code=159; // DRAW_ARROW で描画するシンボルコード
int color_sections;
//--- プロットの指標バッファ
double ColorArrowBuffer[];
//--- カラーインデックを格納するバッファ
double ColorArrowColors[];
//--- 色を格納する14 要素の配列
color colors[]=
{
clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
};
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 指標バッファマッピング
SetIndexBuffer(0,ColorArrowBuffer,INDICATOR_DATA);
SetIndexBuffer(1,ColorArrowColors,INDICATOR_COLOR_INDEX);
//--- PLOT_ARROW の描画のためにシンボルコードを定義する
PlotIndexSetInteger(0,PLOT_ARROW,code);
//--- 矢印の垂直シフトをピクセル単位で設定する
PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,5);
//--- 空の値の 0 を設定
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//----正弦波を塗る色の数
color_sections=8; // #property indicator_color1 のコメントを参照
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| カスタム指標の反復関数 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 矢印の色、大きさ、及びシフトコードを変更するティックを計算する
ticks++;
//--- 充分なティックの数が蓄積されている場合
if(ticks>=N)
{
//--- 矢印プロパティを変更する
ChangeLineAppearance();
//--- ヒストグラムを描画する色を変更する
ChangeColors(colors,color_sections);
//--- ティックカウンタをゼロにリセットする
ticks=0;
}

//--- 指標安倍を計算するブロック
int start=1;
if(prev_calculated>0) start=prev_calculated-1;
//--- 計算ループ
for(int i=1;i<rates_total;i++)
{
//--- 現在の終値が以前の終値より高い場合、矢印を描画する
if(close[i]>close[i-1])
ColorArrowBuffer[i]=close[i];
//--- さもなければ null を指定する
else
ColorArrowBuffer[i]=0;
//--- 矢印の色
int index=i%color_sections;
ColorArrowColors[i]=index;
}
//--- 次の呼び出しのために prev_calculated の値を返す
return(rates_total);
}
//+------------------------------------------------------------------+
//| 線分の色を変更する |
//+------------------------------------------------------------------+
void ChangeColors(color &cols[],int plot_colors)
{
//--- 色の数
int size=ArraySize(cols);
//---
string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";

//--- それぞれのカラーインデックに新しい色をランダムに定義する
for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
{
//--- 乱数を取得
int number=MathRand();
//--- 整数除算の余りから col[] 配列のインデックスを取得
int i=number%size;
//--- 各インデックスの色をPLOT_LINE_COLOR として設定する
PlotIndexSetInteger(0, // グラフィックスタイルの番号
PLOT_LINE_COLOR, // プロパティの識別子
plot_color_ind, // 色を書き込む色インデックス
cols[i]); // 新しい色
//--- 色を書く
comm=comm+StringFormat("ArrowColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
ChartSetString(0,CHART_COMMENT,comm);
}
//---
}
//+------------------------------------------------------------------+
//| 指標に表示された線の外観を変更する |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- 線のプロパティに関する情報を形成するための文字列
string comm="";
//--- 線の幅を変更するブロック
int number=MathRand();
//--- 整数除算の余りの幅を取得
int width=number%5; // 幅は 0〜4 に設定される
//--- 色を PLOT_LINE_WIDTH プロパティに設定
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 線の幅を書く
comm=comm+" Width="+IntegerToString(width);

//--- 矢印のコードを変更するブロック（PLOT_ARROW）
number=MathRand();
//--- 矢印の新しいコードを計算するために、整数の除算の剰余を取得（０〜１９）
int code_add=number%20;
//--- 新しいシンボルコードをcode+code_add に設定
PlotIndexSetInteger(0,PLOT_ARROW,code+code_add);
//--- PLOT_ARROW シンボルコードを書く
comm="\r\n"+"PLOT_ARROW="+IntegerToString(code+code_add)+comm;

//--- 矢印の垂直シフトをピクセル単位で変更するブロック
number=MathRand();
//--- 整数除算の余りとしてシフトを取得
int shift=20-number%41;
//--- 新しいシフトを設定
PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);
//--- PLOT_ARROW_SHIFT シフトを書く
comm="\r\n"+"PLOT_ARROW_SHIFT="+IntegerToString(shift)+comm;

//--- コメントを使用して、チャート上の情報を表示する
Comment(comm);
}

DRAW_COLOR_HISTOGRAM2

DRAW_COLOR_ZIGZAG