DokümantasyonBölümler
MQL5 ReferansıTerminalin Global DeğişkenleriGlobalVariableDel 

GlobalVariableDel

Müşteri terminalinden bir global değişkeni siler.

bool  GlobalVariableDel(
   string  name      // Global değişkenin ismi
   );

Parametreler

name

[in]  Global değişkenin ismi.

Dönüş değeri

Başarı durumunda 'true' değerine, aksi durumda 'false' değerine dönüş yapacaktır. Hata ile ilgili bilgi almak için, GetLastError() fonksiyonunun çağrılması gerekir.

Not

Global değişkenler, son erişimlerinin ardından 4 hafta boyunca müşteri terminali tarafından saklanır, sonra otomatik olarak silinirler.

 

Örnek:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#define   GV_NAME    "TestGlobalVariableDel"
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- GV_NAME adlı müşteri terminali global değişkeninin varlığını kontrol et
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("Terminal global variable named \"%s\" does not exist", GV_NAME);
      return;
     }
     
//--- GV_NAME adlı müşteri terminali global değişkenini sil
   if(!GlobalVariableDel(GV_NAME))
     {
      Print("GlobalVariableDel() failed. Error ",GetLastError());
      return;
     }
     
//--- GV_NAME adlı müşteri terminali global değişkenini silmenin başarılı olup olmadığını kontrol et
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("The terminal global variable named \"%s\" was successfully deleted", GV_NAME);
     }
     
   /*
   GV_NAME adlı müşteri terminali global değişkeninin mevcut olmadığı durumda sonuç
   Terminal global variable named "TestGlobalVariableDel" does not exist
   
   GV_NAME adlı müşteri terminali global değişkeninin mevcut olduğu durumda sonuç
   The terminal global variable named "TestGlobalVariableDel" was successfully deleted
   */
  }