Descargar MetaTrader 5

DRAW_ZIGZAG

El estilo DRAW_ZIGZAG dibuja segmentos de color especificado, usando valores de dos búfers indicadores. Este estilo es muy parecido al DRAW_SECTION, pero a diferencia del último, éste permite dibujar segmentos verticales dentro de los márgenes de una barra, si los valores de los dos búfers indicadores están establecidos para esta barra. Los segmentos se trazan desde un valor en el primer búfer indicador hasta un valor en el segundo. Ninguno de los dos búferes puede contener sólo valores vacíos. Si es así, no se dibuja nada.

El grosor, color y el estilo de la línea se puede establecer de la misma manera como para el estilo DRAW_SECTION — con las directivas del compilador, o bien dinámicamente, utilizando la función PlotIndexSetInteger(). El cambio dinámico de las propiedades de la construcción gráfica permite "vivificar" los indicadores, para que cambien su apariencia en función de la situación actual.

Los segmentos se trazan desde un valor no vacío de un búfer hasta otro valor no vacío de otro búfer indicador. Para indicar qué valor se debe considerar "vacío", establezca este valor en la propiedad PLOT_EMPTY_VALUE:

//--- el valor 0 (valor vacío) no va a participar en el proceso de trazado
   PlotIndexSetDouble(índice_ de_construcción_DRAW_ZIGZAG,PLOT_EMPTY_VALUE,0);

Rellene siempre los búfers indicadores con valores de forma explícita, para las barras que se ignoran indique en el búfer un valor vacío.

El número de búfers requeridos para construir DRAW_ZIGZAG – 2.

Aquí tenemos un ejemplo del indicador que traza la sierra a base de los precios High y Low. El color, grosor y el estilo de la línea del zigzag se cambian de forma aleatoria cada N tics.

Ejemplo del estilo DRAW_ZIGZAG

Fíjense en que inicialmente para la construcción gráfica plot1 con el estilo DRAW_ZIGZAG las propiedades se establecen mediante la directiva del compilador #property, y luego en la función OnCalculate() estas tres propiedades se establecen de forma aleatoria. El parámetro N está pasado a los parámetros externos del indicador para que exista la posibilidad de establecerlo manualmente (pestaña "Parámetros" en la ventana de propiedades del indicador).

//+------------------------------------------------------------------+
//|                                                  DRAW_ZIGZAG.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Indicador para demostrar DRAW_ZIGZAG"
#property description "Dibuja con segmentos rectos \"la sierra\", saltando las barras de un día"
#property description "El día que se salta se elige de forma aleatoria al iniciar el indicador"
#property description "El color, grosor y el estilo de segmentos se cambia de forma aleatoria"
#property description " dentro de cada N tics"
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   1
//--- plot ZigZag
#property indicator_label1  "ZigZag"
#property indicator_type1   DRAW_ZIGZAG
#property indicator_color1  clrBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- parámetros input
input int      N=5;              // número de tics a cambiar 
//--- indicator buffers
double         ZigZagBuffer1[];
double         ZigZagBuffer2[];
//--- día de la semana para el que el indicador no se dibuja
int invisible_day;
//--- array para almacenar colores
color colors[]={clrRed,clrBlue,clrGreen};
//--- array para almacenar estilos de trazado de la línea
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- vinculación de arrays con búfers indicadores
   SetIndexBuffer(0,ZigZagBuffer1,INDICATOR_DATA);
   SetIndexBuffer(1,ZigZagBuffer2,INDICATOR_DATA);
//--- obtenemos un número aleatorio de 0 a 6, para este día el indicador no se dibuja
   invisible_day=MathRand()%6;
//--- el valor 0 (valor vacío) no va a participar en el proceso de trazado
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- el valor 0 (valor vacío) no va a participar en el proceso de trazado
   PlotIndexSetString(0,PLOT_LABEL,"ZigZag1;ZigZag2");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- contamos los tics para el cambio del estilo, color y grosor de la línea
   ticks++;
//--- si tenemos acumulado un número suficiente de tics
   if(ticks>=N)
     {
      //--- cambiamos las propiedades de la línea
      ChangeLineAppearance();
      //--- actualizamos el contador de tics pasándolo a cero
      ticks=0;
     }
 
//--- necesitaremos una estructura de tiempo para obtener el día de la semana de cada barra
   MqlDateTime dt;
 
//--- posición de inicio del cálculo
   int start=0;
//--- si el indicador se calcula en el tic anterior, empezamos el cálculo a partir del penúltimo
   if(prev_calculated!=0) start=prev_calculated-1;
//--- ciclo de cálculos
   for(int i=start;i<rates_total;i++)
     {
      //--- apuntaremos en la estructura la hora de apertura de la barra
      TimeToStruct(time[i],dt);
      //--- si el día de la semana de esta barra es igual a invisible_day
      if(dt.day_of_week==invisible_day)
        {
         //--- apuntaremos en el búfer los valores vacíos para esta barra
         ZigZagBuffer1[i]=0;
         ZigZagBuffer2[i]=0;
        }
      //--- si el día de la semana es correcto, llenamos los búfers 
      else
        {
         //--- si el número de la barra es par
         if(i%2==0)
           {
            //---  escribimos en el 1-r búfer High, en el 2-do Low
            ZigZagBuffer1[i]=high[i];
            ZigZagBuffer2[i]=low[i];
           }
         //--- número de la barra impar
         else
           {
            //--- llenamos la barra en sentido inverso
            ZigZagBuffer1[i]=low[i];
            ZigZagBuffer2[i]=high[i];
           }
        }
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| cambia la apariencia de segmentos en el zigzag                   |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- cadena para formar la información sobre las propiedades del ZigZag
   string comm="";
//--- bloque del cambio del color del zigzag
   int number=MathRand(); // obtenemos un número aleatorio
//--- el divisor del número es igual al tamaño del array colors[]
   int size=ArraySize(colors);
//--- obtenemos el índice para seleccionar nuevo color como el remanente de la división de números enteros
   int color_index=number%size;
//--- estableceremos el color como la propiedad PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- apuntaremos el color de la línea
   comm=comm+"\r\n"+(string)colors[color_index];
 
//--- bloque de cambio del grosor de la línea
   number=MathRand();
//--- obtenemos el grosor como el remanente de la división de números enteros
   int width=number%5;   // el grosor puede ser de 0 a 4
//--- estableceremos el color como la propiedad PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- apuntaremos el grosor de la línea
   comm=comm+"\r\nWidth="+IntegerToString(width);
 
//--- bloque de cambio del estilo de la línea
   number=MathRand();
//--- el divisor del número es igual al tamaño del array styles
   size=ArraySize(styles);
//--- obtenemos el índice para seleccionar nuevo estilo como el remanente de la división de números enteros
   int style_index=number%size;
//--- estableceremos el color como la propiedad PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- apuntaremos el estilo de la línea
   comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- agregaremos la información sobre el día que se ignora en los cálculos
   comm="\r\nDía no dibujable - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- mostraremos la información en el gráfico a través del comentario
   Comment(comm);
  }

 


Actualizado: 2015.12.03