English Русский Español Deutsch Português
preview
市場シミュレーション:ポジション表示(IX)

市場シミュレーション:ポジション表示(IX)

MetaTrader 5 — テスター |
11 0
Daniel Jose
Daniel Jose

はじめに

読者の皆さん、こんにちは。 リプレイ/シミュレーションシステムの構築に関する新しい記事へようこそ。

前回「市場シミュレーション:ポジション表示(VIII)」では、これを実装する方法、より正確には、ユーザー操作によってテイクプロフィットラインやストップロスラインを削除したり、ポジションを非常に簡単に決済したりできるように、ポジション表示インジケータのコードをどう修正すべきかを紹介しました。 本連載をずっと追ってきた方なら、ここで具体的に何が実装されているのか、理解するのは難しくないと思います。 しかし、現時点では、取引シミュレーションに関してはまだ何もしていません。 でも、そのことについては、とりあえず今は気にしないでください。 たとえそれが必ずしも明らかではないとしても、私たちはその方向に向かって進んでいます。

さて、私たちは今、ある問題に直面しています。それは、一方でかなり厄介ですが、他方で非常に興味深いものです。 問題は、一度削除したテイクプロフィットラインとストップロスラインを、ターミナルを使わずに、チャート上で直接操作して復元するにはどうすればよいかということです。 一見すると、これは簡単に思えます。 しかし、克服しなければならない課題がいくつかあります。


問題の解決策をじっくり考える

基本的に、この問題は次のように解決できます。チャート上の価格ラインをクリックすることで、チャートに新しいラインを追加することができます。 このラインを希望する水準までドラッグし、マウスボタンを離した瞬間に、エキスパートアドバイザー(EA)が、そこをテイクプロフィットラインまたはストップロスラインの設定先として認識するようにします。 基本的には、それだけです。 実際のところ、とても簡単なのです。

しかし、このアプローチについてもう少し考えてみましょう。 まず、ラインを単に適当に動かすだけでは済まないため、ラインを正しく移動できるシステムを追加または実装する必要があります。 取引サーバーがEAから送信されたリクエストを拒否しないように、ラインのドラッグを終了する位置の価格は、一定の条件を満たしている必要があります。 この段階での問題は、各資産クラスごとに固有のティックサイズが設定されている可能性があることです。 場合によっては、その値が0.01ドルになることもあれば、0.50ドルになることも、あるいは0.20ドルになることもあります。 一見すると、これは非常に複雑に見えますが、幸いなことに、この問題に対する解決策はすでに実装済みです。 これはすでにマウスインジケータに実装されています。 つまり、もう価格調整について心配する必要はありません。 必要なのは、マウスインジケータの位置を確認し、その位置に対応する価格をEAに渡す値として使用することだけです。 こうすることで、EAは、ストップロスラインまたはテイクプロフィットラインを作成するために、どの価格を取引サーバーに送信すべきかを把握できるようになります。 これで問題が一つ減りました。

しかし、他にも分析し、解決すべき課題が残っています。 次の問題は、このポジションに両方のラインが存在しない場合、どちらのラインを作成するかという点です。 この初期段階において、この問題は最も興味深いものの一つです。 要するに、買いポジションが開かれている場合、ラインをより高い価格までドラッグすると、それをテイクプロフィットラインとして設定できるということです。 一方、売りポジションの場合に同じように、つまりより高い価格へラインをドラッグすると、それをストップロスラインとして設定できます。 逆方向への動きの場合も同様です。この場合、そのラインはストップロスラインか、あるいはテイクプロフィットラインのいずれかとして解釈されます。 しかし、現在の市場価格を用いることも可能です。 つまり、買いポジションのラインを現在の市場価格より高い位置まで移動した場合、それをテイクプロフィットラインとみなします。 売りポジションの場合は、ストップロスを設定することになります。 ただし、買いポジションであっても、ラインを現在の取引価格より低い位置へ移動した場合は、それをストップロスとみなします。 また、売りポジションの場合は、テイクプロフィットのポイントを特定することになります。

この説明で少し混乱させてしまったかもしれません。 しかし、私が説明しようとしていることを理解するのは、システムの実装にある方法を選ぶ理由を理解する上で、極めて重要です。 これをおこなうのに、唯一の正しい方法などありません。 あるのは、私が作ろうとしているものに適した方法だけです。 ただし、何らかの理由で別のやり方を採用したい場合は、私が説明している内容を理解しておく必要があります。そうすることで、より一貫性があり、わかりやすい方法でシステムを実装できるようになるからです。

ただ、この説明は一見分かりにくいだけでなく、もう一つ小さな問題があります。 説明をより分かりやすくするために、少しの間、次のような状況を想像してみてください。トレーダーのあなたはある銘柄を取引しており、たとえば100ドルという価格でそれを購入することにしたとします。 Chart Tradeインジケータを使用して、成行注文が送信されます。 その後、EAは、テイクプロフィットラインとストップロスラインが設定されたリクエストを送信します。 しばらくして、あなたはこれらのラインを削除することにします。 これをおこなうには、これまでの記事で実装したボタンを、ポジション表示インジケータと併せて使用します。 これで、EAは要求を認識し、テイクプロフィットとストップロスを削除するコマンドを取引サーバーに送信します。 これで、望んでいた状況が得られます。 つまり、テイクプロフィットラインもストップロスラインもない保有ポジションです。 ここで、この状況について考えながら、私の考えの筋道を論理的に追ってみてください。

仮に価格が150ドルまで上昇したとしましょう。 ここで、あなたはストップロスを設定するタイミングだと判断します。 このラインはポジションに紐付けられます。板に新たに出され、価格が戻るのを待つ注文ではありません。 この二つは異なる状況なので、この区別は重要です。 では、トレーダーがポジションにストップロスラインを設定するには、どうすればよいのでしょうか。 トレーダーにとって最も自然な操作は、ポジションラインをクリックしてドラッグすることです。 しかし、 どこに、どのレベルまでドラッグすればよいのでしょうか。 それが問題です。 でも、少し話を単純化してみましょう。 トレーダーのあなたはストップロスを140ドルに設定しようと考えています。 それがあなたのやりたいことです。 でも、どうやってそれを実現するのでしょうか。 あるいは、もっと正確に言えば、プログラマーとして、これをどのように実装すべきでしょうか。 そして、そこから困難が始まるのです。 なぜなら、プログラマーとしてそのような状況に対して適切な対策を講じておかないと、たとえ自分が実装したシステムを使っていても、自分が書いたプログラムを扱う際に、自分自身がミスを犯してしまうことになるかもしれないからです。

簡単に言えば、次のような仕組みを実装した場合です。まず、100ドルの水準にある水平の価格ラインをクリックし、マウスを90ドルまでドラッグしてボタンを離します。これにより、EAは、ストップロスラインを作成するためのリクエストを取引サーバーに送信する必要があると認識します。その後で初めて、90ドルにあるそのラインをつかみ、140ドルまでドラッグできるという仕組みです。この場合、ラインを100ドルから140ドルへ直接ドラッグすると、誤操作になってしまう可能性があります。 これは、EAが、この操作を、意図したストップロスラインの作成要求ではなく、テイクプロフィットラインの作成要求として解釈するためです。

一見すると、この価格ライン自体にはまったく意味がないので、これは大きな問題にはならないはずです。 ここで少し本題を離れて、あることを説明しておく必要があります。 多くのトレーダーが真実だと信じていることが、実は単なる大きな誤解に過ぎないのです。 繰り返しになりますが、すべてがテイクプロフィットラインとストップロスライン上で起こるわけでは決してありません。 ポジションは、その価格と完全に一致する価格で取引が成立した場合に限り、決済されます。 また、その価格で成立する出来高は、価格が変わる前にすべてのロットを吸収できるだけの十分な量でなければなりません。 その価格にあるロットの全数量が吸収される前に価格が変わると、その注文は未約定となります。 つまり、ポジションは開いたままになります。 これは、経験の浅いトレーダーの多くに影響する、かなり深刻な問題です。というのも、その多くは自動売買ロボットを利用しており、テイクプロフィット注文やストップロス注文は、価格がその水準を通り越しても未約定になることはなく、必ず執行されると思い込んでいるからです。

以前の連載の一つで、同様の問題について解説しました。 まだ読んでいない方には、この連載をぜひ読むことをお勧めします。 比較的わかりやすい全15本の記事で構成されており、完全に自動で動作するEAの開発方法を解説しています。 その連載では、この注文の未約定という具体的な問題を解決する方法を示しています。リプレイ/シミュレーションシステムの開発の現段階で、他の解決策を検討する際の参考になるかもしれません。 たとえば、同じ数量の反対注文を使う方法があります。成行注文として執行されるため、価格が注文水準を通り越しても、いずれにせよ約定します。 この連載の第1回目の記事は、以下のリンクからご覧いただけます。

自動で動くEAを作る(第01回):概念と構造

注文が未約定になる可能性があるため、ストップロスやテイクプロフィットを板に出す反対注文として扱う実装は検討できないと述べました。 そのように実装したならば、問題解決のアプローチが根本から変わってしまうからです。 さて、読者の皆さんは、何を実装する必要があるのか、十分に理解できたでしょうか。 この問題に対する私の解決策は単純です。 トレーダーやユーザーに、移動させるラインがストップロスラインかテイクプロフィットラインかを事前に指定する選択肢を与えることができるのに、解決策をわざわざ複雑にする必要はないでしょう。 以前、別の連載記事で、その方法について解説しました。 しかし、当時の連載では、別の点に重点を置いていました。 プログラミングを始めたばかりの人たちが、それらの記事を活用するとは思ってもみませんでした。 そのため、当時の実装は機能していたものの、記事の説明は、そのシステムを基に何かを開発する方法を学びたい人にとって、何の助けにもなりませんでした。

幸いなことに、そのやり方は今では変わりました。 ここでは、なぜ実装にそのような方法を採用するのかを学び、理解していただきたいと思います。 しかし、何よりもまず、教材をしっかりと学び、私が皆さんに伝えようとしている知識を活用して、自分なりの解決策を導き出してほしいと思います。

それでは、始めましょう。 これまでに説明したすべての状況から、一つのことがはっきりしました。それは、チャート上のラインをドラッグする方法を見つける必要があるということです。 単にドラッグするだけで、テイクプロフィットやストップロスの水準を変更することができるようになります。 したがって、この段階で実装に着手する必要があります。 それでは、次の話題に移りましょう。


価格ラインを移動する準備

価格ライン(ここでポジション表示インジケータの「価格ライン」と呼んでいるのは、ストップロスラインとテイクプロフィットラインのことです)を移動できるようにするには、まずシステムに新しいイベントを追加する必要があります。 これは、以下に示すように簡単におこなうことができます。

01. //+------------------------------------------------------------------+
02. #property copyright "Daniel Jose"
03. //+------------------------------------------------------------------+
04. #define def_VERSION_DEBUG
05. //+------------------------------------------------------------------+
06. #ifdef def_VERSION_DEBUG
07.     #define macro_DEBUG_MODE(A) \
08.                     Print(__FILE__, " ", __LINE__, " ", __FUNCTION__ + " " + #A + " = " + (string)(A));
09. #else
10.     #define macro_DEBUG_MODE(A)
11. #endif
12. //+------------------------------------------------------------------+
13. #define def_SymbolReplay          "RePlay"
14. #define def_MaxPosSlider          400
15. #define def_MaskTimeService       0xFED00000
16. #define def_IndicatorTimeFrame    (_Period < 60 ? _Period : (_Period < PERIOD_D1 ? _Period - 16325 : (_Period == PERIOD_D1 ? 84 : (_Period == PERIOD_W1 ? 91 : 96))))
17. #define def_IndexTimeFrame        4
18. //+------------------------------------------------------------------+
19. union uCast_Double
20. {
21.     double   dValue;
22.     long     _long;                                  // 1 Information
23.     datetime _datetime;                              // 1 Information
24.     uint     _32b[sizeof(double) / sizeof(uint)];    // 2 Informations
25.     ushort   _16b[sizeof(double) / sizeof(ushort)];  // 4 Informations
26.     uchar    _8b [sizeof(double) / sizeof(uchar)];   // 8 Informations
27. };
28. //+------------------------------------------------------------------+
29. enum EnumEvents     {
30.             evTicTac,                        //Event of tic-tac
31.             evHideMouse,                     //Hide mouse price line
32.             evShowMouse,                     //Show mouse price line
33.             evHideBarTime,                   //Hide bar time
34.             evShowBarTime,                   //Show bar time
35.             evHideDailyVar,                  //Hide daily variation
36.             evShowDailyVar,                  //Show daily variation
37.             evHidePriceVar,                  //Hide instantaneous variation
38.             evShowPriceVar,                  //Show instantaneous variation
39.             evCtrlReplayInit,                //Initialize replay control
40.             evChartTradeBuy,                 //Market buy event
41.             evChartTradeSell,                //Market sales event 
42.             evChartTradeCloseAll,            //Event to close positions
43.             evChartTrade_At_EA,              //Event to communication
44.             evEA_At_ChartTrade,              //Event to communication
45.             evChatWriteSocket,               //Event to Mini Chat
46.             evChatReadSocket,                //Event To Mini Chat
47.             evUpdate_Position,               //Event to communication
48.             evMsgClosePositionEA,            //Event to communication
49.             evMsgCloseTakeProfit,            //Event to communication
50.             evMsgCloseStopLoss,              //Event to communication
51.             evMsgNewTakeProfit,              //Event to communication
52.             evMsgNewStopLoss                 //Event to communication
53.                         };
54. //+------------------------------------------------------------------+
55. enum EnumPriority {                          //Priority list on objects
56.             ePriorityNull = -1,
57.             ePriorityDefault = 0,
58.             ePriorityChartTrade = 5,
59.             ePriorityOrders = 10
60.                         };
61. //+------------------------------------------------------------------+

Defines.mqh

リストに新しいイベントが2つ追加されていることに注目してください。 これにより、ポジション表示インジケータとEAの連携がしやすくなります。 それが完了したら、EA内のC_Ordersクラスに移り、これら2つのイベントを実装することができます。 変更後のクラスのコードは以下のとおりです。

001. //+------------------------------------------------------------------+
002. #property copyright "Daniel Jose"
003. //+------------------------------------------------------------------+
004. #include "..\Defines.mqh"
005. //+------------------------------------------------------------------+
006. class C_Orders
007. {
008.     protected:
009. //+------------------------------------------------------------------+
010. inline const ulong GetMagicNumber(void) const { return m_Base.MagicNumber; }
011. //+------------------------------------------------------------------+
012.         bool ClosePosition(const ulong ticket)
013.             {
014.                 bool   IsBuy;
015.                 string szContract;
016.                 
017.                 if  (!PositionSelectByTicket(ticket)) return false;
018.                 IsBuy = PositionGetInteger(POSITION_TYPE) == POSITION_TYPE_BUY;
019.                 szContract = PositionGetString(POSITION_SYMBOL);
020.                 ZeroMemory(m_Base.TradeRequest);
021.                 m_Base.TradeRequest.action    = TRADE_ACTION_DEAL;
022.                 m_Base.TradeRequest.type      = (IsBuy ? ORDER_TYPE_SELL : ORDER_TYPE_BUY);
023.                 m_Base.TradeRequest.price     = NormalizeDouble(SymbolInfoDouble(szContract, (IsBuy ? SYMBOL_BID : SYMBOL_ASK)), (int)SymbolInfoInteger(szContract, SYMBOL_DIGITS));
024.                 m_Base.TradeRequest.position  = ticket;
025.                 m_Base.TradeRequest.symbol    = szContract;
026.                 m_Base.TradeRequest.volume    = PositionGetDouble(POSITION_VOLUME);
027.                 m_Base.TradeRequest.deviation = 1000;
028.                 
029.                 return SendToPhysicalServer() != 0;
030.             };
031. //+------------------------------------------------------------------+    
032.     private    :
033. //+------------------------------------------------------------------+
034.         struct stBase
035.         {
036.             MqlTradeRequest TradeRequest;
037.             ulong           MagicNumber;
038.             bool            bTrash;
039.         }m_Base;
040. //+------------------------------------------------------------------+
041.         struct stChartTrade
042.         {
043.             struct stEvent
044.             {
045.                 EnumEvents  ev;
046.                 string      szSymbol,
047.                             szContract;
048.                 bool        IsDayTrade;
049.                 ushort      Leverange;
050.                 double      PointsTake,
051.                             PointsStop;
052.             }Data;
053. //---
054.             bool Decode(const EnumEvents ev, const string sparam)
055.                 {
056.                     string Res[];
057.         
058.                     if (StringSplit(sparam, '?', Res) != 7) return false;
059.                     stEvent loc = {(EnumEvents) StringToInteger(Res[0]), Res[1], Res[2], (bool)(Res[3] == "D"), (ushort) StringToInteger(Res[4]), StringToDouble(Res[5]), StringToDouble(Res[6])};
060.                     if ((ev == loc.ev) && (loc.szSymbol == _Symbol)) Data = loc;
061.                     else return false;
062.                     
063.                     return true;
064.                 }
065. //---
066.         }m_ChartTrade;
067. //+------------------------------------------------------------------+
068.         ulong SendToPhysicalServer(void)
069.             {
070.                 MqlTradeCheckResult  TradeCheck;
071.                 MqlTradeResult       TradeResult;
072.                 
073.                 ZeroMemory(TradeCheck);
074.                 ZeroMemory(TradeResult);
075.                 if (!OrderCheck(m_Base.TradeRequest, TradeCheck))
076.                 {
077.                     PrintFormat("Order System - Check Error: %d", GetLastError());
078.                     return 0;
079.                 }
080.                 m_Base.bTrash = OrderSend(m_Base.TradeRequest, TradeResult);
081.                 if (TradeResult.retcode != TRADE_RETCODE_DONE)
082.                 {
083.                     PrintFormat("Order System - Send Error: %d", TradeResult.retcode);
084.                     return 0;
085.                 };
086.                 
087.                 return TradeResult.order;
088.             }
089. //+------------------------------------------------------------------+    
090.         ulong ToMarket(const ENUM_ORDER_TYPE type)
091.             {
092.                 double price  = SymbolInfoDouble(m_ChartTrade.Data.szContract, (type == ORDER_TYPE_BUY ? SYMBOL_ASK : SYMBOL_BID));
093.                 double vol    = SymbolInfoDouble(m_ChartTrade.Data.szContract, SYMBOL_VOLUME_STEP);
094.                 uchar  nDigit = (uchar)SymbolInfoInteger(m_ChartTrade.Data.szContract, SYMBOL_DIGITS);
095.                 
096.                 ZeroMemory(m_Base.TradeRequest);
097.                 m_Base.TradeRequest.magic         = m_Base.MagicNumber;
098.                 m_Base.TradeRequest.symbol        = m_ChartTrade.Data.szContract;
099.                 m_Base.TradeRequest.price         = NormalizeDouble(price, nDigit);
100.                 m_Base.TradeRequest.action        = TRADE_ACTION_DEAL;
101.                 m_Base.TradeRequest.sl            = NormalizeDouble(m_ChartTrade.Data.PointsStop == 0 ? 0 : price + (m_ChartTrade.Data.PointsStop * (type == ORDER_TYPE_BUY ? -1 : 1)), nDigit);
102.                 m_Base.TradeRequest.tp            = NormalizeDouble(m_ChartTrade.Data.PointsTake == 0 ? 0 : price + (m_ChartTrade.Data.PointsTake * (type == ORDER_TYPE_BUY ? 1 : -1)), nDigit);
103.                 m_Base.TradeRequest.volume        = NormalizeDouble(vol + (vol * (m_ChartTrade.Data.Leverange - 1)), nDigit);
104.                 m_Base.TradeRequest.type          = type;
105.                 m_Base.TradeRequest.type_time     = (m_ChartTrade.Data.IsDayTrade ? ORDER_TIME_DAY : ORDER_TIME_GTC);
106.                 m_Base.TradeRequest.stoplimit     = 0;
107.                 m_Base.TradeRequest.expiration    = 0;
108.                 m_Base.TradeRequest.type_filling  = ORDER_FILLING_RETURN;
109.                 m_Base.TradeRequest.deviation     = 1000;
110.                 m_Base.TradeRequest.comment       = "Order Generated by Experts Advisor.";
111. 
112.                 MqlTradeRequest TradeRequest[1];
113. 
114.                 TradeRequest[0] = m_Base.TradeRequest;
115.                 ArrayPrint(TradeRequest);
116. 
117.                 return (((type == ORDER_TYPE_BUY) || (type == ORDER_TYPE_SELL)) ? SendToPhysicalServer() : 0);
118.             };
119. //+------------------------------------------------------------------+
120.         void CloseAllsPosition(void)
121.             {
122.                 for (int count = PositionsTotal() - 1; count >= 0; count--)
123.                 {
124.                     if (PositionGetSymbol(count) != m_ChartTrade.Data.szContract) continue;
125.                     if (PositionGetInteger(POSITION_MAGIC) != m_Base.MagicNumber) continue;
126.                     ClosePosition(PositionGetInteger(POSITION_TICKET));
127.                 }
128.             };
129. //+------------------------------------------------------------------+    
130.         void ModifyValueSLTP(const ulong ticket, const string symbol, const double sl, const double tp)
131.             {
132.                 ZeroMemory(m_Base.TradeRequest);            
133.                 MqlTradeRequest TradeRequest[1];
134. 
135.                 if ((sl < 0) || (tp < 0)) if (!PositionSelectByTicket(ticket)) return;
136.                 m_Base.TradeRequest.magic     = m_Base.MagicNumber;
137.                 m_Base.TradeRequest.action    = TRADE_ACTION_SLTP;
138.                 m_Base.TradeRequest.symbol    = symbol;
139.                 m_Base.TradeRequest.position  = ticket;
140.                 m_Base.TradeRequest.sl        = (sl < 0 ? PositionGetDouble(POSITION_SL) : sl);
141.                 m_Base.TradeRequest.tp        = (tp < 0 ? PositionGetDouble(POSITION_TP) : tp);
142.                 
143.                 TradeRequest[0] = m_Base.TradeRequest;
144.                 ArrayPrint(TradeRequest);
145.                 
146.                 SendToPhysicalServer();
147.             }
148. //+------------------------------------------------------------------+    
149.     public    :
150. //+------------------------------------------------------------------+
151.         C_Orders(const ulong magic)
152.             {
153.                 m_Base.MagicNumber = magic;
154.             }
155. //+------------------------------------------------------------------+    
156.         void DispatchMessage(const int id, const long &lparam, const double &dparam, const string &sparam)
157.             {
158.                 switch (id)
159.                 {
160.                     case CHARTEVENT_CUSTOM + evChartTradeBuy     :
161.                     case CHARTEVENT_CUSTOM + evChartTradeSell    :
162.                     case CHARTEVENT_CUSTOM + evChartTradeCloseAll:
163.                         if (m_ChartTrade.Decode((EnumEvents)(id - CHARTEVENT_CUSTOM), sparam)) switch (m_ChartTrade.Data.ev)
164.                         {
165.                             case evChartTradeBuy:
166.                                 ToMarket(ORDER_TYPE_BUY);
167.                                 break;
168.                             case evChartTradeSell:
169.                                 ToMarket(ORDER_TYPE_SELL);
170.                                 break;
171.                             case evChartTradeCloseAll:
172.                                 CloseAllsPosition();
173.                                 break;
174.                         }
175.                         break;
176.                     case CHARTEVENT_CUSTOM + evMsgClosePositionEA:
177.                         ClosePosition((ulong)(lparam));
178.                         break;
179.                     case CHARTEVENT_CUSTOM + evMsgCloseTakeProfit:
180.                         ModifyValueSLTP((ulong)(lparam), sparam, dparam, 0);
181.                         break;
182.                     case CHARTEVENT_CUSTOM + evMsgCloseStopLoss:
183.                         ModifyValueSLTP((ulong)(lparam), sparam, 0, dparam);
184.                         break;
185.                     case CHARTEVENT_CUSTOM + evMsgNewTakeProfit:
186.                         ModifyValueSLTP((ulong)(lparam), sparam, -1, dparam);
187.                         break;
188.                     case CHARTEVENT_CUSTOM + evMsgNewStopLoss:
189.                         ModifyValueSLTP((ulong)(lparam), sparam, dparam, -1);
190.                         break;
191.                 }
192.             }
193. //+------------------------------------------------------------------+    
194. };
195. //+------------------------------------------------------------------+

C_Orders.mqh

変更はクラスのコードの一部にしか及んでいないため、クラス全体のコードを記載するのは無意味に思えるかもしれません。 でも、問題ありません。それでは、変更点を見てみましょう。 185行目と188行目では、EAが新しいイベントを適切に処理できるように、このような形で実装しています。 ここで注目してほしいのは、以前とまったく同じ処理、つまりModifyValueSLTPを使用したということです。 しかし、以前とは異なり、今回はフィールドの1つに負の値を指定します。 メッセージフィールドの新しい値は、以前と同様にdparamパラメータを通じて渡されます。 では、この負の値にはどのような意味があるのでしょうか。 その理由は何でしょうか。 これを理解するには、130行目のコードを確認する必要があります。そこが、ModifyValueSLTP関数を実装している箇所です。

この関数には、いくつか細かな変更が加えられている点に注意してください。 まず、135行目で、sl または tp の値が負であるかどうかを確認します。 この場合、PositionSelectByTicket関数を呼び出します。 この呼び出しは、ポジションの最新の値を読み込むために必要です。 なぜでしょうか。 その理由は140行目と141行目のコードを見ればわかります。 引数のいずれかの値が負の場合、サーバーが既存の値を削除しないように、そのポジションに設定されている最新の値が使用されます。 一方、ラインを削除する場合のように値がゼロであるか、その他の非負の値である場合、サーバーはその値をそのまま使用して、トレーダーが指定した水準にストップロスラインまたはテイクプロフィットラインを設定します。 これで、EAのコードは更新され、構造に関するさらなる変更は不要となりました。

これで、EAのコードがテイクプロフィットとストップロスのどちらの価格変更要求も認識できるようになったので、ポジション表示インジケータに注力できます。 ただし、インジケータのコードの分析を始める前に、読者の皆さんには、価格が更新されるとインジケータがその価格を自動的に表示することを改めて確認しておきたいと思います。 つまり、チャート上の価格ラインがどこにあるかについて、気にする必要はないということです。 必要なのは、EAが水平価格ラインを変更するように、イベントを生成する手続きを作成することだけです。

というわけで、これからお見せするものは、最終版には含まれません。 価格ラインを動かす方法をお見せしたいだけです。 そのためには、ソースコードにいくつかの細かい修正を加える必要があります。 そして、読者の皆さんが、これほど多くの変更に戸惑うことのないよう、一つずつ順を追って説明していきましょう。 まず、マウスインジケータだけを使って操作をおこなうように、インジケータのコードを修正します。 そのためには、これまでの記事で取り上げたコードにいくつかの変更を加える必要があります。 新しいコードは以下のとおりです。

001. //+------------------------------------------------------------------+
002. #property copyright "Daniel Jose"
003. //+------------------------------------------------------------------+
004. #define def_NameHLine        m_Info.szPrefixName + "#HLINE"
005. #define def_NameBtnClose     m_Info.szPrefixName + "#CLOSE"
006. //+------------------------------------------------------------------+
007. #define def_PathBtns "Images\\Market Replay\\Orders\\"
008. #define def_Btn_Close def_PathBtns + "Btn_Close.bmp"
009. #resource "\\" + def_Btn_Close;
010. //+------------------------------------------------------------------+
011. #include "..\Auxiliar\C_Mouse.mqh"
012. //+------------------------------------------------------------------+
013. class C_ElementsTrade : private C_Mouse
014. {
015.     private    :
016. //+------------------------------------------------------------------+
017.         enum eObjects {LINE_PRICE, BTN_CLOSE, ELEM_NULL};
018. //+------------------------------------------------------------------+
019.         struct st00
020.         {
021.             ulong        ticket;
022.             string       szPrefixName;
023.             EnumEvents   ev;
024.             double       price;
025.             struct st01
026.             {
027.                 short xi, xf, yi, yf;
028.             }Positions[ELEM_NULL];
029.         }m_Info;
030. //+------------------------------------------------------------------+
031.         void UpdateViewPort(void)
032.         {
033.             int x, y;
034.             
035.             ChartTimePriceToXY(0, 0, 0, m_Info.price, x, y);
036.             ObjectSetDouble(0, def_NameHLine, OBJPROP_PRICE, m_Info.price);
037.             x = 130;
038.             m_Info.Positions[BTN_CLOSE].xi = (short)(x - 8);
039.             m_Info.Positions[BTN_CLOSE].xf = (short)(x + 8);
040.             m_Info.Positions[BTN_CLOSE].yi = (short)(y - 8);
041.             m_Info.Positions[BTN_CLOSE].yf = (short)(y + 8);
042.             ObjectSetInteger(0, def_NameBtnClose, OBJPROP_XDISTANCE, x);
043.             ObjectSetInteger(0, def_NameBtnClose, OBJPROP_YDISTANCE, y);
044.         }
045. //+------------------------------------------------------------------+
046.         eObjects CheckMousePosition(double &price)
047.             {
048.                 short x, y;
049.                 st_Mouse loc;
050.                 
051.                 loc = GetPositionsMouse();
052.                 price = loc.Position.Price;
053.                 x = loc.Position.X_Graphics;
054.                 y = loc.Position.Y_Graphics;
055.                 for (eObjects c0 = LINE_PRICE; c0 < ELEM_NULL; c0++)
056.                     if ((x > m_Info.Positions[c0].xi) && (x < m_Info.Positions[c0].xf) &&
057.                         (y > m_Info.Positions[c0].yi) && (y < m_Info.Positions[c0].yf)) return c0;
058.                 return ELEM_NULL;
059.             }
060. //+------------------------------------------------------------------+
061.     public    :
062. //+------------------------------------------------------------------+
063.         C_ElementsTrade(const ulong ticket, const EnumEvents ev, color _color, EnumPriority ePrio, string szDescr = "\n")
064.             :C_Mouse(0, "")
065.         {
066.             string szObj;
067.             
068.             ZeroMemory(m_Info);
069.             m_Info.szPrefixName = StringFormat("%I64u@%d", m_Info.ticket = ticket, (int)(m_Info.ev = ev));
070.             CreateObjectGraphics(szObj = def_NameHLine, OBJ_HLINE, _color, ePrio);
071.             ObjectSetInteger(0, szObj, OBJPROP_WIDTH, 2);
072.             ObjectSetString(0, szObj, OBJPROP_TEXT, szDescr);
073.             ObjectSetString(0, szObj, OBJPROP_TOOLTIP, szDescr);
074.             ObjectSetInteger(0, szObj, OBJPROP_SELECTABLE, ePrio != ePriorityNull);
075.             CreateObjectGraphics(szObj = def_NameBtnClose, OBJ_BITMAP_LABEL, clrNONE, (EnumPriority)(ePriorityOrders + 1));
076.             ObjectSetString(0, szObj, OBJPROP_BMPFILE, 0, "::" + def_Btn_Close);
077.             ObjectSetInteger(0, szObj, OBJPROP_ANCHOR, ANCHOR_CENTER);
078.         }
079. //+------------------------------------------------------------------+
080.         ~C_ElementsTrade()
081.         {
082.             if (m_Info.szPrefixName != "")
083.                 ObjectsDeleteAll(0, m_Info.szPrefixName);
084.         }
085. //+------------------------------------------------------------------+
086.         inline void UpdatePrice(const double price)
087.         {
088.             m_Info.price = price;
089.             UpdateViewPort();
090.         }
091. //+------------------------------------------------------------------+
092.         void DispatchMessage(const int id, const long &lparam, const double &dparam, const string &sparam)
093.         {
094.             double price;
095.             
096.             C_Mouse::DispatchMessage(id, lparam, dparam, sparam);
097.             switch (id)
098.             {
099.                 case CHARTEVENT_MOUSE_MOVE:
100.                     if (CheckClick(C_Mouse::eClickLeft)) switch(CheckMousePosition(price))
101.                     {
102.                         case LINE_PRICE:
103.                             break;
104.                         case BTN_CLOSE:
105.                             if (PositionSelectByTicket(m_Info.ticket)) switch (m_Info.ev)
106.                             {
107.                                 case evMsgClosePositionEA:
108.                                     EventChartCustom(0, evMsgClosePositionEA, m_Info.ticket, 0, "");
109.                                     break;
110.                                 case evMsgCloseTakeProfit:
111.                                     EventChartCustom(0, evMsgCloseTakeProfit, m_Info.ticket, PositionGetDouble(POSITION_SL), PositionGetString(POSITION_SYMBOL));
112.                                     break;
113.                                 case evMsgCloseStopLoss:
114.                                     EventChartCustom(0, evMsgCloseStopLoss, m_Info.ticket, PositionGetDouble(POSITION_TP), PositionGetString(POSITION_SYMBOL));
115.                                     break;
116.                             }
117.                             break;
118.                     }
119.                     break;
120.                 case CHARTEVENT_CHART_CHANGE:
121.                     UpdateViewPort();
122.                     break;
123.             }
124.         }
125. //+------------------------------------------------------------------+
126. };
127. //+------------------------------------------------------------------+
128. #undef def_Btn_Close
129. #undef def_PathBtns
130. //+------------------------------------------------------------------+
131. #undef def_NameBtnClose
132. #undef def_NameHLine
133. //+------------------------------------------------------------------+

C_ElementsTrade.mqh

このコードを見て、何も変わっていないと思うかもしれません。しかし、実はそうではありません。 コードの挙動は完全に変わっています。 ここでは、C_Terminalクラスではなく、C_Mouseクラスを使用している点に注目してください。 これは11行目でおこなわれます。 同様に、このクラスはC_Terminalを直接継承するのではなく、C_Mouseを継承しています。 このクラスはC_Mouseを継承しており、その結果、C_Terminalクラスも間接的に継承しています。 その結果、ポジション表示インジケータとのやり取りにマウスインジケータを使うようになります。 しかし、この目標を達成するには、前述の変更を単に実施するだけでは不十分です。 コードにはさらなる変更が必要です。 そこで、17行目に列挙型を追加しています。 この変更の目的は、これまでMetaTrader 5側でおこなわれていた処理を置き換えることです。 つまり、これからはコードをもう少し自由に制御できるようになるということです。

この置き換えに伴い、25行目で新しい構造体を宣言しています。 この構造体には4つの変数が含まれており、それらは27行目で宣言されています。 ただし、実際には、この構造体を使って各要素の座標を格納する配列を構成しており、28行目でその要素数をX個に指定しています。 この場合、要素は3つあります。 さて、それではこの配列に要素を追加しましょう。 これは、31行目で定義されている関数内でおこなわれます。 38行目から41行目では、閉じるボタンのマウスクリックを検出する位置、つまりクリック判定領域(クリックが検出される領域)を追加しています。 これらの行に現れる「8」という値は、ビットマップのサイズの半分を表しています。 念のため確認しておくと、ビットマップのサイズは16×16ピクセルです。 また、ビットマップは中央に配置されているため、このクリック判定領域を正しく設定する必要があります。 これで、閉じるボタンの位置がわかりました。

しかし、46行目に進む前に、クラスのコンストラクタを見てみましょう。 これは63行目に書かれています。 64行目では、C_Mouseクラスを初期化するようになっている点に注目してください。 以前は、C_Terminalクラスでした。 C_Mouseクラスをこの方法で初期化することで、Mouseオブジェクトを作成しないことを MetaTrader 5に伝えます。 チャート上にマウスインジケータが存在する場合に、それにアクセスできればよいのです。

それでは、46行目に戻って、そこで何が起きているのかを確認してみましょう。 この関数は一見とても複雑に見えますが、実際はそれほど複雑ではありません。 ここでは、51行目でマウスインジケータの位置を記録しているだけです。 その直後の52行目で、価格の値を格納しています。これは、まもなく説明する呼び出し元のコードにその値を返すためです。 しかし、ここで特に注目したいのは、以下の行です。 これらの行では、クリックされたオブジェクトを返すために、クリック判定領域を確認します。 オブジェクトが特定されなかった場合、58行目で呼び出し元に無効な値を返します。

それでは最後に、CheckMousePosition関数を呼び出すオブジェクトを見てみましょう。 具体的には、92行目にあるDispatchMessage関数のことです。 ここからが最も興味深い部分です。というのも、まず最初におこなうのは、C_Mouseクラスのイベントハンドラを呼び出すことだからです。 この呼び出しは96行目でおこなわれます。 その理由は、マウスインジケータからデータを取得する際にバッファリングシステムを使用していないため、データの正確性を確保する必要があるからです。 C_Mouseクラスでイベントを処理した後、マウスイベントであれば、コードの99行目が実行されます。

ここで注意してください。ここでのマウスイベントは、MQL5で一般的に使われるマウス処理の実装方法から想像されるものとは異なります。 ここでは、マウスのイベントがフィルタリングされ、異なる方法で処理されます。 これを理解するには、リプレイ/シミュレーションシステムに関するこの連載の過去の記事に戻り、マウスインジケータの実装方法を確認してみてください。 そこで、マウスインジケータを使用している際、一部のクリックイベントが無視される場合があることに気づくでしょう。 これは、このインジケータが分析用に設計されているためです。 この連載では、分析オブジェクトを設定せずにチャートを直接操作できる独自の分析モードを作成するために、インジケータを変更する方法を紹介しました。 マウスポインタがその操作をおこなってくれます。

したがって、100行目の条件判定が成立するのは、分析モードの使用中にクリックがおこなわれなかった場合だけです。 分析中に、このC_ElementsTradeクラスのコードが追跡しているオブジェクトを誤ってクリックしても、そのクリックは無視されます。 したがって、図形の描画をおこなっていない状態でチャートのどこかをクリックすると、条件判定が成立し、CheckMousePosition関数が呼び出されます。 ただし、ここで触れておくべき重要な点が一つあります。 この判定では、チャート上の表示順序、つまりZOrderプロパティの値は完全に無視されます。 つまり、注意が必要だということです。 ZOrderの値が小さいオブジェクトをクリックした場合でも、そのオブジェクトが優先される可能性があります。ここでの順序は、17行目の列挙型によって決まるためです。 また、2つのオブジェクトが異なるインジケータに属していても、クリック判定領域の位置が同じであれば、両方がこのイベントを受け取ります。 この場合、どちらのオブジェクトのZOrder値が大きいか、あるいはどちらが前面にあるかは関係ありません。 修正が提供されるまでは、この点にご注意ください。

これをおこなう方法については、後で見ていきます。 ただし、今のところは注意してください。 コードの説明に戻りましょう。CheckMousePosition関数の実行が完了すると、どのオブジェクトがクリックされたかが正確にわかります。 この時点で、これらのケースを区別します。 102行目では、LINE_PRICEオブジェクトがクリックされたときに特定のイベントが発生するよう、すでに指定し始めている点に注目してください。 104行目には、MetaTrader 5がこの処理をおこなっていたときとまったく同じコードを記述しました。 こうして、以前はMetaTrader 5プラットフォームによって制御されていた部分を、独自のコードで完全に置き換えることができました。

インジケータの残りのコードは変更されないため、ここでは記載する必要はありません。


まとめ

この記事では、次回の記事でさらに詳しく取り上げる予定の課題について触れました。 さて、締めくくる前に、EAのコードに施したちょっとした変更点をお見せしたいと思います。 目的は、ポジションが決済されたとき、つまり価格がストップロスラインまたはテイクプロフィットラインに達したときに、EAがイベントを発生させるようにすることです。 この調整をおこなわないと、ポジション表示インジケータは、自身をチャートから削除してよいという通知を受け取れません。 修正後のコードは以下の通りです。

001. //+------------------------------------------------------------------+
002. #property copyright "Daniel Jose"
003. #property icon "/Images/Market Replay/Icons/Replay - EA.ico"
004. #property description "Demo version between interaction"
005. #property description "of Chart Trade and Expert Advisor"
006. #property version   "1.121"
007. #property link "https://www.mql5.com/pt/articles/13265"
008. //+------------------------------------------------------------------+
009. #include <Market Replay\Order System\C_Orders.mqh>
010. #include <Market Replay\Auxiliar\C_Terminal.mqh>
011. //+------------------------------------------------------------------+
012. enum eTypeContract {MINI, FULL};
013. //+------------------------------------------------------------------+
014. input eTypeContract user00 = MINI;         //Cross order in contract
015. //+------------------------------------------------------------------+
016. C_Orders    *Orders;
017. C_Terminal  *Terminal;
018. //+------------------------------------------------------------------+
019. int OnInit()
020. {
021.     Terminal = NULL;
022.     Orders = new C_Orders(0xC0DEDAFE78514269);
023.     
024.     return INIT_SUCCEEDED;
025. }
026. //+------------------------------------------------------------------+
027. void OnTick() {}
028. //+------------------------------------------------------------------+
029. void OnChartEvent(const int id, const long &lparam, const double &dparam, const string &sparam)
030. {
031.     int handle;
032.     
033.     (*Orders).DispatchMessage(id, lparam, dparam, sparam);
034.     switch (id)
035.     {
036.         case CHARTEVENT_CHART_CHANGE:
037.             if (Terminal != NULL) break;
038.             else
039.             {
040.                 ulong ul;
041.                 Terminal = new C_Terminal(0, 0, user00);
042.                 for (int count = PositionsTotal() - 1; count >= 0; count--)
043.                 {
044.                     ul = PositionGetTicket(count);
045.                     if (PositionGetString(POSITION_SYMBOL) != (*Terminal).GetInfoTerminal().szSymbol)
046.                     {
047.                         ChartIndicatorDelete(0, 0, IntegerToString(ul));
048.                         continue;
049.                     }
050.                     handle = iCustom(NULL, PERIOD_CURRENT, "\\Indicators\\Position View.ex5", ul);
051.                     ChartIndicatorAdd(0, 0, handle);
052.                     IndicatorRelease(handle);
053.                 }
054.             }
055.         case CHARTEVENT_CUSTOM + evChartTrade_At_EA:
056.             EventChartCustom(0, evEA_At_ChartTrade, user00, 0, "");
057.             break;
058.     }
059. }
060. //+------------------------------------------------------------------+
061. void OnTradeTransaction(const MqlTradeTransaction &trans, const MqlTradeRequest &request, const MqlTradeResult &result)
062. {    
063.     static ulong ticket = 0;
064.     
065.     if (Terminal == NULL) return;
066.     switch (trans.type)
067.     {
068.         case TRADE_TRANSACTION_HISTORY_ADD:
069.             EventChartCustom(0, evUpdate_Position, trans.position, 0, "");
070.             ticket = (trans.order != trans.position ? trans.position : 0);
071.             break;
072.         case TRADE_TRANSACTION_REQUEST:
073.             if ((request.symbol == (*Terminal).GetInfoTerminal().szSymbol) && (result.retcode == TRADE_RETCODE_DONE)) switch (request.action)
074.             {
075.                 case TRADE_ACTION_DEAL:
076.                     if (ticket > 0) EventChartCustom(0, evUpdate_Position, ticket, 0, "");
077.                     else
078.                     {
079.                         int handle = iCustom(NULL, PERIOD_CURRENT, "\\Indicators\\Position View.ex5", result.order);
080.                         ChartIndicatorAdd(0, 0, handle);
081.                         IndicatorRelease(handle);
082.                     }
083.                     ticket = 0;
084.                     break;
085.                 case TRADE_ACTION_SLTP:
086.                     EventChartCustom(0, evUpdate_Position, request.position, 0, "");
087.                     break;
088.             }
089.             break;
090.     };
091. }
092. //+------------------------------------------------------------------+
093. void OnDeinit(const int reason)
094. {
095.     ulong ul;
096.     
097.     switch (reason)
098.     {
099.         case REASON_REMOVE:
100.         case REASON_INITFAILED:
101.             EventChartCustom(0, evEA_At_ChartTrade, -1, 0, "");
102.             break;
103.     }
104.     if (Terminal != NULL) for (int count = PositionsTotal() - 1; count >= 0; count--)
105.     {
106.         ul = PositionGetTicket(count);
107.         if (PositionGetString(POSITION_SYMBOL) != (*Terminal).GetInfoTerminal().szSymbol) continue;
108.         ChartIndicatorDelete(0, 0, IntegerToString(ul));
109.     }
110.     delete Orders;
111.     delete Terminal;
112. }
113. //+------------------------------------------------------------------+

Expert Advisor.mq5

この修正は、具体的にはコードに69行目を追加するというものです。 この行がないと、価格ラインのいずれかに到達してポジションが決済された際、更新イベントはトリガーされません。 また、少し補足すると、この記事を読んでいるだけでは気づきにくかったかもしれない点が一つあります。 これは、具体的にはストップロスラインとテイクプロフィットラインの移動に関することです。 「ポジション表示インジケータが作成したラインは、ドラッグすればすでに移動するのに、なぜわざわざこのような移動処理を実装するのか」と疑問に思う方もいるでしょうが、それはまったくもっともな疑問です。

しかし読者の皆さん、実際には必ずしもそうではありません。 実は、取引可能な銘柄を使用している場合、移動させているのはたいていMetaTrader 5が作成したラインです。 これから実装するのは、まさにMetaTrader 5が作成したラインが存在しない場合に、ラインを移動させる機能です。 あるいは、MetaTrader 5の設定で、これらのラインの移動が許可されていない場合です。

この設定がどこにあるかわからない場合は、以下の画像をご覧ください。

デフォルトでは、MetaTrader 5は上の画像に示されている設定を使用します。 ただし、次の画像のようにこの設定を変更すれば、このような動きは起こりません。

この状態では、チャート上の銘柄が取引できない銘柄であるかのように、MetaTrader 5を使用することになります。 つまり、これはリプレイ/シミュレーションで同じシステムやインジケータを使用する際に遭遇する典型的な状況です。 したがって、価格ラインの移動に関わるすべての処理を実装することが重要です。 問題は、これをおこなうべきかどうかではなく、単にどのように、いつおこなうかということです。 この連載記事を読んでいるものの、ソースコードをコンパイルできない方のために、修正済みの実行ファイルを添付しました。 次回の記事では、リプレイ/シミュレーションシステムの実装について、引き続きさらに詳しく解説していきます。

ファイル 説明
Experts\Expert Advisor.mq5
Chart TradeとEAの連携を示します(操作にはMouse Studyが必要)。
Indicators\Chart Trade.mq5 送信する注文を設定するためのウィンドウを作成します(操作にはMouse Studyが必要です)。
Indicators\Market Replay.mq5 リプレイ/シミュレーションサービスを操作するためのコントロールを作成します(操作にはMouse Studyが必要)。
Indicators\Mouse Study.mq5 グラフィカルコントロールとユーザーとのやり取りを可能にします(これは市場のリプレイ/シミュレーションシステムでも、実際の市場でも必要です)。
Indicators\Order Indicator.mq5 成行注文の生成と、その操作および管理を担当します。
Indicators\Position View.mq5 保有ポジションの検出と管理、およびやりとりと制御を担当します。
Services\Market Replay.mq5 市場のリプレイ/シミュレーションサービスを作成し、管理する、システム全体の中核となるファイルです。

MetaQuotes Ltdによりポルトガル語から翻訳されました。
元の記事: https://www.mql5.com/pt/articles/13265

添付されたファイル |
Anexo.zip (779.24 KB)
初級から中級まで:キュー、リスト、ツリー(I) 初級から中級まで:キュー、リスト、ツリー(I)
プログラミングをきちんと学びたいと真剣に考えている人にとって極めて重要な、いくつかの概念について、短い連載として解説していきます。 単純な要素に基づく内容ですが、最初は非常に複雑に感じられるかもしれないので、一歩ずつ解説していきます。 まず「キュー」とは何かを整理してみましょう。
GPT言語モデルに基づく自動売買ロボット GPT言語モデルに基づく自動売買ロボット
MetaTrader 5プラットフォーム上で金融時系列を予測するための、Transformerベースの専用アーキテクチャ「TimeGPT」の完全な実装を紹介します。 金融データへのAttention機構の適応、価格変化の選択的なトークン化、ハードウェアの特性を考慮した最適化、高度な学習手法について解説します。 CPUでの学習時間が15分で、24バーの予測対象期間において87%の予測正解率を達成したことを示す実際のテスト結果も掲載しています。 また、自動再学習機能を備えた、すぐに使える取引用エキスパートアドバイザー(EA)も紹介します。
取引におけるニューラルネットワーク:Adaptive Graph Diffusionモデル(最終回) 取引におけるニューラルネットワーク:Adaptive Graph Diffusionモデル(最終回)
MQL5を用いたSAGDFNフレームワークの構築に関する取り組みを締めくくり、開発プロセスを総括するとともに、実践的なテストの結果を報告します。 これまでに実装したモジュールを1つのシステムに統合し、このアプローチの長所を強調するとともに、その弱点を指摘し、改善策について検討してみましょう。
取引におけるニューラルネットワーク:Adaptive Graph Diffusionモデル(Attentionモジュール) 取引におけるニューラルネットワーク:Adaptive Graph Diffusionモデル(Attentionモジュール)
SAGDFNフレームワークの主要な構成要素の実装について、詳しく見ていきます。 時系列予測のために、Sparse Attentionと重要な近傍の選択をどのように構成するかを示します。 ここで紹介する手法は、予測精度と計算効率のバランスを取っています。