//+------------------------------------------------------------------+
//| DRAW_ZIGZAG.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "An indicator to demonstrate DRAW_ZIGZAG"
#property description "It draws a \"saw\" as straight segments, skipping the bars of one day"
#property description "The day to skip is selected randomly during indicator start"
#property description "The color, width and style of segments are changed randomly"
#property description " every N ticks"
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots 1
//--- ZigZag をプロットする
#property indicator_label1 "ZigZag"
#property indicator_type1 DRAW_ZIGZAG
#property indicator_color1 clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- 入力パラメータ
input int N=5; // 変化をもたらすティックの数
//--- 指標バッファ
double ZigZagBuffer1[];
double ZigZagBuffer2[];
//--- 指標がプロットされない曜日
int invisible_day;
//--- 色を格納する配列
color colors[]={clrRed,clrBlue,clrGreen};
//--- 線のスタイルを格納する配列
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 配列と指標バッファを関連付ける
SetIndexBuffer(0,ZigZagBuffer1,INDICATOR_DATA);
SetIndexBuffer(1,ZigZagBuffer2,INDICATOR_DATA);
//--- プロットしない曜日を決めるのに0〜6の乱数を取得
invisible_day=MathRand()%6;
//--- 0（空）値は描画されない
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- 0（空）値は描画されない
PlotIndexSetString(0,PLOT_LABEL,"ZigZag1;ZigZag2");
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| カスタム指標の反復関数 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 線のスタイル、色、及び幅を変更するティックを計算する
ticks++;
//--- 充分なティックの数が蓄積されている場合
if(ticks>=N)
{
//--- 線のプロパティを変更する
ChangeLineAppearance();
//--- ティックカウンタをゼロにリセットする
ticks=0;
}
//--- 各足の曜日を取得するのに時間の構造体が必要
MqlDateTime dt;
//--- 計算開始位置
int start=0;
//--- 指標が以前に計算されている場合には、計算開始点を最後から2 つ目のバーに設定する
if(prev_calculated!=0) start=prev_calculated-1;
//--- 計算ループ
for(int i=start;i<rates_total;i++)
{
//--- バーのオープン時間を書く
TimeToStruct(time[i],dt);
//--- このバーの曜日が invisible_day に等しい場合
if(dt.day_of_week==invisible_day)
{
//--- このバーでは、空の値をバッファに書く
ZigZagBuffer1[i]=0;
ZigZagBuffer2[i]=0;
}
//--- 曜日が大丈夫なら、バッファに書き込む
else
{
//--- バー番号が偶数の場合
if(i%2==0)
{
//--- 1 番目のバッファの高値と2 番目のバッファの安値を書く
ZigZagBuffer1[i]=high[i];
ZigZagBuffer2[i]=low[i];
}
//--- バー番号が奇数の場合
else
{
//--- 逆の順序でバーに記入
ZigZagBuffer1[i]=low[i];
ZigZagBuffer2[i]=high[i];
}
}
}
//--- 次の呼び出しのために prev_calculated の値を返す
return(rates_total);
}
//+------------------------------------------------------------------+
//| ジグザグセグメントの外観を変更する |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- ジグザグのプロパティに関する情報を形成するための文字列
string comm="";
//--- ジグザグの色を変更するブロック
int number=MathRand(); // 乱数を取得
//--- 除数は colors[] 配列のサイズと同じ
int size=ArraySize(colors);
//--- 新しい色を選択するためのインデックスを整数除算の余りから取得
int color_index=number%size;
//--- 色をPLOT_LINE_COLOR プロパティとして設定
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- 線の色を書く
comm=comm+"\r\n"+(string)colors[color_index];
//--- 線の幅を変更するブロック
number=MathRand();
//--- 整数除算の余りの幅を取得
int width=number%5; // 幅は 0〜4 に設定される
//--- 色を PLOT_LINE_WIDTH プロパティに設定
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 線の幅を書く
comm=comm+"\r\nWidth="+IntegerToString(width);
//--- 線のスタイルを変更するブロック
number=MathRand();
//--- 除数は、スタイルの配列の大きさに等しい
size=ArraySize(styles);
//--- 新しいスタイルを選択するためのインデックスを整数除算の余りから取得
int style_index=number%size;
//--- 色をPLOT_LINE_COLOR プロパティとして設定
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 線のスタイルを書く
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- 計算では省略された日についての情報を追加する
comm="\r\nNot plotted day - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- コメントを使用して、チャート上の情報を表示する
Comment(comm);
}
|
