DokümantasyonBölümler
MQL5 ReferansıStandart KütüphaneBilimsel ÇizelgelerCAxisValuesFunctionFormat 

ValuesFunctionFormat (Get yöntemi)

Eksen değerlerinin gösterilme biçimini tanımlayan fonksiyonun işaretçisini alır.

DoubleToStringFunction  ValuesFunctionFormat()

Dönüş Değeri

Eksen değerlerinin gösterilme biçimini tanımlayan fonksiyonun işaretçisi.

ValuesFunctionFormat (Set yöntemi)

Eksen değerlerinin gösterilme biçimini tanımlayan fonksiyonun işaretçisini ayarlar.

void  ValuesFunctionFormat(
   DoubleToStringFunction  func      // nümerik değerleri dizgi biçimine dönüştüren fonksiyon 
   )

Parametreler

func

[in]  Nümerik değerleri dizgi biçimine dönüştüren özel fonksiyon.

Örnek:

graphics_close

X ekseni değerlerinin gösterilme şekli şu kodla değiştirilebilir:

//+------------------------------------------------------------------+
//|                                              DateAxisGraphic.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Graphics\Graphic.mqh>
//--- verileri depolamak için bir dizi
double arrX[];
double arrY[];
//+------------------------------------------------------------------+
//| X-ekseni üzerinde değerler oluşturan özel fonksiyon              |
//+------------------------------------------------------------------+
string TimeFormat(double x,void *cbdata)
  {
   return(TimeToString((datetime)arrX[ArraySize(arrX)-(int)x-1]));
  }
//+------------------------------------------------------------------+
void OnStart()
  {
   MqlRates rates[];
   CopyRates(Symbol(),Period(),0,100,rates);
   ArraySetAsSeries(rates,true);
   int size=ArraySize(rates);
   ArrayResize(arrX,size);
   ArrayResize(arrY,size);
   for(int i=0; i<size;++i)
     {
      arrX[i]=(double)rates[i].time;
      arrY[i]=rates[i].close;
     }
//--- grafiği oluştur
   CGraphic graphic;
   if(!graphic.Create(0,"DateAxisGraphic",0,30,30,780,380))
     {
      graphic.Attach(0,"DateAxisGraphic");
     }
//--- eğriyi oluştur
   CCurve *curve=graphic.CurveAdd(arrY,CURVE_LINES);
//--- X-eksenini al
   CAxis *xAxis=graphic.XAxis();
//--- X-ekseninin özelliklerini ayarla
   xAxis.AutoScale(false);
   xAxis.Type(AXIS_TYPE_CUSTOM);
   xAxis.ValuesFunctionFormat(TimeFormat);
   xAxis.DefaultStep(20.0);
//--- çiz 
   graphic.CurvePlotAll();
   graphic.Update();
  }