DokumentationKategorien
Nachschlagewerk MQL5Globalvariablen des KundenterminalsGlobalVariableDel 

GlobalVariableDel

Entfernt globale Variable des Client-Terminals.

bool  GlobalVariableDel(
   string  name      // Name
   );

Parameter

name

[in]  Name der globalen Variable.

Rückgabewert

Bei der erfolgreichen Entfernung gibt die Funktion true zurück, anderenfalls false. Für die Erhaltung der fehlerbezogenen Information muss die Funktion GetLastError() aufgerufen werden.

Hinweis

Globale Variablen existieren im Client-Terminal innerhalb von 4 Wochen seit dem letzten Zugriffs, danach werden sie automatisch entfernt.

 

Beispiel:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#define   GV_NAME    "TestGlobalVariableDel"
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Überprüfen, ob die globale Variable GV_NAME des Client-Terminals vorhanden ist
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("Terminal global variable named \"%s\" does not exist", GV_NAME);
      return;
     }
     
//--- Löschen der globalen Variablen GV_NAME des Client-Terminals
   if(!GlobalVariableDel(GV_NAME))
     {
      Print("GlobalVariableDel() failed. Error ",GetLastError());
      return;
     }
     
//--- Überprüfen, ob die globale Variable GV_NAME des Client-Terminals erfolgreich gelöscht wurde
   if(!GlobalVariableCheck(GV_NAME))
     {
      PrintFormat("The terminal global variable named \"%s\" was successfully deleted", GV_NAME);
     }
     
   /*
   Ergebnis bei Fehlen der globalen Variable des Client-Terminals mit dem Namen GV_NAME
   Terminal global variable named "TestGlobalVariableDel" does not exist
   
   Ergebnis im Falle des Vorhandenseins der globalen Variable des Client-Terminals mit dem Namen GV_NAME
   The terminal global variable named "TestGlobalVariableDel" was successfully deleted
   */
  }