Referência MQL5Séries Temporais e Acesso a IndicadoresiBarShift

iBarShift

Busca de barra segundo o tempo. A função retorna o índice da barra na qual o tempo especificado coincide.

int  iBarShift(
   const string        symbol,          // símbolo
   ENUM_TIMEFRAMES     timeframe,       // período
   datetime            time,            // tempo
   bool                exact=false      // modo
   );

Parâmetros

symbol

[in] Nome simbólico do instrumento. NULL significa o símbolo atual.

timeframe

[in] Período. Pode ser um dos valores da enumeração ENUM_TIMEFRAMES. PERIOD_CURRENT significa o período atual do gráfico atual.

time

[in] Valor do tempo para a pesquisa.

exact=false

[in] Valor retornado se a barra não for encontrada para o tempo especificado. Se exact=false, iBarShift retorna o índice da barra mais próxima cujo tempo de abertura é menor do que o especificado (time_open<time). Se essa barra não for encontrada (não há histórico antes do tempo especificado), a função retornará -1. Se exact=true, não é pesquisada a barra mais próxima e a função iBarShift retorna imediatamente -1.

Valor de retorno

Índice da barra que coincide com o tempo especificado. Se não houver barra para o tempo especificado ("buraco" no histórico), a função retorna -1 ou o índice da barra mais próxima (dependendo do parâmetro exact).

Exemplo:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- data é no domingo
   datetime time=D'2002.04.25 12:00';
   string symbol="GBPUSD";
   ENUM_TIMEFRAMES tf=PERIOD_H1;
   bool exact=false;
//--- se não houver barra para o tempo especificado, iBarShift retornará o índice da barra mais próxima
   int bar_index=iBarShift(symbol,tf,time,exact);
//--- verificamos o código de erro após chamada de iBarShift()
   int error=GetLastError();
   if(error!=0)
     {
      PrintFormat("iBarShift(): GetLastError=%d - data solicitada %s "+
                  "para %s %s no histórico disponível não encontrada",
                  error,TimeToString(time),symbol,EnumToString(tf));
      return;
     }
//--- função iBarShift() executada com sucesso, imprimimos os resultados para exact=false
   PrintFormat("1. %s %s %s(%s): bar index is %d (exact=%s)",
               symbol,EnumToString(tf),TimeToString(time),
               DayOfWeek(time),bar_index,string(exact));
   datetime bar_time=iTime(symbol,tf,bar_index);
   PrintFormat("Time of bar #%d is %s (%s)",
               bar_index,TimeToString(bar_time),DayOfWeek(bar_time));
//--- precisamos encontrar o índice da barra para o tempo especificado, se ele não existir, obteremos -1
   exact=true;
   bar_index=iBarShift(symbol,tf,time,exact);
//--- função iBarShift() executada com sucesso, imprimimos os resultados para exact=true
   PrintFormat("2. %s %s %s (%s):bar index is %d (exact=%s)",
               symbol,EnumToString(tf),TimeToString(time)
               ,DayOfWeek(time),bar_index,string(exact));
  }
//+------------------------------------------------------------------+
//| Retorna o nome do dia da semana                                   |
//+------------------------------------------------------------------+
string DayOfWeek(const datetime time)
  {
   MqlDateTime dt;
   string day="";
   TimeToStruct(time,dt);
   switch(dt.day_of_week)
     {
      case 0: day=EnumToString(SUNDAY);
      break;
      case 1: day=EnumToString(MONDAY);
      break;
      case 2: day=EnumToString(TUESDAY);
      break;
      case 3: day=EnumToString(WEDNESDAY);
      break;
      case 4: day=EnumToString(THURSDAY);
      break;
      case 5: day=EnumToString(FRIDAY);
      break;
      default:day=EnumToString(SATURDAY);
      break;
     }
//---
   return day;
  }
//+------------------------------------------------------------------+
/* Resultado da execução
   1. GBPUSD PERIOD_H1 2018.06.10 12:00(SUNDAY): bar index is 64 (exact=false)
   Time of bar #64 is 2018.06.08 23:00 (FRIDAY)
   2. GBPUSD PERIOD_H1 2018.06.10 12:00 (SUNDAY):bar index is -1 (exact=true)
*/

iBars

iClose