OnCalculate

int OnCalculate(
  const int        rates_total,       // price[]配列サイズ
  const int        prev_calculated,   // 以前の呼び出しで処理されたバーの数
  const int        begin,             // 意味のあるデータが始まるprice []配列のインデックス番号
  const double&    price[]           // 計算のための値の配列
  );

int OnCalculate(
  const int        rates_total,       // 入力時間枠のサイズ
  const int        prev_calculated,   // 以前の呼び出しで処理されたバーの数
  const datetime&  time[],           // 時間配列
  const double&    open[],           // 始値配列
  const double&    high[],           // 高値配列
  const double&    low[],           // 安値配列
  const double&    close[],         // 終値配列
  const long&      tick_volume[],     // ティックボリューム配列
  const long&      volume[],         // 真のボリュームの配列
  const int&      spread[]         // スプレッドの配列
  );

//+------------------------------------------------------------------+
//|                                           OnCalculate_Sample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link     "https://www.mql5.com"
#property version   "1.00"
#property description "Sample Momentum indicator calculation"
 
//---- 指標の設定
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
#property indicator_type1   DRAW_LINE
#property indicator_color1  Blue
//---- 入力
input int MomentumPeriod=14; // 計算期間
//---- 指標バッファ
double    MomentumBuffer[];
//--- 計算期間を格納するグローバル変数
int       IntPeriod;
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数                                            |
//+------------------------------------------------------------------+
void OnInit()
 {
//--- 入力パラメータを確認する
  if(MomentumPeriod<0)
    {
     IntPeriod=14;
    Print("Period parameter has an incorrect value. The following value is to be used for calculations ",IntPeriod);
    }
  else
     IntPeriod=MomentumPeriod;
//---- バッファ  
  SetIndexBuffer(0,MomentumBuffer,INDICATOR_DATA);
//---- データウィンドウとサブウィンドウで表示される指標名
  IndicatorSetString(INDICATOR_SHORTNAME,"Momentum"+"("+string(IntPeriod)+")");
//--- 描画が始まるバーのインデックスを設定する
  PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,IntPeriod-1);
//--- 描画されない空の値を0.0に設定する
  PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//--- 表示される指標の精度
  IndicatorSetInteger(INDICATOR_DIGITS,2);
 }
//+------------------------------------------------------------------+
//|  モメンタム指標計算                                                   |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,     // price[]配列サイズ
              const int prev_calculated, // 以前に処理されたバーの数
              const int begin,           // 有意義なデータの始まり
              const double &price[])     // 処理される値の配列
 {
//--- 初期の計算位置
  int StartCalcPosition=(IntPeriod-1)+begin;
//---- 計算データが不十分の場合
  if(rates_total<StartCalcPosition)
    return(0); // ゼロ値で終了 - 指標は未計算
//--- 正しい描画を開始する
  if(begin>0)
    PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartCalcPosition+(IntPeriod-1));
//--- 計算を開始し、開始位置を定義する
  int pos=prev_calculated-1;
  if(pos<StartCalcPosition)
     pos=begin+IntPeriod;
//--- 計算のメインループ
  for(int i=pos;i<rates_total && !IsStopped();i++)
     MomentumBuffer[i]=price[i]*100/price[i-IntPeriod];
//--- OnCalculateの実行が完了したので、後に続く呼び出しのために新しいprev_calculated値を返す
  return(rates_total);
 }