DocumentaçãoSeções
Referência MQL5Variáveis Globais do TerminalGlobalVariableDel 

GlobalVariableDel

Exclui uma variável global a partir do terminal do cliente.

bool  GlobalVariableDel(
   string  name      // Nome da variável global
   );

Parâmetros

name

[in]  Nome da variável global.

Valor do Retorno

Se bem sucedida, a função retorna true, caso contrário ela retorna false. Para obter uma informação sobre o erro é necessário chamar a função GetLastError().

Observação

As variáveis globais existem no terminal do cliente durante 4 semanas desde a última utilização, então eles são excluídos automaticamente.

 

Exemplo:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#define   GV_NAME    "TestGlobalVariableDel"
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- vamos verificar a existência da variável global do terminal de cliente com o nome GV_NAME
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("Terminal global variable named \"%s\" does not exist", GV_NAME);
      return;
     }
     
//--- vamos excluir a variável global do terminal de cliente com o nome GV_NAME
   if(!GlobalVariableDel(GV_NAME))
     {
      Print("GlobalVariableDel() failed. Error ",GetLastError());
      return;
     }
     
//--- vamos verificar o sucesso da exclusão da variável global do terminal de cliente com o nome GV_NAME
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("The terminal global variable named \"%s\" was successfully deleted", GV_NAME);
     }
     
   /*
 resultado na ausência da variável global do terminal de cliente com o nome GV_NAME
   Terminal global variable named "TestGlobalVariableDel" does not exist
   
 resultado quando existe a variável global do terminal de cliente com o nome GV_NAME
   The terminal global variable named "TestGlobalVariableDel" was successfully deleted
   */
  }