Desenvolvimento de um indicador personalizado de sentimento do mercado
Introdução
Identificar a verdadeira direção do mercado nem sempre é fácil, especialmente quando diferentes timeframes apresentam sinais conflitantes. Um trader pode observar um forte movimento de alta no gráfico de 30 minutos, enquanto o gráfico de 4 horas ainda indica pressão vendedora. Essa divergência frequentemente gera dúvidas, operações desalinhadas ou entradas contrárias ao viés direcional predominante do mercado. Sem uma abordagem estruturada para conciliar os sinais do timeframe superior com os dos inferiores, os traders correm o risco de tomar decisões impulsivas com base em informações incompletas, comprometendo a consistência e a rentabilidade das operações.
O indicador personalizado Market Sentiment resolve esse problema ao reunir os sinais de diferentes timeframes em um único painel de fácil interpretação. Ao analisar a tendência do timeframe superior em conjunto com as estruturas dos timeframes inferiores, ele classifica o sentimento do mercado em cinco categorias: altista, baixista, risk-on, risk-off ou neutro. Essa abordagem em múltiplos níveis permite que os traders mantenham uma visão abrangente do mercado e, ao mesmo tempo, identifiquem momentos de entrada com base em confirmações de curto prazo. Dessa forma, o indicador simplifica a tomada de decisões, reduz a incerteza e ajuda a alinhar as operações às condições atuais do mercado.
Desenvolvimento e lógica de funcionamento
Sentimento altista:
Ocorre quando traders e investidores, de modo geral, esperam uma valorização dos preços. Caracteriza-se por uma pressão compradora superior à pressão vendedora. Entre os sinais mais comuns estão a formação de máximas e mínimas ascendentes, volumes elevados durante os movimentos de alta e um cenário econômico ou noticiário favorável. Em situações extremas, o sentimento altista pode evoluir para euforia, quando o otimismo se torna excessivo, frequentemente próximo ao fim de um mercado de alta.

Sentimento baixista:
Reflete a expectativa de queda dos preços, em um cenário no qual a pressão vendedora supera a compradora. Geralmente, é identificado pela formação de máximas e mínimas descendentes, volumes elevados durante os movimentos de baixa e fatores econômicos ou notícias desfavoráveis. Em situações extremas, o sentimento baixista pode se transformar em pânico, provocando vendas agressivas que frequentemente ocorrem nas mínimas do mercado ou nas proximidades delas.

Sentimento neutro:
Ocorre quando os participantes do mercado ainda não têm uma expectativa definida quanto à direção dos preços ou quando existe equilíbrio entre compradores e vendedores. Nesse cenário, os preços geralmente oscilam dentro de uma faixa de negociação, sem estabelecer uma tendência clara de alta ou de baixa. Entre os principais sinais estão períodos de consolidação, baixa volatilidade e a tendência dos traders de aguardar confirmações antes de abrir posições.

Regime risk-on:
Descreve um regime de mercado no qual os investidores estão dispostos a assumir mais riscos, direcionando seus recursos com maior frequência para ações, commodities e ativos de alto rendimento. Nesse cenário, o capital é alocado em instrumentos com maior potencial de retorno. Entre os sinais mais comuns estão a valorização dos índices de ações e a baixa demanda por ativos de proteção, como ouro e títulos públicos.

Regime risk-off:
O regime risk-off, por outro lado, ocorre quando os investidores buscam proteção diante do medo ou da incerteza. Nesse cenário, o capital migra para ativos tradicionalmente considerados mais seguros, como ouro, dólar americano, franco suíço e títulos públicos. Esse regime geralmente se caracteriza pela queda dos índices de ações e pelo aumento da demanda por moedas e ativos de proteção.

Relação entre os timeframes:

Diagrama da arquitetura:

Primeiros passos
//+------------------------------------------------------------------+ //| Market_Sent.mq5 | //| GIT under Copyright 2025, MetaQuotes Ltd. | //| https://www.mql5.com/en/users/johnhlomohang/ | //+------------------------------------------------------------------+ #property copyright "GIT under Copyright 2025, MetaQuotes Ltd." #property link "https://www.mql5.com/en/users/johnhlomohang/" #property version "1.00" #property strict #property indicator_chart_window #property indicator_buffers 0 #property indicator_plots 0 //+------------------------------------------------------------------+ //| Input parameters | //+------------------------------------------------------------------+ input group "Timeframe Settings" input ENUM_TIMEFRAMES HigherTF = PERIOD_H4; input ENUM_TIMEFRAMES LowerTF1 = PERIOD_H1; input ENUM_TIMEFRAMES LowerTF2 = PERIOD_M30; input group "Indicator Settings" input int MAPeriod = 200; input int SwingLookback = 5; input double ATRThreshold = 0.002; input group "Visual Settings" // force top-left dark theme input int PanelCorner = 0; input int PanelX = 10; input int PanelY = 10; input string FontFace = "Arial"; input int FontSize = 10; input color BullishColor = clrLimeGreen; input color BearishColor = clrRed; input color RiskOnColor = clrDodgerBlue; input color RiskOffColor = clrOrangeRed; input color NeutralColor = clrGold;
Começaremos configurando a estrutura básica do indicador personalizado de sentimento do mercado em MQL5. A seção inicial contém metadados como copyright, version e link, além de diretivas que definem as propriedades do indicador. Os valores indicator_buffers 0 e indicator_plots 0 indicam que não serão utilizados buffers de indicador nem plotagens convencionais, pois o indicador foi desenvolvido para apresentar informações em um painel visual, em vez de traçar linhas ou histogramas. Essas configurações estabelecem a base necessária para a execução da lógica de análise do sentimento do mercado.
Os parâmetros de entrada oferecem aos traders flexibilidade para personalizar o indicador. O grupo "Timeframe Settings" permite selecionar o timeframe superior (H4 por padrão) e dois timeframes inferiores (H1 e M30) para a análise do sentimento do mercado. No grupo "Indicator Settings", os traders podem ajustar parâmetros técnicos, como o período da média móvel, o período de análise dos extremos locais e o limiar do ATR, utilizados para interpretar o comportamento dos preços e a volatilidade. Por fim, o grupo "Visual Settings" controla a apresentação do painel de sentimento do mercado no gráfico, incluindo sua posição, estilo e tamanho da fonte, além das cores específicas para os sentimentos altista, baixista e neutro, bem como para os regimes risk-on e risk-off. Em conjunto, esses parâmetros de entrada oferecem uma estrutura flexível para identificar e visualizar o sentimento do mercado em diferentes timeframes.
//+------------------------------------------------------------------+ //| Global variables | //+------------------------------------------------------------------+ int higherTFHandle, lowerTF1Handle, lowerTF2Handle; double higherTFMA[], lowerTF1MA[], lowerTF2MA[]; datetime lastUpdateTime = 0; string indicatorName = "MarketSentiment"; //--- helper: convert timeframe to string string TFtoString(int tf) { switch(tf) { case PERIOD_M1: return "M1"; case PERIOD_M5: return "M5"; case PERIOD_M15: return "M15"; case PERIOD_M30: return "M30"; case PERIOD_H1: return "H1"; case PERIOD_H4: return "H4"; case PERIOD_D1: return "D1"; case PERIOD_W1: return "W1"; case PERIOD_MN1: return "MN"; default: return "TF?"; } }
Esta seção define as variáveis globais e uma função auxiliar necessárias ao funcionamento do indicador de sentimento do mercado. Os três identificadores de indicadores (higherTFHandle, lowerTF1Handle e lowerTF2Handle) armazenam as referências aos cálculos das médias móveis em diferentes timeframes, enquanto os arrays (higherTFMA[], lowerTF1MA[], lowerTF2MA[]) armazenam os valores calculados dessas médias. A variável lastUpdateTime é inicializada para registrar a marca de tempo da última atualização do indicador, evitando cálculos desnecessários, enquanto indicatorName define um prefixo ou identificador comum para os objetos criados no gráfico. Além disso, a função auxiliar TFtoString() converte as constantes numéricas dos timeframes em representações textuais legíveis (por exemplo, PERIOD_H1 -> "H1"), facilitando a identificação dos períodos nas etiquetas e na apresentação das informações no painel do indicador.
//+------------------------------------------------------------------+ //| OnInit | //+------------------------------------------------------------------+ int OnInit() { indicatorName = "MarketSentiment_" + IntegerToString(ChartID()); higherTFHandle = iMA(_Symbol, HigherTF, MAPeriod, 0, MODE_EMA, PRICE_CLOSE); lowerTF1Handle = iMA(_Symbol, LowerTF1, MAPeriod, 0, MODE_EMA, PRICE_CLOSE); lowerTF2Handle = iMA(_Symbol, LowerTF2, MAPeriod, 0, MODE_EMA, PRICE_CLOSE); ArraySetAsSeries(higherTFMA, true); ArraySetAsSeries(lowerTF1MA, true); ArraySetAsSeries(lowerTF2MA, true); CreatePanel(); return(INIT_SUCCEEDED); }
A função OnInit() inicializa o indicador de sentimento do mercado, atribuindo nomes exclusivos aos objetos do gráfico com base no identificador do gráfico e criando os handles das médias móveis para o timeframe superior e os timeframes inferiores, utilizando o período especificado e o método EMA. Ela também configura os arrays das médias móveis no modo de séries temporais, facilitando o acesso aos valores mais recentes. Em seguida, chama a função CreatePanel() para desenhar o painel de sentimento do mercado no gráfico e retorna INIT_SUCCEEDED, confirmando que a inicialização foi concluída com sucesso.
//+------------------------------------------------------------------+ void OnDeinit(const int reason) { ObjectsDeleteAll(0, indicatorName); IndicatorRelease(higherTFHandle); IndicatorRelease(lowerTF1Handle); IndicatorRelease(lowerTF2Handle); }
A função OnDeinit() realiza a limpeza dos recursos quando o indicador é removido. Ela exclui todos os objetos do gráfico associados ao seu indicatorName exclusivo e libera os handles das médias móveis do timeframe superior e dos timeframes inferiores. Isso evita vazamentos de memória e impede que objetos desnecessários permaneçam no gráfico.
//+------------------------------------------------------------------+ int OnCalculate(const int rates_total, const int prev_calculated, const datetime &time[], const double &open[], const double &high[], const double &low[], const double &close[], const long &tick_volume[], const long &volume[], const int &spread[]) { if (TimeCurrent() - lastUpdateTime < 10 && prev_calculated > 0) return(rates_total); lastUpdateTime = TimeCurrent(); CopyBuffer(higherTFHandle, 0, 0, 3, higherTFMA); CopyBuffer(lowerTF1Handle, 0, 0, 3, lowerTF1MA); CopyBuffer(lowerTF2Handle, 0, 0, 3, lowerTF2MA); double higherTFPrice = iClose(_Symbol, HigherTF, 0); double lowerTF1Price = iClose(_Symbol, LowerTF1, 0); double lowerTF2Price = iClose(_Symbol, LowerTF2, 0); int higherTFBias = GetHigherTFBias(higherTFPrice, higherTFMA[0]); bool lowerTF1Bullish = IsBullishStructure(LowerTF1, SwingLookback); bool lowerTF1Bearish = IsBearishStructure(LowerTF1, SwingLookback); bool lowerTF2Bullish = IsBullishStructure(LowerTF2, SwingLookback); bool lowerTF2Bearish = IsBearishStructure(LowerTF2, SwingLookback); bool lowerTF1Breakout = HasBreakout(LowerTF1, SwingLookback, higherTFBias); bool lowerTF2Breakout = HasBreakout(LowerTF2, SwingLookback, higherTFBias); int sentiment = DetermineSentiment( higherTFBias, lowerTF1Bullish, lowerTF1Bearish, lowerTF1Breakout, lowerTF2Bullish, lowerTF2Bearish, lowerTF2Breakout ); UpdatePanel(higherTFBias, lowerTF1Bullish, lowerTF1Bearish, lowerTF2Bullish, lowerTF2Bearish, sentiment); return(rates_total); }
A função OnCalculate() constitui a principal rotina de processamento do indicador e é acionada quando novos dados de preço ou ticks são recebidos. Inicialmente, aplica um controle de frequência que permite executar os cálculos somente quando tiverem transcorrido pelo menos 10 segundos desde a última atualização, evitando processamento desnecessário. Em seguida, copia os valores das médias móveis dos buffers do timeframe superior e dos timeframes inferiores e obtém os preços de fechamento mais recentes de cada um deles, reunindo os dados necessários para avaliar o sentimento do mercado.
Depois de obter os preços e os valores das médias móveis, a função determina o viés direcional do timeframe superior e verifica se os timeframes inferiores apresentam uma estrutura de alta ou de baixa. Também confirma possíveis rompimentos que estejam alinhados ao viés direcional do timeframe superior. Essas condições são combinadas pela função DetermineSentiment(), que classifica o sentimento do mercado como altista, baixista, risk-on, risk-off ou neutro. Por fim, a função UpdatePanel() apresenta os resultados visualmente no gráfico, oferecendo aos traders um painel de sentimento do mercado baseado em múltiplos timeframes, atualizado em tempo real.
//+------------------------------------------------------------------+ //| Determine higher timeframe bias | //+------------------------------------------------------------------+ int GetHigherTFBias(double price, double maValue) { double deviation = MathAbs(price - maValue) / maValue; if (price > maValue && deviation > ATRThreshold) return 1; else if (price < maValue && deviation > ATRThreshold) return -1; else return 0; }
A função responsável pela avaliação do viés direcional do timeframe superior compara o preço atual com o valor da média móvel correspondente. Se o preço estiver acima da média móvel (MA) e a diferença superar o limiar de ATR definido, a função retorna 1, indicando um viés direcional altista. Se o preço estiver abaixo da média e a diferença for suficientemente grande, retorna -1, indicando um viés direcional baixista. Caso nenhuma dessas condições seja atendida, retorna 0, sinalizando que o viés direcional do timeframe superior é neutro ou indefinido.
//+------------------------------------------------------------------+ //| Bullish structure | //+------------------------------------------------------------------+ bool IsBullishStructure(ENUM_TIMEFRAMES tf, int lookback) { int swingHighIndex = iHighest(_Symbol, tf, MODE_HIGH, lookback * 2, 1); int swingLowIndex = iLowest (_Symbol, tf, MODE_LOW, lookback * 2, 1); int prevHigh = iHighest(_Symbol, tf, MODE_HIGH, lookback, lookback+1); int prevLow = iLowest (_Symbol, tf, MODE_LOW, lookback, lookback+1); if (swingHighIndex==-1 || swingLowIndex==-1 || prevHigh==-1 || prevLow==-1) return false; return (iHigh(_Symbol, tf, swingHighIndex) > iHigh(_Symbol, tf, prevHigh) && iLow(_Symbol, tf, swingLowIndex) > iLow (_Symbol, tf, prevLow)); } //+------------------------------------------------------------------+ //| Bearish structure | //+------------------------------------------------------------------+ bool IsBearishStructure(ENUM_TIMEFRAMES tf, int lookback) { int swingHighIndex = iHighest(_Symbol, tf, MODE_HIGH, lookback * 2, 1); int swingLowIndex = iLowest (_Symbol, tf, MODE_LOW, lookback * 2, 1); int prevHigh = iHighest(_Symbol, tf, MODE_HIGH, lookback, lookback+1); int prevLow = iLowest (_Symbol, tf, MODE_LOW, lookback, lookback+1); if (swingHighIndex==-1 || swingLowIndex==-1 || prevHigh==-1 || prevLow==-1) return false; return (iHigh(_Symbol, tf, swingHighIndex) < iHigh(_Symbol, tf, prevHigh) && iLow(_Symbol, tf, swingLowIndex) < iLow (_Symbol, tf, prevLow)); }
A função IsBullishStructure() identifica uma estrutura de preços altista no timeframe especificado, comparando as máximas e mínimas locais mais recentes com os pontos de oscilação anteriores. Inicialmente, utiliza as funções iHighest e iLowest para localizar as máximas e mínimas locais atuais e anteriores. Se a máxima atual for superior à máxima anterior e a mínima atual também for superior à mínima anterior, a função retorna true, confirmando uma estrutura altista. Caso contrário, retorna false.
Da mesma forma, a função IsBearishStructure() identifica uma estrutura de preços baixista comparando os extremos locais mais recentes com os anteriores. Se a máxima atual for inferior à máxima anterior e a mínima atual também for inferior à mínima anterior, a função retorna true, indicando uma estrutura baixista. Ambas as funções utilizam a análise de extremos locais em um período definido, permitindo que o indicador avalie as tendências de preços de curto prazo em relação aos movimentos anteriores.
//+------------------------------------------------------------------+ bool HasBreakout(ENUM_TIMEFRAMES tf, int lookback, int higherTFBias) { int swingHighIndex = iHighest(_Symbol, tf, MODE_HIGH, lookback, 1); int swingLowIndex = iLowest (_Symbol, tf, MODE_LOW, lookback, 1); if (swingHighIndex==-1 || swingLowIndex==-1) return false; double swingHigh = iHigh(_Symbol, tf, swingHighIndex); double swingLow = iLow (_Symbol, tf, swingLowIndex); double price = iClose(_Symbol, tf, 0); if (higherTFBias==1) return (price > swingHigh); if (higherTFBias==-1) return (price < swingLow); return false; }
Esta função verifica se o preço atual rompeu para cima ou para baixo os extremos locais mais recentes no timeframe especificado, considerando o viés direcional do timeframe superior. Inicialmente, identifica a máxima e a mínima locais mais recentes. Se algum desses valores não estiver disponível, retorna false. Quando o viés direcional do timeframe superior é altista, a função retorna true se o preço atual superar a máxima local. Quando o viés é baixista, retorna true se o preço cair abaixo da mínima local. Se o viés direcional do timeframe superior for neutro, o rompimento é desconsiderado e a função retorna false.
//+------------------------------------------------------------------+ int DetermineSentiment(int higherTFBias, bool tf1Bullish, bool tf1Bearish, bool tf1Breakout, bool tf2Bullish, bool tf2Bearish, bool tf2Breakout) { if (higherTFBias==1 && tf1Bullish && tf2Bullish) return 1; if (higherTFBias==-1 && tf1Bearish && tf2Bearish) return -1; if (higherTFBias==1 && (tf1Breakout||tf2Breakout)) return 2; if (higherTFBias==-1 && (tf1Breakout||tf2Breakout)) return -2; return 0; }
A função DetermineSentiment() combina o viés direcional do timeframe superior, as estruturas dos timeframes inferiores e os sinais de rompimento para classificar o sentimento geral do mercado. Ela retorna 1 para o sentimento altista quando o timeframe superior apresenta viés altista e ambos os timeframes inferiores exibem estruturas de alta; -1 para o sentimento baixista quando ocorre a combinação oposta de condições; 2 para o regime risk-on quando surgem rompimentos nos timeframes inferiores em um contexto de viés altista no timeframe superior; e -2 para o regime risk-off quando ocorrem rompimentos semelhantes em um contexto de viés baixista no timeframe superior. Se nenhuma dessas condições for atendida, retorna 0, indicando um sentimento neutro ou um mercado em movimento lateral.
//+------------------------------------------------------------------+ //| Panel Creation (dark theme, top-left) | //+------------------------------------------------------------------+ void CreatePanel() { string bg = indicatorName + "_BG"; ObjectCreate(0, bg, OBJ_RECTANGLE_LABEL, 0, 0, 0); ObjectSetInteger(0, bg, OBJPROP_XDISTANCE, PanelX); ObjectSetInteger(0, bg, OBJPROP_YDISTANCE, PanelY); ObjectSetInteger(0, bg, OBJPROP_XSIZE, 200); ObjectSetInteger(0, bg, OBJPROP_YSIZE, 120); ObjectSetInteger(0, bg, OBJPROP_CORNER, 0); ObjectSetInteger(0, bg, OBJPROP_BGCOLOR, clrBlack); ObjectSetInteger(0, bg, OBJPROP_BORDER_COLOR, clrGray); ObjectSetInteger(0, bg, OBJPROP_BACK, true); ObjectSetInteger(0, bg, OBJPROP_SELECTABLE, false); ObjectSetInteger(0, bg, OBJPROP_HIDDEN, true); string title = indicatorName + "_Title"; ObjectCreate(0, title, OBJ_LABEL, 0, 0, 0); ObjectSetInteger(0, title, OBJPROP_XDISTANCE, PanelX+10); ObjectSetInteger(0, title, OBJPROP_YDISTANCE, PanelY+10); ObjectSetInteger(0, title, OBJPROP_CORNER, 0); ObjectSetString (0, title, OBJPROP_TEXT, "Market Sentiment"); ObjectSetInteger(0, title, OBJPROP_COLOR, clrWhite); ObjectSetString (0, title, OBJPROP_FONT, FontFace); ObjectSetInteger(0, title, OBJPROP_FONTSIZE, FontSize); string tfs[3] = { TFtoString(HigherTF), TFtoString(LowerTF1), TFtoString(LowerTF2) }; for(int i=0;i<3;i++) { string tfLabel = indicatorName+"_TF"+(string)i; ObjectCreate(0, tfLabel, OBJ_LABEL, 0,0,0); ObjectSetInteger(0, tfLabel, OBJPROP_XDISTANCE, PanelX+10); ObjectSetInteger(0, tfLabel, OBJPROP_YDISTANCE, PanelY+30+i*20); ObjectSetInteger(0, tfLabel, OBJPROP_CORNER, 0); ObjectSetString (0, tfLabel, OBJPROP_TEXT, tfs[i]+":"); ObjectSetInteger(0, tfLabel, OBJPROP_COLOR, clrLightGray); ObjectSetString (0, tfLabel, OBJPROP_FONT, FontFace); ObjectSetInteger(0, tfLabel, OBJPROP_FONTSIZE, FontSize); string sentLabel = indicatorName+"_Sentiment"+(string)i; ObjectCreate(0, sentLabel, OBJ_LABEL, 0,0,0); ObjectSetInteger(0, sentLabel, OBJPROP_XDISTANCE, PanelX+100); ObjectSetInteger(0, sentLabel, OBJPROP_YDISTANCE, PanelY+30+i*20); ObjectSetInteger(0, sentLabel, OBJPROP_CORNER, 0); ObjectSetString (0, sentLabel, OBJPROP_TEXT, "N/A"); ObjectSetInteger(0, sentLabel, OBJPROP_COLOR, NeutralColor); ObjectSetString (0, sentLabel, OBJPROP_FONT, FontFace); ObjectSetInteger(0, sentLabel, OBJPROP_FONTSIZE, FontSize); } string fnl = indicatorName+"_Final"; ObjectCreate(0, fnl, OBJ_LABEL, 0,0,0); ObjectSetInteger(0, fnl, OBJPROP_XDISTANCE, PanelX+10); ObjectSetInteger(0, fnl, OBJPROP_YDISTANCE, PanelY+100); ObjectSetInteger(0, fnl, OBJPROP_CORNER, 0); ObjectSetString (0, fnl, OBJPROP_TEXT, "Final: Neutral"); ObjectSetInteger(0, fnl, OBJPROP_COLOR, NeutralColor); ObjectSetString (0, fnl, OBJPROP_FONT, FontFace); ObjectSetInteger(0, fnl, OBJPROP_FONTSIZE, FontSize+2); }
A função CreatePanel() inicializa um painel com os elementos visualmente organizados no canto superior esquerdo do gráfico, utilizando um tema escuro que proporciona boa legibilidade sobre um gráfico de fundo claro. Inicialmente, cria um retângulo de fundo com preenchimento preto e borda cinza, posicionado atrás dos demais objetos do gráfico e configurado para não permitir sua seleção. Em seguida, adiciona um título na parte superior do painel, identificando claramente o indicador como "Market Sentiment", com texto branco para facilitar a leitura sobre o fundo escuro.
Abaixo do título, a função cria etiquetas para cada um dos três timeframes monitorados, sendo um superior e dois inferiores. Os nomes dos timeframes são apresentados ao lado dos respectivos valores atuais de sentimento do mercado, inicialmente definidos como "N/A" e exibidos em uma cor neutra. Na parte inferior, uma etiqueta maior apresenta o sentimento geral do mercado, cujo valor inicial é "Neutral". Essa configuração permite acompanhar facilmente o viés direcional do mercado em diferentes timeframes por meio de um único painel compacto.
//+------------------------------------------------------------------+ //| Panel Update | //+------------------------------------------------------------------+ void UpdatePanel(int higherTFBias, bool tf1Bullish, bool tf1Bearish, bool tf2Bullish, bool tf2Bearish, int sentiment) { // Higher TF string txt="Neutral"; color col=NeutralColor; if(higherTFBias==1){txt="Bullish"; col=BullishColor;} else if(higherTFBias==-1){txt="Bearish"; col=BearishColor;} ObjectSetString(0, indicatorName+"_Sentiment0", OBJPROP_TEXT, txt); ObjectSetInteger(0, indicatorName+"_Sentiment0", OBJPROP_COLOR, col); // Lower TF1 txt="Neutral"; col=NeutralColor; if(tf1Bullish){txt="Bullish"; col=BullishColor;} else if(tf1Bearish){txt="Bearish"; col=BearishColor;} ObjectSetString(0, indicatorName+"_Sentiment1", OBJPROP_TEXT, txt); ObjectSetInteger(0, indicatorName+"_Sentiment1", OBJPROP_COLOR, col); // Lower TF2 txt="Neutral"; col=NeutralColor; if(tf2Bullish){txt="Bullish"; col=BullishColor;} else if(tf2Bearish){txt="Bearish"; col=BearishColor;} ObjectSetString(0, indicatorName+"_Sentiment2", OBJPROP_TEXT, txt); ObjectSetInteger(0, indicatorName+"_Sentiment2", OBJPROP_COLOR, col); // Final string finalSent="Neutral"; color finalCol=NeutralColor; switch(sentiment){ case 1: finalSent="Bullish"; finalCol=BullishColor; break; case -1: finalSent="Bearish"; finalCol=BearishColor; break; case 2: finalSent="Risk-On"; finalCol=RiskOnColor; break; case -2: finalSent="Risk-Off"; finalCol=RiskOffColor; break; } ObjectSetString(0, indicatorName+"_Final", OBJPROP_TEXT, "Final: "+finalSent); ObjectSetInteger(0, indicatorName+"_Final", OBJPROP_COLOR, finalCol); }
A função UpdatePanel() atualiza dinamicamente o painel de sentimento do mercado com base nos resultados da análise mais recente. Primeiro, avalia o viés direcional do timeframe superior e atualiza a etiqueta correspondente com o valor "Bullish", "Bearish" ou "Neutral", aplicando a cor apropriada. Em seguida, realiza a mesma atualização para os dois timeframes inferiores, verificando suas estruturas altistas ou baixistas e apresentando os resultados nas respectivas etiquetas, com a indicação de cor correspondente.
Por fim, a função determina o sentimento geral do mercado ao combinar o viés direcional, as estruturas de preços e os rompimentos identificados em todos os timeframes. A etiqueta de resultado final é atualizada com um dos valores exibidos na interface: "Bullish", "Bearish", "Risk-On", "Risk-Off" ou "Neutral", acompanhado da cor correspondente. Esses valores representam, respectivamente, sentimento altista, sentimento baixista, regime risk-on, regime risk-off e sentimento neutro. O prefixo "Final" no painel identifica a avaliação consolidada. Dessa forma, os traders conseguem identificar rapidamente o viés direcional do mercado em diferentes timeframes com uma única consulta ao painel.

Conclusão
Com isso, desenvolvemos um indicador personalizado de sentimento do mercado que combina a análise de múltiplos timeframes para oferecer uma representação visual clara do viés direcional e do sentimento atual do mercado. O indicador calcula médias móveis no timeframe superior e nos timeframes inferiores, identifica estruturas altistas ou baixistas com base nas máximas e mínimas locais, detecta possíveis rompimentos e determina o sentimento geral do mercado. O painel de tema escuro, localizado no canto superior esquerdo do gráfico, apresenta o viés direcional e a estrutura de preços de cada timeframe, além do sentimento consolidado do mercado. A indicação por cores permite distinguir rapidamente condições altistas, baixistas, neutras, risk-on e risk-off.
Esse indicador ajuda os traders a tomar decisões mais fundamentadas ao reunir dados complexos do mercado em uma representação visual de fácil interpretação. Por meio da análise do sentimento do mercado em múltiplos timeframes, atualizada em tempo real, ele permite avaliar rapidamente as tendências, identificar possíveis oportunidades de negociação e alinhar as estratégias ao viés direcional e ao sentimento predominantes do mercado. Isso reduz a incerteza e torna a tomada de decisões mais eficiente.
Traduzido do Inglês pela MetaQuotes Ltd.
Artigo original: https://www.mql5.com/en/articles/19422
Aviso: Todos os direitos sobre esses materiais pertencem à MetaQuotes Ltd. É proibida a reimpressão total ou parcial.
Esse artigo foi escrito por um usuário do site e reflete seu ponto de vista pessoal. A MetaQuotes Ltd. não se responsabiliza pela precisão das informações apresentadas nem pelas possíveis consequências decorrentes do uso das soluções, estratégias ou recomendações descritas.