DRAW_NONE

El estilo DRAW_NONE se utiliza cuando es necesario calcular los valores del búfer y mostrarlos en la "Ventana de datos", pero la misma representación en el gráfico no se precisa. Para ajustar la precisión de representación, utilice la expresión IndicatorSetInteger(INDICATOR_DIGITS,número_de_dígitos) en la función OnInit():

int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,InvisibleBuffer,INDICATOR_DATA);
//--- fijamos la precisión para el valor a mostrar en la Ventana de datos
   IndicatorSetInteger(INDICATOR_DIGITS,0);
//---
   return(INIT_SUCCEEDED);
  }

El número de búfers requeridos para construir DRAW_NONE – 1.

Aquí tenemos un ejemplo del indicador que muestra en la "Ventana de datos" el número de la barra sobre la que está situado el ratón. La numeración corresponde a la serie temporal. Es decir, la barra actual no finalizada tiene el índice cero, mientras que la barra más antigua tiene el índice más grande.

Ejemplo del estilo DRAW_NONE

Fíjense que a pesar de que la construcción gráfica №1 tenga especificado el color rojo de representación, el indicador no dibuja nada en el gráfico.

//+------------------------------------------------------------------+
//|                                                    DRAW_NONE.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plot Invisible
#property indicator_label1  "Bar Index"
#property indicator_type1   DRAW_NONE
#property indicator_style1  STYLE_SOLID
#property indicator_color1  clrRed
#property indicator_width1  1
//--- indicator buffers
double         InvisibleBuffer[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- vinculación del array con el búfer indicador
   SetIndexBuffer(0,InvisibleBuffer,INDICATOR_DATA);
//--- fijaremos la precisión con la que el valor será mostrado en la "Ventana de datos"
   IndicatorSetInteger(INDICATOR_DIGITS,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static datetime lastbar=0;
//--- si es el primer cálculo del indicador,
   if(prev_calculated==0)
     {
      //--- reenumeraremos las barras por primera vez
      CalcValues(rates_total,close);
      //--- recordaremos la hora de apertura de la barra actual en lastbar
      lastbar=(datetime)SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE);
     }
   else
     {
      //--- si ha aparecido una barra nueva, la hora de su apertura no coincide con lastbar
      if(lastbar!=SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE))
        {
         //--- volveremos a enumerar las barras de nuevo
         CalcValues(rates_total,close);
         //--- actualizaremos la hora de apertura de la barra actual en lastbar
         lastbar=(datetime)SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE);
        }
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| enumeramos las barras como en una serie temporal                 |
//+------------------------------------------------------------------+
void CalcValues(int total,double const  &array[])
  {
//--- estableceremos para el búfer indicador la indexación como en la serie temporal
   ArraySetAsSeries(InvisibleBuffer,true);
//--- llenaremos para cada barra su número
   for(int i=0;i<total;i++) InvisibleBuffer[i]=i;
  }