Оптимизация и тонкая настройка исходного кода для улучшения результатов тестирования на истории

MetaTrader 5 — Примеры | 28 июля 2025, 08:23

Введение

Достижение надежных результатов тестирования на истории в алгоритмической торговле зависит не только от надежной логики стратегии, но также от эффективности и точности базового кода. Оптимизация и тонкая настройка исходного кода имеют решающее значение для обеспечения надлежащей работы советников (EA), минимизации вычислительных затрат и максимальной точности исполнения. Плохо оптимизированный код может исказить результаты тестирования на истории из-за задержки выполнения ордеров, неверного обнаружения сигналов или исчерпания ресурсов — проблем, которые маскируют истинный потенциал стратегии.

В процессе разработки стратегии мы предпримем несколько ключевых шагов, чтобы гарантировать, что советник будет как функционально сильным, так и технически надежным. Начнем с добавления пользовательских вспомогательных функций и повторно используемых логических блоков для оптимизации операций и исключения повторяющегося кода. Затем введем хорошо структурированные переменные и константы, улучшающие читаемость кода и упрощающие настройку параметров. Эти основополагающие изменения помогут поддерживать код в рабочем состоянии и улучшат общее время выполнения при больших нагрузках во время тестирования на истории или мультисимвольном тестировании.

Еще одной важной областью усовершенствования является более эффективное использование технических индикаторов. Вместо того, чтобы слепо рассчитывать индикаторы на каждом тике или баре, мы реализуем более умную логику обновления, чтобы уменьшить нагрузку и лаг. Мы также будем экспериментировать с различными комбинациями индикаторов для поддержки более эффективного принятия решений в логике советника. Объединив структурное усовершенствование кода, учитывающие эффективность функции и оптимизацию индикаторов, мы можем радикально улучшить как качество, так и скорость тестирования на истории, приближая нас к стабильно прибыльной и готовой к развертыванию стратегии.

Разработка стратегии

Разработка нашей алгоритмической торговой стратегии начинается со структурированного, методического подхода к распознаванию паттернов и проверке сигналов. В своей основе стратегия имеет фреймворк, основанный на свечном анализе, предназначенный для выявления высоковероятных сценариев разворота. Для длинных позиций логика систематически обнаруживает три последовательные бычьи свечи, за которыми следуют одна или две корректирующие медвежьи свечи, достигающие кульминации в подтверждающей бычьей свече на индексе 1 (последний закрытый бар).

Наоборот, короткие позиции активируются обратным паттерном: три последовательные медвежьи свечи, за которыми следуют одна или две коррекционные бычьи свечи и завершаются подтверждающей медвежьей свечой с индексом 1. Такая конфигурация гарантирует, что сигналы подтверждаются только при формировании нового бара, согласуя исполнение с подтвержденным ценовым действием, а не с внутрибарными колебаниями.

Для практической реализации этой логики архитектура стратегии будет отдавать приоритет модульной разработке кода и вычислительной эффективности. Во-первых, будут реализованы вспомогательные функции для абстрагирования повторяющихся задач, таких как классификация японских свечей (определение бычьего/медвежьего тренда) и проверка последовательности (последовательная проверка паттернов свечей). Эти функции будут использовать нативные методы доступа к ценовым данным на MQL5, включая `iOpen()` и `iClose()`, минимизируя при этом избыточные вычисления за счет кэширования статических переменных.

Во-вторых, событийно-управляемая модель исполнения гарантирует, что советник (EA) будет обрабатывать сигналы только при формировании нового бара, что определяется путем сравнения временных меток в индексе 1. Такой подход снижает ненужную вычислительную нагрузку и предотвращает ложные триггеры при разработке бара.

Заключительный этап разработки будет сосредоточен на оптимизации эффективности и тестировании надежности. Для повышения точности входа/выхода будут интегрированы такие технические индикаторы, как фильтры объема или уровни стоп-лосса с поправкой на волатильность. Кроме того, исторические буферные массивы будут предварительно выделены для хранения паттернов японских свечей, что снизит непроизводительные потери на выделение памяти во время работы. Объединив эти элементы — модульную конструкцию кода, управляемое событиями выполнение и интеграцию стратегических индикаторов — советник достигнет баланса между отзывчивостью и эффективностью использования ресурсов.

Код:

//+------------------------------------------------------------------+
//|                           Includes                               |
//+------------------------------------------------------------------+
#include <Trade/Trade.mqh>
MqlTick CTick, PTick;
CTrade trade;

enum InLot{
   Lot_fixed,
   Lot_dynamic,
};

//+------------------------------------------------------------------+
//|                           Inputs                                 |
//+------------------------------------------------------------------+
input group "--------------General Inputs--------------"
input int RSI_Period = 14;
input int    TakeProfit   = 100;     // TP in points
input ulong  MagicNumber  = 888888;  // EA identifier
input int    MaxBarsCheck = 8;       // Historical bars to analyze
input InLot Lot_mode = Lot_fixed;
input double  In_Lot = 0.01;
input bool TrailYourStop = true;
input int trailingStop = 50;
//input int StopLoss = 234;

//+------------------------------------------------------------------+
//|                      Global Variables                            |
//+------------------------------------------------------------------+
int rsiHandle, macdHanlde;
datetime lastBarTime;

double pointMultiplier;
double StopLoss     = 150;

bool bullish_pattern_met = false;
bool bearish_pattern_met = false;

double first_bullish_low = 0.0;
double first_bearish_high = 0.0;

ENUM_TIMEFRAMES TimeFrame = PERIOD_CURRENT;

Архитектура советника объединяет основные библиотеки и структуры данных, обеспечивающие бесперебойную работу торговых функций. Включение библиотеки <Trade/Trade.mqh> обеспечивает доступ к классу CTrade, оптимизируя операции по управлению ордерами, такие как открытие, изменение и закрытие позиции. Две структуры MqlTick — `CTick` и `PTick` — используются для отслеживания данных о ценах в реальном времени, обеспечивая точность периода исполнения и анализа состояния рынка. Перечисление (InLot) определяет методологию расчета размера позиции советника, предлагая как фиксированный (Lot_fixed), так и динамический (Lot_dynamic) режимы, причем последний зарезервирован для возможных расчетов лота с поправкой на риск в будущих циклах.

Пользовательская настройка осуществляется с помощью специального интерфейса ввода, позволяющего настраивать параметры без изменения основного кода. К критически важным настройкам относятся RSI_Period (по умолчанию: 14), управляющий индикатором, чью чувствительность мы будем использовать позже в процессе разработки, а также значения `TakeProfit ` и `trailingStop` (в пунктах) для определения пороговых значений риска и прибыли. Параметр `MagicNumber` обеспечивает целостность идентификации сделки, а `MaxBarsCheck` определяет глубину исторических данных для анализа паттернов. Гибкость управления размером позиции достигается с помощью Lot_mode и In_Lot, а функции трейлинг-стопа (TrailYourStop, trailingStop) автоматизируют защиту прибыли по мере благоприятного развития сделок.

На внутреннем уровне глобальные переменные управляют сложными операционными рабочими процессами. Хэндлы индикатора (rsiHandle, macdHandle) хранят экземпляры индикатора и ссылаются на них во время работы, в то время как `lastBarTime` облегчает временную синхронизацию, записывая временную метку последней проанализированной свечи. Булевы флаги (bullish_pattern_met, bearish_pattern_met) и маркеры уровня колебания (first_bullish_low, first_bearish_high) динамически отслеживают рыночные условия, а TimeFrame указывает периодичность работы советника, по умолчанию устанавливая таймфрейм активного графика для удобства немедленного использования.

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   // Create RSI and MACD indicator handles
   rsiHandle = iRSI(_Symbol, TimeFrame, RSI_Period, PRICE_CLOSE);
   macdHanlde = iMACD(_Symbol, TimeFrame, 12, 26, 9, PRICE_CLOSE);

   return(INIT_SUCCEEDED);
}

Функция `Oninit()`корректно инициализирует индикаторы RSI и MACD, назначая корректные настройки для их периодов и типов цен. Эти индикаторы сохраняются в памяти для будущего использования при оптимизации торговых сигналов. Успешная настройка возвращает INIT_SUCCEEDED, подтверждая готовность советника к работе.

void OnTick(){

   if(!NewBarTrigger()) return;
   ThreeBar();
}
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//| Detects new bar formation                                        |
//+------------------------------------------------------------------+
bool NewBarTrigger(){

   datetime currentTime = iTime(_Symbol, PERIOD_CURRENT, 0);
   if(currentTime != lastBarTime){
      lastBarTime = currentTime;
      return true;
   }
   return false;
}

double getHigh(int index) {
    return iHigh(_Symbol, _Period, index);
}

double getLow(int index) {
    return iLow(_Symbol, _Period, index);
}

//+------------------------------------------------------------------+
//| Execute trade with risk parameters                               |
//+------------------------------------------------------------------+
void ExecuteTrade(ENUM_ORDER_TYPE tradeType)
{
   double point = SymbolInfoDouble(_Symbol, SYMBOL_POINT);
   double price = (tradeType == ORDER_TYPE_BUY) ? SymbolInfoDouble(_Symbol, SYMBOL_ASK) :                                                  SymbolInfoDouble(_Symbol, SYMBOL_BID);

   // Convert StopLoss and TakeProfit from pips to actual price distances
   double sl_distance = StopLoss * point;
   double tp_distance = TakeProfit * point;
   
   double sl = (tradeType == ORDER_TYPE_BUY) ? price - sl_distance :
                                               price + sl_distance;   
   double tp = (tradeType == ORDER_TYPE_BUY) ? price + tp_distance :
                                               price - tp_distance;
   trade.PositionOpen(_Symbol, tradeType, In_Lot, price, sl, tp, NULL);
}

Функция `OnTick()` выполняет функцию пульса нашего советника, срабатывая при каждом входящем тике. Чтобы избежать избыточной обработки и ненужных вычислений, сначала проверяется наличие новой свечи с помощью `NewBarTrigger()`. Если сформировался новый бар, мы затем вызываем функцию `ThreeBar()`, которая содержит нашу торговую логику и процедуру обнаружения паттернов.

Функция `NewBarTrigger()` отвечает за обнаружение начала новой свечи. Это делается путем сравнения текущего времени открытия свечи с ранее сохраненным (`lastBarTime`). Если обнаруживается новая временная метка, она обновляет `lastBarTime` и возвращает значение true, позволяя `OnTick()` продолжить работу. Это гарантирует, что торговые решения принимаются только один раз за бар, что имеет решающее значение для нашей стратегии, которая основана на подтверждениях закрытия бара. Вспомогательные функции `getHigh()` и `getLow()` — это простые служебные вызовы, которые возвращают максимальную и минимальную цену определенного индекса бара на текущем графике.

Функция `ExecuteTrade()` управляет размещением сделок с соответствующими параметрами риска. Сначала извлекает текущую рыночную цену в зависимости от типа сделки (покупка или продажа), затем рассчитывает стоп-лосс и тейк-профит в фактических ценовых единицах, конвертируя заданные пользователем значения пипсов/пунктов с использованием значения `Point` символа. Затем эти рассчитанные уровни передаются в метод `PositionOpen()` из класса `CTrade`, гарантируя, что каждая сделка выполняется с точным и последовательным контролем рисков.

//+------------------------------------------------------------------+
//| Candle pattern detection Function                                |
//+------------------------------------------------------------------+
void ThreeBar() {
   // Settings
   string symbol = Symbol();              // Current symbol
   ENUM_TIMEFRAMES timeframe = PERIOD_M5; // Timeframe (e.g., 1-hour)

   // Pattern detection variables
   int min_bullish_count = 3;
   int min_bearish_count = 3;
   int check_candles = 6;  // Check the last 6 candles for patterns

   bool bullish_pattern = false;
   bool bearish_pattern = false;
   static bool bullish_pattern_detected = false;
   static bool bearish_pattern_detected = false;

   // Loop through recent candles to search for patterns
   for (int i = check_candles; i >= min_bullish_count; i--) {
      
      // Reset pattern flags for each loop iteration
      bullish_pattern = false;
      bearish_pattern = false;

      // 1. Check for Bullish Trend Pattern
      int bullish_count = 0;
      int bearish_count = 0;

      // Count initial bullish candles
      for (int j = i; j >= i - min_bullish_count + 1; j--) {
         if (iClose(symbol, timeframe, j) > iOpen(symbol, timeframe, j)){
            bullish_count++;
            first_bullish_low = getLow(5);
         }
         else
            break;
      }

      // Check for 1 or 2 bearish candles followed by a bullish candle
      if (bullish_count >= min_bullish_count) {
         for (int j = i - bullish_count; j >= i - bullish_count - 1; j--) {
            if (iClose(symbol, timeframe, j) < iOpen(symbol, timeframe, j))
               bearish_count++;
            else
               break;
         }
         if ((bearish_count == 1 || bearish_count == 2) &&
             iClose(symbol, timeframe, i - bullish_count - bearish_count) > iOpen(symbol, timeframe, i - bullish_count - bearish_count)) {
            bullish_pattern = true;
         }
      }

      // 2. Check for Bearish Trend Pattern
      int bearish_candles_count = 0;
      int bullish_candles_count = 0;

      // Count initial bearish candles
      for (int j = i; j >= i - min_bearish_count + 1; j--) {
         if (iClose(symbol, timeframe, j) < iOpen(symbol, timeframe, j)){
            bearish_candles_count++;
            first_bearish_high = getHigh(5);
         }
         else
            break;
      }

      // Check for 1 or 2 bullish candles followed by a bearish candle
      if (bearish_candles_count >= min_bearish_count) {
         for (int j = i - bearish_candles_count; j >= i - bearish_candles_count - 1; j--) {
            if (iClose(symbol, timeframe, j) > iOpen(symbol, timeframe, j))
               bullish_candles_count++;
            else
               break;
         }
         if ((bullish_candles_count == 1 || bullish_candles_count == 2) &&
             iClose(symbol, timeframe, i - bearish_candles_count - bullish_candles_count) < iOpen(symbol, timeframe, i - bearish_candles_count - bullish_candles_count)) {
            bearish_pattern = true;
         }
      }

      // Print result and call functions only once for each pattern
      if (bullish_pattern && !bullish_pattern_detected) {
         Print("Bullish pattern conditions are met");
         ExecuteTrade(ORDER_TYPE_BUY); // Call to buyer function
         bullish_pattern_detected = true;
      } else if (!bullish_pattern) {
         bullish_pattern_detected = false; // Reset when conditions no longer met
      }

      if (bearish_pattern && !bearish_pattern_detected) {
         Print("Bearish pattern conditions are met");
         ExecuteTrade(ORDER_TYPE_SELL); // Call to seller function
         bearish_pattern_detected = true;
      } else if (!bearish_pattern) {
         bearish_pattern_detected = false; // Reset when conditions no longer met
      }   
   }
}

Функция `ThreeBar()` — это основная логика обнаружения паттернов нашего советника. Она анализирует недавние свечные формирования на таймфрейме M5 или любом другом таймфрейме, который вы загружаете в советник, для обнаружения потенциальных установок разворота бычьего или медвежьего тренда. Логика начинается со сканирования последних шести свечей для выявления паттернов, где за серией из как минимум трех последовательных бычьих или медвежьих свечей следует короткий откат (одна или две противоположные свечи), а затем подтверждающая свеча в исходном направлении тренда. Если такая структура обнаружена, это указывает на наличие допустимого паттерна.

В ходе каждого цикла сканирования ключевые ценовые точки, такие как минимум бычьего колебания или максимум медвежьего колебания, фиксируются для возможного использования в будущем, например для разрывов структуры или торговых фильтров.

В настоящее время советник открывает две позиции, когда у нас есть одна медвежья свеча после бычьей свечи, и открывает еще одну сделку после закрытия свечи, но открывает одну позицию, когда у нас есть две медвежьи свечи, за которыми следует бычья свеча. То же самое происходит и с сигналами на продажу. Чтобы решить эту проблему, нам нужно добавить `break`, который немедленно останавливает цикл, как только паттерн инициирует сделку. Это не позволяет советнику продолжать цикл далее на более ранние свечи и находить тот же паттерн в другом месте, особенно когда структура допускает как 1-барные, так и 2-барные откаты.

// Print result and call functions only once for each pattern
if (bullish_pattern && !bullish_pattern_detected) {
   Print("Bullish pattern conditions are met");
   ExecuteTrade(ORDER_TYPE_BUY);
   bullish_pattern_detected = true;
   break; // prevent further detection in this run
} else if (!bullish_pattern) {
   bullish_pattern_detected = false;
}
      
if (bearish_pattern && !bearish_pattern_detected) {
   Print("Bearish pattern conditions are met");
   ExecuteTrade(ORDER_TYPE_SELL);
   bearish_pattern_detected = true;
   break; // prevent further detection in this run
} else if (!bearish_pattern) {
   bearish_pattern_detected = false;
}

Включение индикаторных фильтров:

// Indicator buffers
double rsi_value[1];    // Use array for buffer storage
double macd_main[1];    
double macd_signal[1];
   
// Get indicator values - with error checking
if (CopyBuffer(rsiHandle, 0, 0, 1, rsi_value) <= 0) {
    Print("RSI CopyBuffer error: ", GetLastError());
    return;
}
   
if (CopyBuffer(macdHandle, 0, 0, 1, macd_main) <= 0) { 
    Print("MACD Main Line error: ", GetLastError());
    return;
}
   
if (CopyBuffer(macdHandle, 1, 0, 1, macd_signal) <= 0) { 
    Print("MACD Signal Line error: ", GetLastError());
    return;
}

Перед включением фильтров индикаторов в торговую логику мы должны извлечь и проверить значения индикаторов RSI и MACD с помощью `CopyBuffer()`. Это гарантирует, что советник получает самые последние показания от индикаторов. В приведенном выше коде мы используем массивы для хранения одного значения из каждого буфера индикатора, а обработка ошибок включается после каждого копирования буфера, чтобы выявить любые проблемы, такие как неудачный доступ к хэндлу или отсутствующие данные.

Если какой-либо буфер не может извлечь данные, функция завершает работу досрочно и регистрирует соответствующую ошибку, не давая советнику принимать торговые решения на основе недействительных или отсутствующих входных данных индикатора.

// Filter + Trade Logic
if (bullish_pattern && !bullish_pattern_detected &&
    rsi_value[0] > 50 && macd_main[0] > macd_signal[0])  
{
    Print("Bullish pattern confirmed with RSI(", rsi_value[0], ") and MACD(", 
          macd_main[0], "/", macd_signal[0], ")");
    ExecuteTrade(ORDER_TYPE_BUY);
    bullish_pattern_detected = true;
    break;
 }
else if (!bullish_pattern)
    bullish_pattern_detected = false;
      
if (bearish_pattern && !bearish_pattern_detected &&
    rsi_value[0] < 50 && macd_main[0] < macd_signal[0])  
{
    Print("Bearish pattern confirmed with RSI(", rsi_value[0], ") and MACD(", 
          macd_main[0], "/", macd_signal[0], ")");
    ExecuteTrade(ORDER_TYPE_SELL);
    bearish_pattern_detected = true;
    break;
}
else if (!bearish_pattern)
    bearish_pattern_detected = false;

Модель японских свечей из трех баров сама по себе часто дает плохие результаты при тестировании на исторических данных, поскольку она не учитывает общую рыночную тенденцию, что часто приводит к ложным сигналам. Для повышения эффективности мы внедряем подтверждение тренда путем включения индикаторов RSI и MACD непосредственно в блок принятия торговых решений.

Чтобы бычий сигнал был верным, нам теперь требуется, чтобы RSI был выше 50, что указывает на бычий импульс, а главная линия MACD находилась выше сигнальной линии, что указывает на подтверждение восходящего тренда. Аналогично, для медвежьих сигналов RSI должен быть ниже 50, а главная линия MACD должна быть ниже сигнальной линии. Такая логика фильтрации повышает точность торговли, согласуя входы с более широкой динамикой рынка.

Внедряя эти фильтры, мы гарантируем, что сделки, инициированные трехбарным паттерном, будут исполняться только при наличии поддержки технических индикаторов, отражающих преобладающее направление рынка. Такой подход с двойным подтверждением снижает частоту сделок во время нестабильных или боковых рынков и увеличивает вероятность входа в сделки, имеющие импульс.

В конечном счете, это усовершенствование повышает способность советника принимать решения, что приводит к более последовательным и благоприятным результатам тестирования на истории, а также помогает избегать резких колебаний, вызванных опорой исключительно на структуру японских свечей.

Результаты тестирования на истории по паре (XAU/USD)

Тестирование на истории оценивалось с использованием исторических данных о ценах XAUUSD (золото/доллар США) на 1-часовом таймфрейме в течение 4-месячного окна тестирования (26 ноября 2021 г. — 17 марта 2022 г.). Ключевые параметры включали в себя:

Период RSI: 14
Управление рисками: Тейк-профит (TP) 500 пунктов, стоп-лосс (SL) 150 пунктов, фиксированный размер лота
Конфигурация анализа: исторический период в 8 баров

Рыночный контекст.

В период тестирования средняя цена на золото составляла 1841,59 долл. США, а экстремальные значения волатильности варьировались от 1752,95 долл. США (минимум) до 2070,48 долл. США (максимум). Эта восходящая траектория отражает сильный бычий настрой, особенно очевидный в начале 2022 года, когда цены выросли примерно на 18%, достигнув мартовского пика. Выраженный восходящий тренд в этот период согласуется с макроэкономическими факторами.

Заключение

В этом процессе оптимизации мы устранили ограничения, связанные с опорой исключительно на трехбарную модель японских свечей для входа в сделку, включив ключевые технические индикаторы — RSI и MACD. Мы начали с обеспечения надежного извлечения данных с использованием хэндлов индикаторов и копирования буфера с проверкой ошибок. Затем мы применили эти индикаторы в качестве фильтров подтверждения в логике исполнения сделок, согласовывая сделки с преобладающей рыночной тенденцией. Это значительно повышает качество торговли и последовательность тестирования на истории за счет фильтрации маловероятных сигналов в условиях ранжирования или контртренда.

Таким образом, сочетание необработанных паттернов ценового действия с такими основанными на импульсе индикаторами, как RSI и MACD, создает более контекстно-ориентированную торговую систему. Такой многоуровневый подход повышает способность советника различать высококачественные и низкокачественные торговые настройки. Требуя совпадения свечных паттернов и более широких сигналов тренда, советник становится более дисциплинированным и менее восприимчивым к краткосрочному шуму, что в конечном итоге приводит к повышению эффективности и надежности как при тестировании на истории, так и при реальной торговле.

Дальнейшее совершенствование и исследования:

Область	Предложение	Преимущество
Динамический стоп-лосс или тейк-профит	Отрегулировать SL/TP на основе ATR или недавней волатильности	Делает управление рисками адаптивным к рыночным условиям
Улучшение фильтра тренда	Включать скользящие средние (например, 200 EMA) для определения долгосрочного тренда	Повышает точность направления входа
Контроль частоты сделок	Добавить время ожидания между сделками или ограничение максимального количества сделок в день	Уменьшает чрезмерную торговлю и концентрацию сделок
Мультитаймфреймовый анализ	Подтверждать тренды RSI и MACD на более высоких таймфреймах (например, H1, H4)	Повышает надежность сигнала за счет выравнивания по таймфреймам
Фильтрация новостей	Интегрировать экономический календарь или определение времени выхода новостей	Избегает сделок во время важных событий

Перевод с английского произведен MetaQuotes Ltd.
Оригинальная статья: https://www.mql5.com/en/articles/17702

Прикрепленные файлы |

Загрузить ZIP

OptimizationmgTweaking.mq5 (9.99 KB)

Предупреждение: все права на данные материалы принадлежат MetaQuotes Ltd. Полная или частичная перепечатка запрещена.

Другие статьи автора

Перейти к обсуждению на форуме трейдеров

Создание торговой панели администратора на MQL5 (Часть VIII): Панель аналитики

В этой статье мы углубимся в добавление полезных торговых показателей в специализированное окно, интегрированное в панель администратора советника. Основное внимание уделено внедрению MQL5 для разработки аналитической панели. Подчеркивается ценность данных, которые она предоставляет администраторам. Панель в основном играет образовательную роль, позволяя извлекать из процесса разработки ценные уроки, приносящие пользу как начинающим, так и опытным разработчикам. В статье демонстрируются безграничные возможности, которые предлагает данная серия в плане предоставления передовых программных инструментов. Кроме того, мы рассмотрим реализацию классов PieChart и ChartCanvas в рамках продолжающегося расширения возможностей панели администратора.

Квантовая нейросеть на MQL5 (Часть II): Обучаем нейросеть с обратным распространением ошибки на марковских матрицах ALGLIB

В статье представлена инновационная архитектура квантовой нейронной сети для алгоритмической торговли, объединяющая принципы квантовой механики с современными методами машинного обучения. Система включает квантовые эффекты (резонанс, интерференцию, декогеренцию), многоуровневую память различных временных масштабов, марковские цепи с библиотекой ALGLIB и адаптивное управление параметрами. Полная реализация выполнена на MQL5 с использованием встроенных типов matrix/vector, что устраняет барьеры внедрения в MetaTrader 5.

Оптимизация сообществом ученых — Community of Scientist Optimization (CoSO): Теория

Секреты эффективной оптимизации торговых стратегий в метаэвристических подходах. Community of Scientist Optimization — новый популяционный алгоритм, вдохновленный механизмами функционирования научного сообщества. В отличие от традиционных природных метафор, CoSO моделирует уникальные аспекты человеческой научной деятельности: публикацию результатов в журналах, конкуренцию за гранты и формирование исследовательских групп.

Нейросети в трейдинге: Распутывание структурных компонентов (SCNN)

Предлагаем познакомиться с инновационным фреймворком SCNN, который выводит анализ временных рядов на новый уровень за счёт чёткого разделения данных на долгосрочные, сезонные, краткосрочные и остаточные компоненты. Такой подход значительно повышает точность прогнозирования, позволяя модели адаптироваться к сложной и меняющейся рыночной динамике.