DocumentaçãoSeções
Referência MQL5Informações de MercadoSymbolInfoTick 

SymbolInfoTick

Retorna os preços atuais para o símbolo especificado em uma variável do tipo MqlTick.

bool  SymbolInfoTick(
   string    symbol,     // nome do ativo
   MqlTick&  tick        // referência para a estrutura
   );

Parâmetros

symbol

[in]  Nome do ativo.

tick

[out]  Referência para a estrutura do tipo MqlTick, na qual serão armazenados os preços atuais e o horário da última atualização dos preços.

Valor do Retorno

Retorna true em caso de sucesso, caso contrário, retorna false.

Exemplo:

#define SYMBOL_NAME "EURUSD"
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- declaramos um array do tipo estrutura MqlTick de tamanho 1
   MqlTick tick[1]={};
   
//--- obtemos os preços mais recentes para o símbolo SYMBOL_NAME na estrutura MqlTick
   if(!SymbolInfoTick(SYMBOL_NAME, tick[0]))
     {
      Print("SymbolInfoTick() failed. Error ", GetLastError());
      return;
     }
 
//--- enviamos os dados obtidos para o log
   PrintFormat("Latest price data for the '%s' symbol:", SYMBOL_NAME);
   ArrayPrint(tick);
   /*
   resultado:
   Latest price data for the 'EURUSD' symbol:
                    [time]   [bid]   [ask] [last] [volume]    [time_msc] [flags] [volume_real]
   [0] 2024.05.17 23:58:54 1.08685 1.08695 0.0000        0 1715990334319       6       0.00000
   */
  }