//+--------------------------------------------------------------------------------+
//| DRAW_COLOR_ARROW.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+--------------------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Un indicatore per mostrare DRAW_COLOR_ARROW"
#property description "Disegna varie frecce-colore impostate da caratteri Unicode, su un grafico"
#property description "Il colore, grandezza, slittamento e codice del simbolo delle frecce vengono cambiati"
#property description "dinamicamente ogni N ticks"
#property description "Il parametro code imposta il valore base: code=159 (un cerchio)"
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots 1
//--- plot ColorArrow
#property indicator_label1 "ColorArrow"
#property indicator_type1 DRAW_COLOR_ARROW
//--- Definisce 8 colori per colorare l'istogramma in base ai giorni della settimana (che sono memorizzati nell'array speciale)
#property indicator_color1 clrRed,clrBlue,clrSeaGreen,clrGold,clrDarkOrange,clrMagenta,clrYellowGreen,clrChocolate
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- parametri di input
input int N=5; // Numero di ticks da cambiare
input ushort code=159; // Codice simbolo da disegnare in DRAW_ARROW
int color_sections;
//--- Un buffer indicatore per il disegno
double ColorArrowBuffer[];
//--- Un buffer per memorizzare gli indici di colore
double ColorArrowColors[];
//--- Un array per memorizzare i colori contiene 14 elementi
color colors[]=
{
clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
};
//+--------------------------------------------------------------------------------+
//| Funzione di inizializzazione Indicatore Personalizzato |
//+--------------------------------------------------------------------------------+
int OnInit()
{
//--- mappatura buffers indicatore
SetIndexBuffer(0,ColorArrowBuffer,INDICATOR_DATA);
SetIndexBuffer(1,ColorArrowColors,INDICATOR_COLOR_INDEX);
//--- Definisce il codice simbolo per il disegnamento in PLOT_ARROW
PlotIndexSetInteger(0,PLOT_ARROW,code);
//--- Imposta lo spostamento verticale di frecce in pixel
PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,5);
//--- Imposta come un valore vuoto 0
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---- Il numero di colori per colorare la sinusoide
color_sections=8; // vedere il commento di #property indicator_color1
//---
return(INIT_SUCCEEDED);
}
//+--------------------------------------------------------------------------------+
//| Funzione di iterazione indicatore personalizato |
//+--------------------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- Calcola i ticks per cambiare il colore, la grandezza , slittamento e codice della freccia
ticks++;
//--- Se un numero critico di ticks è stato accumulato
if(ticks>=N)
{
//--- Cambia le proprietà delle frecce
ChangeLineAppearance();
//--- Cambia i colori usati per disegnare l'istogramma
ChangeColors(colors,color_sections);
//--- Resetta il contatore dei ticks a zero
ticks=0;
}
//--- Blocco per il calcolo dei valori dell'indicatore
int start=1;
if(prev_calculated>0) start=prev_calculated-1;
//--- Ciclo del calcolo
for(int i=1;i<rates_total;i++)
{
//--- Se il prezzo Close corrente è maggiore di quello precedente, disegna una freccia
if(close[i]>close[i-1])
ColorArrowBuffer[i]=close[i];
//--- In caso contrario, specificare il valore null
else
ColorArrowBuffer[i]=0;
//--- Colore freccia
int index=i%color_sections;
ColorArrowColors[i]=index;
}
//--- restituisce il valore di prev_calculated per la prossima chiamata
return(rates_total);
}
//+--------------------------------------------------------------------------------+
//| Cambia il colore dei segmenti della linea |
//+--------------------------------------------------------------------------------+
void ChangeColors(color &cols[],int plot_colors)
{
//--- Il numero dei colori
int size=ArraySize(cols);
//---
string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
//--- Per ogni indice colore definisce un nuovo colore casualmente
for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
{
//--- Ottiene un valore casuale
int number=MathRand();
//--- Ottiene un indice nell'array col[] come resto della divisione dell'intero
int i=number%size;
//--- Imposta il colore per ogni indice che ha proprietà PLOT_LINE_COLOR
PlotIndexSetInteger(0, // Il numero di stili grafici
PLOT_LINE_COLOR, // Identificatore proprietà
plot_color_ind, // Lìindice del colore, dove scriviamo il colore
cols[i]); // Un nuovo colore
//--- Scrivi i colori
comm=comm+StringFormat("ArrowColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
ChartSetString(0,CHART_COMMENT,comm);
}
//---
}
//+--------------------------------------------------------------------------------+
//| Cambia l'apparenza di una linea visualizzata nell'indicatore |
//+--------------------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- Una stringa per la formazione di informazioni sulle proprietà di linea
string comm="";
//--- Un blocco per modificare la larghezza della linea
int number=MathRand();
//--- Ottiene la larghezza del resto della divisione intera
int width=number%5; // Lo spessore è impostato da 0 a 4
//--- Imposta il colore come proprietà PLOT_LINE_WIDTH
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Scrive lo spessore della linea
comm=comm+" Width="+IntegerToString(width);
//--- Un blocco per il cambio del codice della freccia (PLOT_ARROW)
number=MathRand();
//--- Ottiene il resto della divisione intera per calcolare un nuovo codice della freccia (da 0 a 19)
int code_add=number%20;
//--- Imposta il nuovo codice simbolo come il risultato di code+code_add
PlotIndexSetInteger(0,PLOT_ARROW,code+code_add);
//--- Scrive il codice simbolo PLOT_ARROW
comm="\r\n"+"PLOT_ARROW="+IntegerToString(code+code_add)+comm;
//--- Un blocco per cambiare lo slittamento verticale delle frecce in pixel
number=MathRand();
//--- Prende lo slittamento come il resto della divisione intera
int shift=20-number%41;
//--- Imposta il nuovo slittamento da
PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);
//--- Scrive lo slittamento di PLOT_ARROW_SHIFT
comm="\r\n"+"PLOT_ARROW_SHIFT="+IntegerToString(shift)+comm;
//--- Imposta le informazioni del grafico usando un commento
Comment(comm);
}
|