Référence MQL5Fonctions sur les ObjetsObjectGetTimeByValue

ObjectGetTimeByValue

Retourne la valeur du temps pour l'objet indiqué avec son prix.

datetime  ObjectGetTimeByValue(
   long    chart_id,     // identificateur du graphique
   string  name,         // nom de l'objet
   double  value,        // prix
   int     line_id       // ligne
   );

Paramètres

chart_id

[in] L'identificateur du graphique. 0 signifie le graphique courant.

name

[in] Le nom de l'objet.

value

[in] La valeur du prix.

line_id

[in] L'identificateur de la ligne.

Valeur de Retour

La valeur du temps pour la valeur indiquée du prix de l'objet indiqué.

Note

La fonction utilise un appel synchrone, ce qui signifie que la fonction attend la fin de l'exécution de toutes les commandes présentes dans la queue de ce graphique avant cet appel. C'est pourquoi cette fonction peut être consommatrice en terme de temps. Cette caractéristique doit être prise en compte lors de l'utilisation d'un grand nombre d'objets sur un graphique.

Puisqu'un objet à une coordonnée de prix peut avoir plusieurs valeurs, il est nécessaire d'indiquer le numéro de la ligne. Cette fonction est employée seulement pour les objets suivants :

La ligne de tendance (OBJ_TREND)
La ligne de tendance selon un angle (OBJ_TRENDBYANGLE)
Le ligne de Gann (OBJ_GANNLINE)
Le canal équidistant (OBJ_CHANNEL) - 2 lignes
Le canal de régression linéaire (OBJ_REGRESSION) - 3 lignes
Le canal d'écart type (OBJ_STDDEVCHANNEL) - 3 lignes
La ligne flêchée (OBJ_ARROWED_LINE)

Exemple :

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#define   OBJ_NAME   "TestObjectGetTimeByValue" // nom de l'objet graphique
#define   STEP       100                        // pas (step) du prix

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- ID, symbole
   long   chart_id=ChartID();
   string chart_symbol=ChartSymbol(chart_id);

//--- récupère la valeur du point du symbole du graphique
   double point=SymbolInfoDouble(chart_symbol, SYMBOL_POINT);
   if(point==0)
     {
      PrintFormat("Failed to get the Point value of the \"%s\" symbol. Error %d", chart_symbol, GetLastError());
      return;
     }

//--- crée un canal équidistant entre le plus haut de la barre visible de gauche et le plus bas de celle de droite.
   if(!CreateChannel(chart_id))
      return;

//--- valeurs maximales et minimales du graphique, décimales du symbole du graphique
   double chart_max=ChartGetDouble(chart_id, CHART_PRICE_MAX);
   double chart_min=ChartGetDouble(chart_id, CHART_PRICE_MIN);
   int    digits=(int)SymbolInfoInteger(chart_symbol, SYMBOL_DIGITS);

//--- tant que le prix calculé est supérieur à la valeur minimale du prix du graphique,
//--- parcours les prix du graphique en boucle avec STEP et récupère la valeur temps
//--- pour la valeur de prix calculée de chaque ligne du canal équidistant.
//--- écrit l'heure de réception de chaque ligne dans le journal
   int index=0;
   double price=chart_max;
   do
     {
      price=chart_max-STEP*index*point;
      datetime time0=ObjectGetTimeByValue(chart_id, OBJ_NAME, price, 0);
      datetime time1=ObjectGetTimeByValue(chart_id, OBJ_NAME, price, 1);
      string   time0_str=(time0>0 ? TimeToString(time0) : "No value at this price");
      string   time1_str=(time1>0 ? TimeToString(time1) : "No value at this price");
      string   idx=StringFormat("%02d", index);
      PrintFormat("[%s] For price %.*f the time value at line 0: %s, at line 1: %s", idx, digits, price, time0_str, time1_str);
      index++;
     }
   while(!IsStopped() && price>=chart_min);

//--- attends 5 secondes et nettoie tout
   Sleep(5000);
   ObjectDelete(chart_id, OBJ_NAME);
   ChartRedraw(chart_id);
   /*
   résultat :
   [00] For price 1.26110 the time value at line 0: No value at this price,  at line 1: No value at this price
   [01] For price 1.26010 the time value at line 0: 2024.12.30 17:00, at line 1: No value at this price
   [02] For price 1.25910 the time value at line 0: 2024.12.30 22:30, at line 1: No value at this price
   [03] For price 1.25810 the time value at line 0: 2024.12.31 04:00, at line 1: 2024.12.30 16:30
   [04] For price 1.25710 the time value at line 0: 2024.12.31 10:00, at line 1: 2024.12.30 22:00
   [05] For price 1.25610 the time value at line 0: 2024.12.31 15:30, at line 1: 2024.12.31 03:30
   [06] For price 1.25510 the time value at line 0: 2024.12.31 21:00, at line 1: 2024.12.31 09:00
   [07] For price 1.25410 the time value at line 0: 2025.01.02 03:30, at line 1: 2024.12.31 14:30
   [08] For price 1.25310 the time value at line 0: No value at this price, at line 1: 2024.12.31 20:30
   [09] For price 1.25210 the time value at line 0: No value at this price, at line 1: 2025.01.02 03:00
   [10] For price 1.25110 the time value at line 0: No value at this price, at line 1: No value at this price
   [11] For price 1.25010 the time value at line 0: No value at this price, at line 1: No value at this price
   [12] For price 1.24910 the time value at line 0: No value at this price, at line 1: No value at this price
   [13] For price 1.24810 the time value at line 0: No value at this price, at line 1: No value at this price
   */
  }
//+--------------------------------------------------------------------------------------------+
//| Construit un canal équidistant du +haut de la barre de gauche au +bas de celle de droite   |
//+--------------------------------------------------------------------------------------------+
bool CreateChannel(const long chart_id=0)
  {
   long     bar1  =0, bar2  =0, visible=0;
   datetime time1 =0, time2 =0;
   double   price1=0, price2=0;

//--- récupère la première barre du graphique visible à gauche
   ResetLastError();
   if(!ChartGetInteger(chart_id, CHART_FIRST_VISIBLE_BAR, 0, bar1))
     {
      PrintFormat("%s: ChartGetInteger() failed. Error %d",__FUNCTION__, GetLastError());
      return(false);
     }
//--- nombre de barres visibles sur le graphique
   if(!ChartGetInteger(chart_id, CHART_VISIBLE_BARS, 0, visible))
     {
      PrintFormat("%s: ChartGetInteger() failed. Error %d",__FUNCTION__, GetLastError());
      return(false);
     }

//--- ajuste les valeurs obtenues et calcule l'indice de la première barre visible à droite.
   bar1-=1;
   visible-=2;
   bar2=bar1-visible;

//--- symbole du graphique
   string symbol=ChartSymbol(chart_id);

//--- récupère l'heure de la première barre visible sur la gauche du graphique
   ResetLastError();
   datetime time_array[1];
   if(CopyTime(symbol, PERIOD_CURRENT, (int)bar1, 1, time_array)!=1)
     {
      PrintFormat("%s: CopyTime() failed. Error %d",__FUNCTION__, GetLastError());
      return(false);
     }
   time1=time_array[0];

//--- récupère l'heure de la première barre du graphique visible sur la droite
   if(CopyTime(symbol, PERIOD_CURRENT, (int)bar2, 1, time_array)!=1)
     {
      PrintFormat("%s: CopyTime() failed. Error %d",__FUNCTION__, GetLastError());
      return(false);
     }
   time2=time_array[0];

//--- récupère le prix le Plus Haut de la première barre visible sur la gauche du graphique
   double price_array[];
   if(CopyHigh(symbol, PERIOD_CURRENT, (int)bar1, 1, price_array)!=1)
     {
      PrintFormat("%s: CopyHigh() failed. Error %d",__FUNCTION__, GetLastError());
      return(false);
     }
   price1=price_array[0];

//--- récupère le prix le Plus Bas de la première barre visible sur la droite du graphique
   if(CopyLow(symbol, PERIOD_CURRENT, (int)bar2, 1, price_array)!=1)
     {
      PrintFormat("%s: CopyLow() failed. Error %d",__FUNCTION__, GetLastError());
      return(false);
     }
   price2=price_array[0];

//--- calcule la plage de prix du graphique en points
//--- pour un canal équidistant, la distance de la deuxième ligne sera égale à 1/3 de la plage de prix
   double range=price1-price2;
   double distance=range*0.3;

//--- aux coordonnées calculées, crée un objet graphique : le canal équidistant
   if(!ObjectCreate(chart_id, OBJ_NAME, OBJ_CHANNEL, 0, time1, price1, time2, price2, time1, price1-distance))
     {
      PrintFormat("%s: ObjectCreate() failed. Error %d",__FUNCTION__, GetLastError());
      return(false);
     }

//--- met à jour le graphique et retourne 'true'
   ChartRedraw(chart_id);
   return(true);
  }

Voir aussi

Les types des objets

ObjectFind

ObjectGetValueByTime