¿Cuál es el grado de fiabilidad del trading por la noche?

Introducción

A lo largo de los últimos seis meses hemos visto muchos Asesores Expertos que han generado beneficios sin prácticamente ningún riesgo y simplemente mediante el trading nocturno con EURCAD, GBPCAD, EURCHF y otros pares de divisas. De hecho, el trading con las cuentas PAMM de Alpari que usa estás estrategias ha conseguido resultados sorprendentes. Sin embargo, hay muchas opiniones negativas sobre este sistema de trading. El propósito de este artículo es ver si realmente el trading plano durante la noche es rentable e identificar todos los riesgos ocultos de este tipo de trading en una cuenta real.

Teoría

La siguiente figura muestra las típicas zonas planas durante la noche. Este no es el mejor gráfico para esta estrategia, pero la elección se hizo adrede. Los límites de la zona plana de la noche son bastante imprecisos. Podemos decir que para EURCHF la zona plana empieza a las18:00-20:00 y finaliza a las 10:00-14:00 según la hora del servidor. Vamos a considerar que es el intervalo entre las 18:00 y las 10:00.

La zona plana de la noche pierde su continuidad durante la apertura de las sesiones de Asia y del Pacífico y se caracteriza por la baja volatilidad de la mayoría de los pares de divisas.

La implementación

En primer lugar, vamos a definir aproximadamente cómo tiene que funcionar el Asesor Experto durante el trading en las zonas planas de la noche.

1) Tiempo de apertura de la transacción – no antes que una hora concreta

2) Tiempo de cierre de la transacción – no más tarde que una hora concreta

3) TP – muy cerca, entre 10 y 50 puntos

4) SL – mayor que TP, de 30 a 70 puntos

5) Entrar al mercado – el precio está cerca de los límites de la zona plana

6) Se definen los límites de la zona plana en las horas anteriores a su inicio

7) El número de transacciones en la noche puede ser limitado ya que entrar en las posiciones Sell o Buy más de una vez y salir con beneficio es raro; la segunda entrada al mercado resulta a menudo en un cierre con pérdidas al final de la zona plana de la noche.

Se pueden implementar esto puntos de la siguiente manera:

// External variables
extern double    Lots=1;
extern int       h_beg=20;
extern int       h_end=10;
extern int       TakeProfit=20; 
extern int       StopLoss=90;

// Auxiliary variables
double max;
double min;
int slippage=5;
int magik=5;
int pos=0;

//Counter of deals over the night session
int Buy_count=0; 
int Sell_count=0;
 
//Function for closing an order
bool CloseOrder()
{
   int ticket,i;
   double Price_close;
   int err;
   int count=0;
   int time;      
       for(i=OrdersTotal()-1;i>=0;i--)
       {
          if (OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
            if (OrderSymbol()==Symbol())           
                if(OrderMagicNumber()==magik)
                   {                                                                
                     if(OrderType()==OP_BUY)      
                        Price_close=NormalizeDouble(Bid,Digits); 
                     if(OrderType()==OP_SELL)       
                        Price_close=NormalizeDouble(Ask,Digits); 

                     if(OrderClose(OrderTicket(),OrderLots(),Price_close,slippage))                        
                           return (true);
                   }                                         
      }
return(false);
}

//Taking a decision 
int GetAction()
{
   int TotalDeals;
   int type=0;
   int N=OrdersTotal(); 

// Counting current positions     
   for(int i = N - 1; i >= 0 ; i--)
      {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
         if( OrderSymbol()==Symbol())
            TotalDeals++;
            type=OrderType();       
       }    

   if (TotalDeals==0)
   {
      pos=0;
   }
   else
   {
      if (type==OP_BUY)
         pos=2;
      if (type==OP_SELL)
         pos=-2;
   }

// Beginning of the night session, determination of the flat boundaries by two preceding bars
   if (Hour()==h_beg)
   {
      max=MathMax(High[1], High[2]);
      min=MathMin(Low[1],Low[2]);
      Buy_count=0;
      Sell_count=0;
   }

// End of session, closing of all positions and disabling trading operations by the Expert Advisor
   if ((Hour()>=h_end)&&(Hour()<h_beg))
   {
      Buy_count=1;
      Sell_count=1;
      max=0;
      min=0;
      if (TotalDeals!=0)
         CloseOrder();
   } 

// Checking for position opening       
      if ((Bid>max)&&(max!=0)&&(pos==0)&&(Sell_count==0))      
            pos=-1;                  

      if ((Ask<min)&&(min!=0)&&(pos==0)&&(Buy_count==0))             
            pos=1;     

   return (0);       
}

//Processed at every tick
int start()
  {
   int action;
   double profit;
   double stop=0;
   double price=0;
   int ticket=-1;  

   GetAction();   
   if (pos==1)
         {
               stop=NormalizeDouble(Ask-StopLoss*Point,Digits);
               profit=(min+TakeProfit*Point);             
               pos=2;                                      

               while (ticket<0)
               {
                  if (!IsTradeContextBusy( )) 
                     ticket=OrderSend(Symbol(),OP_BUY,Lots,Ask,slippage,0,0,NULL,magik,0,Green);
                  if (ticket>0)
                     OrderModify(ticket,0,stop,profit,0,Blue);                           

                  if(ticket<0)
                     Print("OrderSend failed with error #",GetLastError());

                  Sleep(5000);
                  RefreshRates();
               }
               Buy_count=1;                       
         }  

   if (pos==-1)
         {
               stop=NormalizeDouble(Bid+StopLoss*Point,Digits);
               profit=(max-TakeProfit*Point); 
               pos=-2;                                   

               while (ticket<0)
               {
                  if (!IsTradeContextBusy( )) 
                     ticket=OrderSend(Symbol(),OP_SELL,Lots,Bid,slippage,0,0,NULL,magik,0,Green);

                  if (ticket>0)
                     OrderModify(ticket,0,stop,profit,0,Blue);                           

                  if(ticket<0)
                     Print("OrderSend failed with error #",GetLastError());

                  Sleep(5000);
                  RefreshRates();
               }
               Sell_count=1;
        }                            
   return(0);
  }

La prueba

Como se puede observar en el siguiente gráfico, algunas transacciones son realmente interesantes: comprar prácticamente en el nivel LOW (mínimo) y vender prácticamente en el nivel HIGH (máximo) de los precios de la noche. Existen algunas excepciones que normalmente están cerrados en este intervalo de tiempo.

Las pruebas han demostrado que este Asesor Experto sería capaz de ganar más de un 30 % en dos meses haciendo trading con un lote de 10 0000 dólares estadounidenses de depósito. Si incrementamos el riesgo aún más, podremos ver cómo pueden las cuentas PAMM de Alpari conseguir unos resultados del 1000 % en sólo un par de meses.

Uso en la práctica

Por supuesto, no todo es de color de rosa, de lo contrario hubiera aumentado la cantidad de millonarios de forma drástica durante los últimos seis meses. ¿Qué es lo que impide obtener grandes beneficios haciendo trading de noche?

1) Los márgenes por la noche son de 1,5 a 2 veces más anchos para las divisas que son especialmente buenas para el trading de noche; EURCHF, GBPCAD y EURCAD.

2) Las condiciones de trading con grandes beneficios pueden llegar a ser mucho peores en algunos centros de negocios.

3) Puede producirse una serie de grandes operaciones con pérdidas, por ejemplo, después de la intervención del EURCHF/USDCHF.

4) Hay que ajustar los valores de TP constantemente, sobre todo hacia abajo. Mientras que en invierno pudimos recoger el beneficio (take profit) a 40 puntos para una transacción en EURCAD, este valor está ahora alrededor de 20 puntos.

El Asesor Experto para el trading de noche proporcionado en este artículo es muy sencillo y se puede hacer mucho más complejo. Se puede hacer esto de muchas maneras, incluyendo:

1) escalabilidad;

2) análisis de la volatilidad;

3) análisis de las noticias (para evitar el riesgo de las intervenciones);

4) análisis de los principales pares de divisas de los que dependen los pares de divisas cruzados (por ejemplo, para EURCHF serían EURUSD y USDCHF);

5) algoritmos de entrada más complejos.

Se puede utilizar la plantilla proporcionada en este artículo en el trading real. Se obtuvo alrededor del 50 % por año durante sus seis meses de uso. Aunque el Asesor Experto en sí es de poca utilidad en la actualidad, este artículo puede dar un empujón a nuevas ideas que puedan utilizar los miembros del foro o el autor de este artículo.

Conclusión

El trading de noche ofrece la oportunidad de conseguir buenos de beneficio en invierno, mientras que es muy difícil en primavera y peor aún en verano. Con esta tendencia es muy difícil hacer cualquier afirmación para el otoño. Sin embargo, la estrategia tiene el derecho de existir ya que su uso fue capaz de aumentar el depósito en una cuenta real.

El futuro dirá si la estrategia ha dejado de ser útil o no. Aunque el Asesor Experto proporcionado en el artículo es muy sencillo, no se puede dejar de lado y se puede volver a utilizar cuando se produzcan noches planas de nuevo.