OnCalculate

int  OnCalculate(
   const int        rates_total,       // grandezza array price[ ]
   const int        prev_calculated,   // numero di barre gestite alla precedente chiamata
   const int        begin,             // numero indice nell'array price[ ] da cui partono i dati significativi
   const double&    price[]            // array di valori per il calcolo
   );

int  OnCalculate(
   const int        rates_total,       // grandezza delle timeseries input
   const int        prev_calculated,   // numero di barre gestite alla precedente chiamata
   const datetime&  time[],            // array Time
   const double&    open[],            // array Open
   const double&    high[],            // array High
   const double&    low[],             // array Low
   const double&    close[],           // array Close
   const long&      tick_volume[],     // array Tick Volume
   const long&      volume[],          // array Real Volume
   const int&       spread[]           // array Spread
   );

//+------------------------------------------------------------------+
//|                                           OnCalculate_Sample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Calcolo dell'indicatore Momentum di esempio"
 
//---- Impostazioni dell'indicatore
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
#property indicator_type1   DRAW_LINE
#property indicator_color1  Blue
//---- input
input int MomentumPeriod=14; // periodo di Calcolo
//---- buffer indicatore
double    MomentumBuffer[];
//--- variabile globale per la memorizzazione del periodo di calcolo
int       IntPeriod;
//+------------------------------------------------------------------+
//| Funzione di inizializzazione dell'indicatore personalizzato      |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- controlla il parametro di input
   if(MomentumPeriod<0)
     {
      IntPeriod=14;
      Print("Il parametro Period ha un valore errato. Il seguente valore deve essere utilizzato per i calcoli ",IntPeriod);
     }
   else
      IntPeriod=MomentumPeriod;
//---- buffers  
   SetIndexBuffer(0,MomentumBuffer,INDICATOR_DATA);
//---- nome dell'indicatore da visualizzare in DataWindow e sottofinestra
   IndicatorSetString(INDICATOR_SHORTNAME,"Momentum"+"("+string(IntPeriod)+")");
//--- imposta l'indice della barra da cui inizia il disegno
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,IntPeriod-1);
//--- imposta 0.0 come valore vuoto che non è disegnato
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//--- precisione dell'indicatore da visualizzare
   IndicatorSetInteger(INDICATOR_DIGITS,2);
  }
//+------------------------------------------------------------------+
//| Calcolo indicatore Momentum                                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,     // grandezza arrat price[ ] 
                const int prev_calculated, // numero di barre precedentemente gestite
                const int begin,           // da dove partono i dati significativi 
                const double &price[])     // array di valori per la gestione
  {
//--- posizione iniziale per i calcoli
   int StartCalcPosition=(IntPeriod-1)+begin;
// ---- se i dati di calcolo sono insufficienti
   if(rates_total<StartCalcPosition)
      return(0);  // esce con un valore zero - l'indicatore non viene calcolato
//--- inizia il disegno corretto
   if(begin>0)
      PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartCalcPosition+(IntPeriod-1));
//--- avvio calcoli, definisce la posizione di partenza
   int pos=prev_calculated-1;
   if(pos<StartCalcPosition)
      pos=begin+IntPeriod;
//--- ciclo di calcolo principale
   for(int i=pos;i<rates_total && !IsStopped();i++)
      MomentumBuffer[i]=price[i]*100/price[i-IntPeriod];
//--- l'esecuzione OnCalcolate è completa. Restituisce il nuovo valore prev_calculated per la chiamata successiva
   return(rates_total);
  }