GlobalVariableDel

bool  GlobalVariableDel(
   string  name      // 글로벌 변수 이름
   );

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#define   GV_NAME    "TestGlobalVariableDel"
 
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                          |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- GV_NAME이라는 클라이언트 터미널 전역 변수가 있는지 확인합니다.
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("Terminal global variable named \"%s\" does not exist", GV_NAME);
      return;
     }
     
//--- GV_NAME이라는 클라이언트 터미널 전역 변수를 삭제합니다.
   if(!GlobalVariableDel(GV_NAME))
     {
      Print("GlobalVariableDel() failed. Error ", GetLastError());
      return;
     }
     
//--- 클라이언트 터미널 전역 변수 GV_NAME 삭제 성공 여부 확인
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("The terminal global variable named \"%s\" was successfully deleted", GV_NAME);
     }
     
   /*
   다음과 같은 클라이언트 터미널 전역 변수 이름이 없는 경우의 결과GV_NAME
   Terminal global variable named "TestGlobalVariableDel" does not exist
   
   다음과 같은 클라이언트 터미널 전역 변수가 이름이 있는 경우의 결과GV_NAME
   The terminal global variable named "TestGlobalVariableDel" was successfully deleted
   */
  }