StringAdd

この関数は文字列の終わりに別の文字列を追加します。

bool  StringAdd(
  string&  string_var,       // 文字列を追加する文字列
  string  add_substring      // 追加される文字列
  );

パラメータ

string_var

[in][out]  文字列を追加する文字列

add_substring

[in]  元の文字列に追加される文字列

戻り値

成功の場合は true、それ以外の場合は false。エラーコードを受け取るには GetLastError() 関数が呼ばれるべきです。

例:

void OnStart()
 {
  long length=1000000;
  string a="a",b="b",c;
//--- 1 番目の方法
  uint start=GetTickCount(),stop;
  long i;
  for(i=0;i<length;i++)
    {
     c=a+b;
    }
  stop=GetTickCount();
  Print("time for 'c = a + b' = ",(stop-start)," milliseconds, i = ",i);
 
//--- 2 番目の方法
  start=GetTickCount();
  for(i=0;i<length;i++)
    {
     StringAdd(a,b);
    }
  stop=GetTickCount();
  Print("time for 'StringAdd(a,b)' = ",(stop-start)," milliseconds, i = ",i);
 
//--- 3 番目の方法
  start=GetTickCount();
  a="a"; // 変数 a を再初期化する
  for(i=0;i<length;i++)
    {
    StringConcatenate(c,a,b);
    }
  stop=GetTickCount();
  Print("time for 'StringConcatenate(c,a,b)' = ",(stop-start)," milliseconds, i = ",i);
 }

参照

StringConcatenate, StringSplit, StringSubstr