DRAW_SECTION

DRAW_SECTION はセクションを指標バッファの値によって指定された色で描画します。線の幅、色とスタイルは DRAW_LINEスタイルのようにコンパイラディレクティブまたは動的に PlotIndexSetInteger() 関数を使用して指定することが出来ます。プロットのプロパティの動的な変更は、指標の外観が現在の状況に応じて変わるようにして「盛り上げる」ことが出来ます。

セクションは指標バッファの空でない値からあと 1 つの空でない値まで描かれ、空の値は無視されます。「空」値を指定するには PLOT_EMPTY_VALUE プロパティで値を設定します。例えば、指標をゼロ以外の値のセクションのシーケンスとして描画する必要がある場合、ゼロを空値として設定する必要があります。

//--- 0（空）値は描画されない
PlotIndexSetDouble(index_of_plot_DRAW_SECTION,PLOT_EMPTY_VALUE,0);

バッファの値は常に明示的に入力し、描画されないべき要素ではバッファに空の値を設定します。

DRAW_SECTION のプロットに必要なバッファの数は 1 です。

高値と安値の間のセクションを描画する指標の例です。セクションの色、幅とスタイルは全てN ティックごとにランダムに変更されます。

DRAW_SECTION の例

DRAW_SECTION を持つplot1 では、3 つのプロパティは #property コンパイラディレクティブを使用して指定され、後に OnCalculate() 関数でランダムに設定されることにご注意ください。N パラメータは手動設定の可能性を持って（指標の「プロパティ」ウィンドウの「パラメータ」タブ）指標外部パラメータに設定されています。

//+------------------------------------------------------------------+
//| DRAW_SECTION.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"

#property description "An indicator to demonstrate DRAW_SECTION"
#property description "Draws straight sections every bars bars"
#property description "The color, width and style of sections are changed randomly"
#property description "after every N ticks"

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots 1
//--- セクションをプロットする
#property indicator_label1 "Section"
#property indicator_type1 DRAW_SECTION
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- 入力パラメータ
input int bars=5; // バー単位でのセクションの長さ
input int N=5; // セクションスタイルを変更するティック数
//--- プロットの指標バッファ
double SectionBuffer[];
//--- セクションの端を計算する補助変数
int divider;
//--- 色を格納する配列
color colors[]={clrRed,clrBlue,clrGreen};
//--- 線のスタイルを格納する配列
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 配列と指標バッファを関連付ける
SetIndexBuffer(0,SectionBuffer,INDICATOR_DATA);
//--- 0（空）値は描画されない
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- 指標パラメータをチェックする
if(bars<=0)
{
PrintFormat("Invalid value of parameter bar=%d",bars);
return(INIT_PARAMETERS_INCORRECT);
}
else divider=2*bars;
//---+
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| カスタム指標の反復関数 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 線のスタイル、色、及び幅を変更するティックを計算する
ticks++;
//--- 充分なティックの数が蓄積されている場合
if(ticks>=N)
{
//--- 線のプロパティを変更する
ChangeLineAppearance();
//--- ティックカウンタをゼロにリセットする
ticks=0;
}

//--- 指標値の算出が開始されるバーの番号
int start=0;
//--- 指標が以前に計算されている場合には、開始点を前のバーに設定する
if(prev_calculated>0) start=prev_calculated-1;
//--- 指標値の計算
for(int i=start;i<rates_total;i++)
{
//--- バー番号を 2*bars で割って余りを取得
int rest=i%divider;
//--- バー番号が 2*bars で割りきれる場合
if(rest==0)
{
//--- この足の高値でセクションの終わりを設定する
SectionBuffer[i]=high[i];
}
//---除算の剰余は、バーに等しい場合
else
{
//--- この足の高値でセクションの終わりを設定する
if(rest==bars) SectionBuffer[i]=low[i];
//--- 何もない場合、バーを無視して 0 に設定
else SectionBuffer[i]=0;
}
}
//--- prev_calculated 値を次の関数呼び出しのために返す
return(rates_total);
}
//+------------------------------------------------------------------+
//| 指標のセクションの外観を変更する |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- 線のプロパティに関する情報を形成するための文字列
string comm="";
//--- 線の色を変更するブロック
int number=MathRand(); // 乱数を取得
//--- 除数は colors[] 配列のサイズと同じ
int size=ArraySize(colors);
//--- 新しい色を選択するためのインデックスを整数除算の余りから取得
int color_index=number%size;
//--- 色をPLOT_LINE_COLOR プロパティとして設定
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- 線の色を書く
comm=comm+"\r\n"+(string)colors[color_index];

//--- 線の幅を変更するブロック
number=MathRand();
//--- 整数除算の余りの幅を取得
int width=number%5; // 幅は 0〜4 に設定される
//--- 幅を設定
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 線の幅を書く
comm=comm+"\r\nWidth="+IntegerToString(width);

//--- 線のスタイルを変更するブロック
number=MathRand();
//--- 除数は、スタイルの配列の大きさに等しい
size=ArraySize(styles);
//--- 新しいスタイルを選択するためのインデックスを整数除算の余りから取得
int style_index=number%size;
//--- 線のスタイルを設定
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 線のスタイルを書く
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- コメントを使用して、チャート上の情報を表示する
Comment(comm);
}

DRAW_LINE

DRAW_HISTOGRAM