Trabajando con cestas de parejas de divisas en el mercado fórex

Trabajando con cestas de parejas de divisas en el mercado fórex

En el artículo se analizan cuestiones relacionadas con la división en grupos de las parejas de divisas, las cestas; también sobre cómo obtener datos sobre el estado de estas cestas (por ejemplo, sobrecompra o sobreventa); qué indicadores pueden proporcionar estos datos; y al fin, sobre cómo se puede aplicar la información obtenida en el trading práctico.

Introducción

Cada día en la información financiera de los mercados mundiales oímos alguna frase del tipo: "El dólar ha caído con respecto a las divisas mundiales...". Esto significa que el estado de una divisa ha cambiado con respecto al grupo de otras divisas. El uso constante de esta fórmula verbal nos hace desear poner de alguna forma en orden la lista completa de las parejas de divisas, tratar de destacar un cierto número de ellas y quizá hacerlo en varias ocasiones.

Las ideas y propuestas de los tráders sobre el tema de los intentos de distribución de las parejas de divisas en grupos o «cestas», se publican con bastante asiduidad. En los foros de trading se publican artículos y discusiones, e incluso ya se ha desarrollado una serie de herramientas. El agrupamiento de parejas de divisas en «cestas» se hace con el objetivo de analizar con mayor precisión el comportamiento conjunto de las parejas de divisas vecinas en la «cesta». Se supone que estos pares de divisas se comportarán de manera similar en gran medida, crearán extremos aproximadamente al mismo tiempo, e irán en la misma dirección en la mayoría de los casos. Podemos intentar incluso representar un grupo de parejas de divisas o "cesta" en forma de una cierta pareja de divisas media virtual y trabajar con ella como proceda.

Principios y definición

La base de la idea es la reagrupación de las parejas de divisas según los rasgos que resulten importantes para el tráder. Algunos de estos rasgos clave son bien conocidos por todos: por ejemplo, la relación entre el precio del pertróleo y el curso del rublo o la correlación entre las parejas EURUSD y USDCHF. Para la demostración se las podría elegir en un grupo de dos parejas, que en lo sucesivo constituirían la cesta de parejas de divisas, o simplemente cesta de divisas. Tras definir los componentes de la cesta de divisas, podemos hablar de las acciones a realizar con ellas, presuponiendo que las acciones tendrán lugar con todas las parejas que entren en la cesta, en este caso, EURUSD y USDCHF. Podemos observar el comportamiento de ambas parejas de divisas, también podemos ejecutar operaciones comerciales.

La venta o compra de una cesta de divisas presupone que se harán operaciones comerciales simultáneas con cada divisa que la componga. En este caso, según el princio "una pareja de divisas, una orden", se compone la cesta de órdenes, que además no deben estar obligatoriamente en la misma dirección. Las condiciones cuyo cambio acarreará la ejecución de operaciones comerciales, caracterizarán el estado de la cesta de divisas.

Para trabajar posteriormente, usaremos el principio más obvio y natural, el agrupamiento de parejas de divisas. Las principales veintiocho parejas de divisas se dividirán en cestas dependiendo de su divisa básica (o de la divisa de la cotización), que deberá estar presente en cada pareja. El nombre de la cesta se asignará de acuerdo con el nombre de la divisa básica (ver ejemplo en el recuadro 1). El estado de la cesta en este caso será determinado por el estado de su divisa básica. Los parámetros de este estado son, por ejemplo, la sobrecompra, la sobreventa y otras características similares. Estas se nos presentan con los mismos recursos de análisis técnico que ya usamos para valorar el estado de las parejas de divisas habituales.

Principales cestas de divisas

Vamos a dividir el conjunto de parejas de divisas según el principio descrito más arriba. Como resultado, obtenemos ocho cestas de divisas, en cada una de ellas hay siete parejas de divisas:

Número ordinal	Denominación de la cesta	Divisa de la cesta	Parejas de divisas de la cesta
1	Cesta del dólar australiano	AUD	AUDUSD, AUDNZD, AUDJPY, AUDCAD, AUDCHF, EURAUD, GBPAUD
2	Cesta del dólar canadiense	CAD	USDCAD, AUDCAD, NZDCAD, GBPCAD, EURCAD, CADCHF, CADJPY
3	Cesta del franco	CHF	CHFJPY, USDCHF, GBPCHF, EURCHF, AUDCHF, NZDCHF, CADCHF
4	Cesta del euro	EUR	EURUSD, EURJPY, EURCHF, EURGBP, EURNZD, EURCAD, EURAUD
5	Cesta de la libra	GBP	EURGBP, GBPAUD, GBPCAD, GBPCHF, GBPJPY, GBPNZD, GBPUSD
6	Cesta del yen	JPY	AUDJPY, CADJPY, CHFJPY, EURJPY, GBPJPY, NZDJPY, USDJPY
7	Cesta del dólar neozelandés	NZD	NZDUSD, AUDNZD, NZDJPY, NZDCAD, NZDCHF, EURNZD, GBPNZD
8	Cesta del dólar	USD	EURUSD, GBPUSD, AUDUSD, NZDUSD, USDCAD, USDCHF, USDJPY

Recuadro 1. Composición de las parejas de divisas

Una vez decidida la composición de la cesta, concretamos el sentido de las principales operaciones comerciales con ellas. Aceptamos que la compra o venta de la cesta se reduce a la compra o venta de su divisa.

Vamos a ver la situación siguiente. Supongamos que salen buenas noticias sobre el yen, y por consiguiente, podemos esperar que se fortalezca. El inversor decide comprar yenes. Dentro del paradigma estudiado, para comprar una cesta de yen, tendrá que entrar en la VENTA con todas sus parejas de divisas. Y al contrario, si desea vender una cesta de yen, deberá entrar en la compra con todas las parejas de divisas que incluidas en ella.

Para la cesta de euro la cosa parece menos confusa. Si el inversor quiere comprar una cesta de euro, entrará en la compra con todas sus parejas, y al revés. Para el euro y el yen, la cesta de órdenes constará de órdenes en una misma dirección.

Para evitar confusiones con las operaciones comerciales, crearemos el siguiente recuadro de pistas:

Número ordinal	Denominación de la cesta	Operación comercial con la cesta de divisas	Operación comercial con las parejas de divisas de la cesta
1	Cesta del dólar australiano		AUDUSD	AUDNZD	AUDJPY	AUDCAD	AUDCHF	EURAUD	GBPAUD
		SELL	sell	sell	sell	sell	sell	buy	buy
		BUY	buy	buy	buy	buy	buy	sell	sell
2	Cesta del dólar canadiense		USDCAD	AUDCAD	NZDCAD	GBPCAD	EURCAD	CADCHF	CADJPY
		SELL	buy	buy	buy	buy	buy	sell	sell
		BUY	sell	sell	sell	sell	sell	buy	buy
3	Cesta del franco		CHFJPY	USDCHF	GBPCHF	EURCHF	AUDCHF	NZDCHF	CADCHF
		SELL	sell	buy	buy	buy	buy	buy	buy
		BUY	buy	sell	sell	sell	sell	sell	sell
4	Cesta del euro		EURUSD	EURJPY	EURCHF	EURGBP	EURNZD	EURCAD	EURAUD
		SELL	sell	sell	sell	sell	sell	sell	sell
		BUY	buy	buy	buy	buy	buy	buy	buy
5	Cesta de la libra		EURGBP	GBPAUD	GBPCAD	GBPCHF	GBPJPY	GBPNZD	GBPUSD
		SELL	buy	sell	sell	sell	sell	sell	sell
		BUY	sell	buy	buy	buy	buy	buy	buy
6	Cesta del yen		AUDJPY	CADJPY	CHFJPY	EURJPY	GBPJPY	NZDJPY	USDJPY
		SELL	buy	buy	buy	buy	buy	buy	buy
		BUY	sell	sell	sell	sell	sell	sell	sell
7	Cesta del dólar neozelandés		NZDUSD	AUDNZD	NZDJPY	NZDCAD	NZDCHF	EURNZD	GBPNZD
		SELL	sell	buy	sell	sell	sell	buy	buy
		BUY	buy	sell	buy	buy	buy	sell	sell
8	Cesta del dólar		EURUSD	GBPUSD	AUDUSD	NZDUSD	USDCAD	USDCHF	USDJPY
		SELL	buy	buy	buy	buy	sell	sell	sell
		BUY	sell	sell	sell	sell	buy	buy	buy

Recuadro 2. Operaciones comerciales con las cestas

Estado de la cesta de divisas

¿Cómo tomar una decisión sobre la ejecución de una operación comercial con una cesta de divisas? Es difícil hacer algo así basándose solo en el comportamiento de las parejas de divisas, debido al gran tamaño de las cestas de divisas. Necesitaremos datos técnicos adicionales sobre los parámetros del estado de la divisa de la cesta. Prestemos atención al gráfico del indicador RSI para tres parejas de divisas de la cesta de la libra, más concretamente, para GBPUSD, GBPJPY, GBPCHF. En esta figura se representa un gráfico con el marco temporal D1:

Resulta fácil notar las semejanzas de los tres gráficos: muchos extremos están ubicados de la misma forma, y los intervalos de subida y bajada también coinciden. La presuposición más plausible es que esta semejanza se explica porque la divisa de la cesta es la misma: la libra británica. Su debilitamiento provoca el descenso en ciertos segmentos, y su refuerzo redunda en la aparición de segmentos ascendentes en el gráfico.

Las diferencias en los tres gráficos se explican en gran medida por el comportamiento de las divisas de las cotizaciones. En este caso, su influencia se manifiesta en la aparición de extremos locales "sobrantes", en diferentes gradientes de movimientos ascendentes y descendetes, y en cambios locales de la dirección del movimiento.

Tras averiguar cómo cambia el parámetro común para todas las parejas de divisas de la cesta y nivelar la diferencia entre parejas, resolveremos la tarea principal, visualizar este parámetro.  En este ejemplo, el estado de sobrecompra / sobreventa de la libra, un cierto "RSI unificado", se convertirá en este parámetro del estado de la divisa de la cesta, mostrando, no el estado de la pareja de divisas como acostumbran a verlo los tráders, sino solo con una divisa, la divisa de la cesta.

Está claro que podemos limitarnos no solo a RSI. Es posible abarcar otros indicadores semejantes, calculados en base a los indicadores estándar. Hemos decidido aplicar a estos indicadores el nombre genérico de "indicadores unificados".

Metodología para el cálculo del estado de la divisa de la cesta

Para resolver esta tarea, merece la pena recordar las metodologías ya disponibles e intentar actuar de forma análoga. Lo primero que viene a la cabeza en relación con este tema, es el índice del dólar. Recordemos que este índice muestra el estado del dólar con respecto a las otras seis divisas mundiales,  vamos a fijarnos en la forma de cálculo. Se trata de la media geométrica con los coeficientes de peso. Haremos un intento de trasladar este principio a nuestra cesta del dólar, es decir, usaremos nuestro conjunto de parejas de divisas. Vamos a admitir otro punto más: eliminaremos los coeficientes de peso y reduciremos la fórmula a la media geométrica habitual. Estos cambios los introduciremos para usar el principio de la media geométrica en el cálculo de todas las cestas. Prácticamente con casi todas las parejas de divisas, los coeficientes de peso serán desconocidos.

Vamos a comprobar hasta qué punto será intensa la influencia de los cambios introducidos. Para ello, usaremos un indicador muy sencillo:

#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "http://www.mql5.com"
#property version   "1.00"
#property strict

#property indicator_separate_window
#property indicator_buffers 1

input int     iBarsTotal=300;       

string pair[]={"EURUSD","GBPUSD","AUDUSD","NZDUSD","USDCAD","USDCHF","USDJPY"};
bool bDirect[]={false,false,false,false,true,true,true};
int iCount=7;
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double GetValue(int shift)
  {
   double res=1.0,t;
   for(int i=0; i<iCount; i++)
     {
      t=iClose(pair[i],0,shift);
      if(!bDirect[i]) t=1/t;
      res*=t;
     }//end for (int i = 0; i < iCount; i++)
   return (NormalizeDouble(MathPow (res, (double)1/iCount), _Digits) );
  }

double upp[];
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnInit()
  {
   IndicatorShortName("testBasket");
   IndicatorDigits(_Digits);
   SetIndexStyle(0,DRAW_LINE,STYLE_SOLID,2,clrGreen);
   SetIndexBuffer(0,upp);
   SetIndexLabel(0,"testBasket");

   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   if(prev_calculated==0)
     {

      int total;
      if(iBarsTotal==0) total=rates_total;
      else total= MathMin(iBarsTotal,rates_total);
      for(int i = 0; i<total; i++) upp[i] = GetValue(i);
     }//end if (prev_calculated == 0)
   else
     {
      upp[0]=GetValue(0);
     }
   return(rates_total);
  }

Para la comparación se ha usado el indicador gratuito USDX.mq4, que dibuja el índice del dólar de la forma clásica. Aquí tenemos el resultado (marco temporal H1):

En esta imagen se representa en color verde oscuro el gráfico del indicador testBasket.mq4, y en color rojo y verde claro (con los que se dibuja la media), el indicador USDX.mq4. Podemos percibir una coincidencia muy notable en el marco temporal H1. Se nota que las direcciones del movimiento en la mayoría de los segmentos coinciden, al igual que una mayoría aplastante de los extremos locales

En el marco temporal de días la imagen es menos propicia, pero aun así, es totalmente aceptable. La posición de la mayoría de los extremos locales coincide, como sucede con la dirección del movimiento en la mayoría de los segmentos. Las diferencias en lugares concretos se pueden explicar fácilmente por la ausencia de coeficientes de peso y por otros conjuntos de parejas divisas. Además, también se dejan sentir las diferencias en la escala de los gráficos superpuestos unos sobre otros.

Bien, en base a los resultados obtenidos, es conveniente reconocer que la fórmula de cálculo de la media geométrica es aceptable para el cálculo de los diferentes parámetros del estado de la divisa de la cesta. En lo sucesivo, la llamaremos metodología № 1. Pero hay que recordar también las limitaciones de esta fórmula, y más concretamente: será una mala idea usarla para los cálculos con argumentos que pueden adoptar valores negativos. Sabemos que este tipo no es poco frecuente entre los indicadores técnicos. Además, los cálculos de la media geométrica pueden cargar significativamente el terminal si no se los saca a una biblioteca aparte.

Para quitar las limitaciones de uso a las magnitudes negativas en calidad de argumentos, podemos intentar aplicar otra fórmula, por ejemplo,  la fórmula de la media aritmética habitual. Crearemos otro indicador de prueba para los cálculos con esta fórmula, en calidad de argumentos usaremos los valores del indicador Stochastic:

#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "http://www.mql5.com"
#property version   "1.00"
#property strict

#property indicator_separate_window
#property indicator_minimum    0
#property indicator_maximum    100

#property indicator_buffers 2

input int     iBarsTotal=3000;

string pair[]={"EURUSD","EURJPY","EURCHF","EURGBP","EURNZD","EURCAD","EURAUD"};
int iCount=7;
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void GetValue(int shift,double &s1,double &s2)
  {
   s1=0; s2=1;
   for(int i=0; i<iCount; i++) 
     {
      s1 += iStochastic(pair[i],0,5,3,3,MODE_SMA,0,0,shift);
      s2 *= iStochastic(pair[i],0,5,3,3,MODE_SMA,0,0,shift);
     }
   s1 = NormalizeDouble(s1/iCount, _Digits);
   s2 = NormalizeDouble(MathPow (s2, (double)1/iCount), _Digits);
  }

double upp[],upp1[];
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnInit()
  {
   IndicatorShortName("testBasketS");
   IndicatorDigits(_Digits);
   SetIndexStyle(0,DRAW_LINE,STYLE_SOLID,2,clrRed);
   SetIndexBuffer(0,upp);
   SetIndexLabel(0,"testBasketSA");
   SetIndexStyle(1,DRAW_LINE,STYLE_SOLID,2,clrGreen);
   SetIndexBuffer(1,upp1);
   SetIndexLabel(1,"testBasketSG");

   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   if(prev_calculated==0)
     {

      int total;
      if(iBarsTotal==0) total=rates_total;
      else total= MathMin(iBarsTotal,rates_total);
      for(int i = 0; i<total; i++) GetValue(i,upp[i],upp1[i]);
     }//end if (prev_calculated == 0)
   else
     {
      GetValue(0,upp[0],upp1[0]);
     }
   return(rates_total);
  }

Cargamos este indicador en el gráfico de días de la pareja EURGBP. Aquí tenemos el resultado:

En esta imagen, se dibuja con una línea fina el gráfico del indicador Stochastic original, con una línea roja de grosor doble, el nuevo Stochastic unificado, calculado según la fórmula de la media aritmética. La línea de grosor doble y color verde, mientras tanto, se ha obtenido usando la fórmula de la media geométrica y se muestra para realizar comparaciones.

Directamente a partir de las fórmulas, podemos sacar la conclusión de que los resultados que dan son muy semejantes. El gráfico construido con el uso de la media geométrica tiene extremos más claros, y el gráfico con el uso de la media aritmética tiene un carácter más suavizado. Aunque claro, podría tratarse de una opinión subjetiva. Se supone que para un uso concreto serán decisivas las limitaciones relacionadas con la presencia de argumentos negativos, así como la potencia de la computadora. En general, podemos aceptar la posibilidad de aplicar la fórmula de la media aritmética para los cálculos como metodología № 2.

Primeras conclusiones prácticas

Después de leer los párrafos anteriores, no puedo evitar que me venga a la cabeza la idea: "¿Y para qué sirve todo esto?". Hemos obtenido un nuevo indicador que dibuja un gráfico parecido al gráfico del índice del dólar y otro que dibuja un gráfico parecido al gráfico Stochastic. Podríamos obtener otro indicador que dibuje un gráfico paracido al RSI clásico. Pero los tráders ya tienen RSI y Stochastic, ¿para qué necesitan otros parecidos, qué van a hacer con ellos? Vamos a intentar responder a esta pregunta.

1. Recordemos que los indicadores unificados proporcionan al tráder información sobre el estado de la cesta, y por consiguiente, permiten pronosticar los movimientos de todas las parejas de divisas de la cesta. A su vez, este pronóstico permite realizar operaciones comerciales con todas las parejas de divisas de la cesta.
2. Prestemos atención a que la combinación de los indicadores unificados con su análogo clásico, como se ve en ela última figura con Stochastic, proporciona al tráder un filtro que permite abstenerse de la entrada en ciertas parejas de divisas de la cesta de divisas, analizar los puntos de curce de los gráficos y detectar divergencias.
3. No debemos olvidar que en la formación del gráfico de la pareja de divisas participan dos divisas, y que cada una de ellas es una divisa de su cesta. Para cada una de ellas, el tráder puede obtener información sobre su estado, usando los indicadores unificados. Ya sobre esta base se pueden extraer conclusiones sobre qué hacer posteriormente.

Cualquiera de estos puntos puede servir de base para construir un sistema comercial rentable. Además, con los indicadores unificados es posible también complementar sistemas comerciales ya listos, con los cuales trabajará el tráder. Sin embargo, este tema definitivamente se sale del marco de este artículo, que tiene el objetivo de familiarizar al lector con el principio en sí, en el caso de que no lo conozca ya.

Conclusión

Es conveniente recordar que la decisión sobre la entrada en el mercado y la salida del mismo se debe tomar en base a varias señales, si no estamos hablando de comercio sin indicadores. En el artículo estudiamos un método para obtener estas señales con un sistema en absoluto nuevo, que en ningún caso cancela o sustituye la aplicación de los recursos estándar. El uso conjunto del grupo los indicadores unificados RSI, Stochastic y otros, en combinación con los indicadores estándar, puede proporcionar la cantidad y calidad de señales necesarias para confirmar o rechazar la ejecución de operaciones comerciales y la obtención de beneficios.