ДокументацияРазделы
Справочник MQL5Стандартная библиотекаНаучные графикиCAxisValuesFunctionFormat 

ValuesFunctionFormat (Метод Get)

Возвращает указатель на функцию, определяющую формат вывода значений на оси.

DoubleToStringFunction  ValuesFunctionFormat()

Возвращаемое значение

Указатель на функцию, определяющую формат вывода значений на оси.

ValuesFunctionFormat (Метод Set)

Устанавливает указатель на функцию, которая определяет формат вывода значений на оси.

void  ValuesFunctionFormat(
   DoubleToStringFunction  func      // функция для конвертирования числовых значений в строку 
   )

Параметры

func

[in]  Пользовательская функция для конвертирования числовых значений в строку.

Пример:

graphics_close

Формат вывода значений на оси X был изменен с помощью следующего кода:

//+------------------------------------------------------------------+
//|                                              DateAxisGraphic.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Graphics\Graphic.mqh>
//--- array for store values
double arrX[];
double arrY[];
//+------------------------------------------------------------------+
//| Custom function for create values on X-axis                      |
//+------------------------------------------------------------------+
string TimeFormat(double x,void *cbdata)
  {
   return(TimeToString((datetime)arrX[ArraySize(arrX)-(int)x-1]));
  }
//+------------------------------------------------------------------+
void OnStart()
  {
   MqlRates rates[];
   CopyRates(Symbol(),Period(),0,100,rates);
   ArraySetAsSeries(rates,true);
   int size=ArraySize(rates);
   ArrayResize(arrX,size);
   ArrayResize(arrY,size);
   for(int i=0; i<size;++i)
     {
      arrX[i]=(double)rates[i].time;
      arrY[i]=rates[i].close;
     }
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"DateAxisGraphic",0,30,30,780,380))
     {
      graphic.Attach(0,"DateAxisGraphic");
     }
//--- create curve
   CCurve *curve=graphic.CurveAdd(arrY,CURVE_LINES);
//--- gets the X-axis
   CAxis *xAxis=graphic.XAxis();
//--- sets the X-axis properties
   xAxis.AutoScale(false);
   xAxis.Type(AXIS_TYPE_CUSTOM);
   xAxis.ValuesFunctionFormat(TimeFormat);
   xAxis.DefaultStep(20.0);
//--- plot 
   graphic.CurvePlotAll();
   graphic.Update();
  }