市場シミュレーション:MQL5でのSQL入門(II)
はじめに
リプリケーション/シミュレーションシステムの構築方法を解説する連載の次の記事へようこそ。
前回の「市場シミュレーション:MQL5でのSQL入門(I)」では、MQL5コードと併せてSQLの使用を開始しました。 多くの人は、SQLコードは他のコードに簡単に埋め込むことができると考えていますが、実際にはそうではないことがほとんどです。 SQLコードが文字列として実行ファイルに埋め込められるためです。 SQLコードを文字列として埋め込んでも、短いコード片であれば問題ありませんが、後々かなりの頭痛の種になる可能性があります。
これは、SQLコードを文字列に変換する際にタイプミスがあっても、そのことに気づかない可能性が高いからです。 文字列(つまりSQLコード)が正しいかどうかを目で確認するための、簡単で効果的な方法はありません。なぜなら、文字列内のコードにはシンタックスハイライトが適用されないからです。
こうした問題は、大きなストレスになりかねません。 私自身も、実行ファイル内でSQLコードが正しく動作しない理由を突き止めようとして、苦労したことがあります。 コードを注意深く確認したところ、SQLがテーブル間の適切な関連付けを確立できない原因となっていた、小さなタイプミスを見つけました。 原因を突き止めるだけでかなりの時間を無駄にしてしまい、ようやく原因が分かったときには、その時間をもっと有意義に使えたはずだと感じました。 それ以来、より複雑なコードを書く際には、まったく異なるアプローチを取るようになりました。
まさにそれがこの記事の目的です。すなわち、読者の皆様に、MQL5で作成された実行ファイルでSQLコードを使用する別の方法をご紹介することです。 MetaTrader 5で本格的にSQLを使用する予定である方は、今回ご紹介する手法をぜひ真剣に検討してみてください。この手法は、他のタスクにも応用できます。 非常に複雑なSQL操作を実行する予定がある場合は、実行ファイル内の文字列にコードを直接埋め込むことは避けてください。 どこかでエラーが発生する可能性は高く、その原因を突き止めるのに多くの時間を費やすことになるでしょう。 一方、コードが短くて単純なものであれば、心配する理由はないと思います。
SQLスクリプト入門
MQL5で記述された実行ファイル内でSQLスクリプトを使用するには、まずSQLの構文を理解する必要があります。 SQL文の構成を見てみると、どの文もセミコロン「;」で終わっていることがわかります。 このことから、完結したSQL文をそれぞれ区切るために、どの区切り文字を使えばよいかが見えてきます。
ここで注目すべき興味深い点があります。 通常、SQL文は複数行にわたって記述しますが、実際にはそれぞれが1つの長い行として扱われます。 文は行の先頭から始まり、セミコロンで終わります。 しかし、SQL文は非常に長くなる場合があるため、このように1行で記述すると読みにくいことがあります。 SQLの場合、これは問題になりません。SQLは常にその文を1行として扱います。 これだけで、私たちが何をすべきかはすでに明らかです。
次に取り組むべき課題は、コメントの処理です。 SQLスクリプトに多数のコメントが含まれていることは珍しくありません。ファイルの規模が大きい場合や、特に注意が必要な部分が含まれている場合には、こうしたコメントが非常に役立ちます。 インタープリタが処理しない部分まで送信して時間を無駄にしないよう、SQL文をSQLエンジンに送信する前に、これらのコメントを削除する必要があります。
2つのハイフン(--)で表される行コメントは、処理が簡単です。 一方、ブロックコメントでは、ブロック内にSQLがSQL文として解釈してしまう単語が含まれる可能性があるため、処理が複雑になることがあります。 まさにそれが避けたいことなので、このケースについては別途対応する必要があります。
もうひとつ欠点があります。 SQLは文字列もサポートしており、文字列の中にコメント区切り文字が含まれている場合でも、それらをコメントの開始や終了として解釈してはなりません。 このような場合には特別な処理が必要であり、プログラミングを学び始めたばかりの人は戸惑うかもしれません。 学びのプロセスを簡略化するため、コメントの処理については後回しにします。ひとまず、MQL5でおこなう作業を複雑にしないよう、SQLスクリプトにはコメントが含まれていないものと仮定します。
まずはここから始めましょう。前回の記事では、SQLを扱うためのクラスを作成しました。 このクラスはまだ開発の初期段階ですが、これを使ってスクリプトの処理を担当する別のクラスを作成することができます。 では、具体的にどうすればよいのでしょうか。 複雑に見えるかもしれませんが、私の記事をこれまで読んでくださっている方ならご存知の通り、私は常に可能な限りシンプルな解決策を提案するよう心がけており、今回も例外ではありません。 まず、SQLクラスをメインファイルから分離する必要があります。これは、以下に示す方法を使えば簡単に実行できます。
01. //+------------------------------------------------------------------+ 02. #property copyright "Daniel Jose" 03. //+------------------------------------------------------------------+ 04. class C_DB_SQLite 05. { 06. private : 07. int m_handleDB; 08. public : 09. //+------------------------------------------------------------------+ 10. C_DB_SQLite(const string szFileName) 11. :m_handleDB(INVALID_HANDLE) 12. { 13. if ((m_handleDB = DatabaseOpen(szFileName, DATABASE_OPEN_CREATE | DATABASE_OPEN_READWRITE)) == INVALID_HANDLE) 14. { 15. Print("Unable to create or open the file ", szFileName); 16. return; 17. } 18. } 19. //+------------------------------------------------------------------+ 20. ~C_DB_SQLite() 21. { 22. DatabaseClose(m_handleDB); 23. Print("Closing Database..."); 24. } 25. //+------------------------------------------------------------------+ 26. bool Command(const string szRequestSQL) 27. { 28. bool ret = (m_handleDB == INVALID_HANDLE ? false : DatabaseExecute(m_handleDB, szRequestSQL)); 29. Print("Request execution: ", (ret ? "Success" : "Failed"), "..."); 30. return ret; 31. } 32. //+------------------------------------------------------------------+ 33. }; 34. //+------------------------------------------------------------------+
C_DB_SQLite.mqhのソースコード
先ほどご覧になったコードは、メインファイル内にありました。 つまり、MQL5スクリプトからそのクラスに対応する部分を切り出し、C_DB_SQLite.mqhという名前のヘッダーファイルを作成して、Include\Market Replay\SQLフォルダに保存します。 これにより、今後SQLを扱う際に同じ原則を適用する必要があるスクリプトでも、このヘッダーファイルを利用できます。 この変更により、以前のMQL5スクリプトは以下のようになります。
01. //+------------------------------------------------------------------+ 02. #property copyright "Daniel Jose" 03. #property description "Basic script for SQL database written in MQL5" 04. #property version "1.00" 05. #property script_show_inputs 06. //+------------------------------------------------------------------+ 07. #include <Market Replay\SQL\C_DB_SQLite.mqh> 08. //+------------------------------------------------------------------+ 09. input string user01 = "DataBase01"; //FileName 10. //+------------------------------------------------------------------+ 11. void OnStart() 12. { 13. C_DB_SQLite *DB; 14. 15. DB = new C_DB_SQLite(user01 + ".sqlite"); 16. 17. (*DB).Command("PRAGMA FOREIGN_KEYS = ON;"); 18. (*DB).Command("CREATE TABLE IF NOT EXISTS tb_Symbols" 19. "(" 20. "id PRIMARY KEY," 21. "symbol NOT NULL UNIQUE" 22. ");"); 23. (*DB).Command("CREATE TABLE IF NOT EXISTS tb_Quotes" 24. "(" 25. "of_day NOT NULL," 26. "price NOT NULL," 27. "fk_id NOT NULL," 28. "FOREIGN KEY (fk_id) REFERENCES tb_Symbols(id)" 29. ");"); 30. delete DB; 31. } 32. //+------------------------------------------------------------------+
MQL5スクリプトのソースコード
07行目をご覧ください。ここに#includeディレクティブを追加しました。これにより、スクリプトはヘッダーファイル内のコードを、あたかもメインファイルに直接記述されているかのように利用できるようになります。 まさにその方法で、複数のヘッダーファイルを使ってプロジェクトを構成していきます。 また、この行で、先ほど述べたものとまったく同じファイルパスを指定している点にも注目してください。 MQL5ではデフォルトでそのディレクトリ内のヘッダーファイルを検索するため、Includeフォルダの名前を指定する必要はありませんでした。
ファイルは必ずしもその場所に置かれている必要はありませんが、混乱を避けるため、詳細については触れません。すべてを現状のままにしておくほうがよいでしょう。 些細なことのように思えるかもしれませんが、コードがコンパイルできないという人もいて、彼らが本当にすべてを理解できたのか確信が持てないまま、何度も説明しなければならなかったのです。
この例は非常に単純なので、ヘッダーファイルの仕組みを説明するためにこれを使っています。 当たり前の説明に思えたら申し訳ありませんが、この手順を皆さんに理解していただきたいのです。 記事にファイルを添付しないことにしたため、実際に取り組む皆さんには、コード全体を入手し、各ファイルを正しいパスに配置して最終的な実行ファイルを生成する方法を知っておいていただく必要があります。
SQLスクリプトを扱うために必要な基本的な構造はすでに整っており、それは別のファイルに保存されています。 ここで重要な点を1つ指摘しておきます。本来の構想ではSQLスクリプトを別のファイルに保存しますが、コンパイラディレクティブを使用することで、そのファイルをMQL5で生成される実行ファイルに埋め込むことができます。 これは、MQL5コード内にSQL文を文字列として埋め込むよりも、はるかにすっきりした解決策だと思います。 しかし、その実現方法を見る前に、MQL5コードからこのSQLスクリプトを利用できるように、スクリプトを処理する仕組みを用意しておきます。 まずは、以下に示すように新しいクラスを作成しましょう。
01. //+------------------------------------------------------------------+ 02. #property copyright "Daniel Jose" 03. //+------------------------------------------------------------------+ 04. #include "C_DB_SQLite.mqh" 05. //+------------------------------------------------------------------+ 06. class C_ScriptSQL : private C_DB_SQLite 07. { 08. private : 09. public : 10. //+------------------------------------------------------------------+ 11. C_ScriptSQL(const string szFileScript, const string szFileDataBase) 12. :C_DB_SQLite(szFileDataBase) 13. { 14. } 15. //+------------------------------------------------------------------+ 16. ~C_ScriptSQL() 17. { 18. } 19. //+------------------------------------------------------------------+ 20. bool Execute(void) 21. { 22. return false; 23. } 24. //+------------------------------------------------------------------+ 25. }; 26. //+------------------------------------------------------------------+
C_ScriptSQL.mqhファイルの初期コード
まずは、 冒頭で何が書かれているか見てみましょう。 04行目の#includeディレクティブに注目してください。 つまり、このヘッダーファイル(以下、C_ScriptSQLと呼びます)に、C_DB_SQLite.mqhファイルをインクルードすることになります。 さて、以下の点にご注意ください。 これは見落としやすい点ですが、非常に重要です。 C_DB_SQLite.mqhという名前はダブルクォートで囲まれています。 つまり、作成するC_ScriptSQLファイルは、C_DB_SQLite.mqhファイルと同じディレクトリに配置するということです。
MQL5やC/C++のコードで04行目のような構文を見たときは、現在のファイルを#includeで指定されたパスとの相対的な位置関係に基づいて検索または配置する必要があると理解してください。 つまり、#includeディレクティブでパスを指定するだけで、異なるフォルダ間を移動できるのです。 したがって、このC_ScriptSQL.mqhファイルは、C_DB_SQLite.mqhファイルと同じフォルダであるInclude\Market Replay\SQLフォルダに保存する必要があります。 このように配置すれば、コードはエラーなくコンパイルされます。
それでは、少し複雑に思えるかもしれない点をいくつか見ていきましょう。 06行目では、C_DB_SQLiteクラスを非公開継承するC_ScriptSQLクラスを宣言している点に注目してください。 このアプローチをとった理由は、後で明らかになるでしょう。 この継承のため、C_DB_SQLiteクラスを初期化するためのコンストラクタを定義する必要があります。 だからこそ、11行目ではC_ScriptSQLクラスのコンストラクタを宣言しているのです。 ここでは、コンストラクタが2つの引数を受け取ることに注意してください。 そこで、C_DB_SQLiteを初期化するために、12行目でそのコンストラクタに引数の1つを渡します。 もう一方のパラメータについては、後で使用します。
クラスの構造をあらかじめ整えておきたいので、16行目でそのデストラクタを宣言しています。 そして、20行目では、メインコードで使用するメソッドを宣言します。 ただし、このメソッドは値を返さなければならないため、22行目でfalseを返すようにしています。 つまり、コードが完成する前にテストをおこなう場合、値を返すはずのメソッドはすべて、必ずfalseを返すようにしておくのです。
では、このC_ScriptSQLクラスは、具体的に何をするのでしょうか。 このクラスは、SQLスクリプトファイルの名前とデータベースの名前を受け取り、そのデータベース上でスクリプトを実行することを想定しています。さらに、スクリプトがクエリを実行する場合には、何らかの値を返せるようにすることも考えています。 当面の目的は、MQL5のメインコード内にあるコードを取り除くことです。 MQL5スクリプトを調べると、このSQLコードを確認できます。
まだやるべきことが多いため、問題を個々のタスクに分解し、本当に必要なものが得られるまで、タスクを1つずつ解決する形で段階的に実装を進める必要があります。 したがって、まず最初におこなうべきことは、MQL5で記述されたメインコードからSQLスクリプトを抽出し、ディスク上のファイルに保存することです。 MQL5では、セキュリティ上の理由から、そのディレクトリ外のファイルへのアクセスが許可されていないため、アクセス可能で使いやすい場所にファイルを保存する必要があります。 簡単にするため、ファイルはMQL5\Filesディレクトリに置いておきます。 つまり、デフォルトでデータベースを保存するディレクトリと同じ場所です。 このようにして、ファイルを特定の名前で保存し、拡張子「.SQL」を付けて区別します。 こうして作成したファイルを以下に示します。
01. PRAGMA FOREIGN_KEYS = ON; 02. 03. CREATE TABLE IF NOT EXISTS tb_Symbols 04. ( 05. id PRIMARY KEY, 06. symbol NOT NULL UNIQUE 07. ); 08. 09. CREATE TABLE IF NOT EXISTS tb_Quotes 10. ( 11. of_day NOT NULL, 12. price NOT NULL, 13. fk_id NOT NULL, 14. FOREIGN KEY (fk_id) REFERENCES tb_Symbols(id) 15. );
SQLスクリプトのソースコード
次の画像では、ハイライト表示されたオブジェクトとその位置を示すマークを確認できます。

これで準備は万全です。 始めるために必要なものは、すでにすべて揃っています。 SQLスクリプトファイルに付けた名前を覚えておいてください。まもなくそれを使うことになります。 先ほど説明した点にご注意ください。SQLスクリプト内のすべてのSQL文は、セミコロンで終わります。 したがって、上記のSQLスクリプトが記述された通りに正確に実行されるよう、システムを実装します。 この段階では、コメントについては気にしなくて大丈夫です。ご覧の通り、SQLスクリプトにはコメントが含まれていないからです。 したがって、C_ScriptSQLファイルに記述すべきコードは以下の通りです。
01. //+------------------------------------------------------------------+ 02. #property copyright "Daniel Jose" 03. //+------------------------------------------------------------------+ 04. #include "C_DB_SQLite.mqh" 05. #include "..\Service Graphics\Support\C_Array.mqh" 06. //+------------------------------------------------------------------+ 07. class C_ScriptSQL : private C_DB_SQLite 08. { 09. private : 10. C_Array m_Arr; 11. char m_Buff[]; 12. int m_Size; 13. //+------------------------------------------------------------------+ 14. void Convert(void) 15. { 16. string sz0 = ""; 17. bool b0 = false, b1 = false; 18. int nLine = 1; 19. 20. for (int count = 0, nC0 = nLine; count < m_Size; count++) 21. { 22. switch (m_Buff[count]) 23. { 24. case '\t': 25. break; 26. case '\n': 27. nC0++; 28. case '\r': 29. break; 30. case ';': 31. b0 = true; 32. default: 33. if ((!b1) && (m_Buff[count] > ' ')) 34. { 35. b1 = true; 36. nLine = nC0; 37. } 38. sz0 += (b1 ? StringFormat("%c", m_Buff[count]) : ""); 39. } 40. if (b0) 41. { 42. m_Arr.Add(sz0, nLine); 43. sz0 = ""; 44. b0 = b1 = false; 45. } 46. } 47. } 48. //+------------------------------------------------------------------+ 49. public : 50. //+------------------------------------------------------------------+ 51. C_ScriptSQL(const string szFileScript, const string szFileDataBase) 52. :C_DB_SQLite(szFileDataBase), 53. m_Size(-1) 54. { 55. int handle; 56. 57. if ((handle = FileOpen(szFileScript, FILE_READ | FILE_BIN)) == INVALID_HANDLE) 58. { 59. Print("Unable to open script file: ", szFileScript); 60. return; 61. } 62. ArrayResize(m_Buff, m_Size = (int) FileSize(handle)); 63. FileReadArray(handle, m_Buff); 64. FileClose(handle); 65. Convert(); 66. } 67. //+------------------------------------------------------------------+ 68. ~C_ScriptSQL() 69. { 70. ArrayFree(m_Buff); 71. } 72. //+------------------------------------------------------------------+ 73. bool Execute(void) 74. { 75. int nLine; 76. string szInfo; 77. 78. for (int c = 0; c >= 0; c++) 79. { 80. szInfo = m_Arr.At(c, nLine); 81. if (nLine > 0) 82. Print(nLine, ">>", szInfo); 83. else break; 84. } 85. return false; 86. } 87. //+------------------------------------------------------------------+ 88. }; 89. //+------------------------------------------------------------------+
C_ScriptSQL.mqhのコード
コード量がすでにかなり増えていることに注意してください。 しかし、必要な機能のほとんどはすでに実装済みです。 とはいえ、ここでコードの内容を簡単に確認しておきましょう。 5行目で、ヘッダーファイルを使用する必要があることを指定しました。 このファイルは、リプレイ/シミュレーションシステムのソースコード内にすでに存在しています。 このヘッダーファイルは、本連載の過去の記事で探してください。 これまでの記事を読み進め、私が示した通りにコードを更新してきたのであれば、心配する必要はありません。必要な正しいファイルはすでに手元にあるはずだからです。
さて、10行目から12行目にかけて、このクラスのいくつかのprivate変数が確認できます。 一方、14行目には、m_Buffの内容を解析して文字列配列に分割するためのメソッドがあります。 このメソッドは、面倒な処理をすべて引き受けてくれるという点で、非常に興味深いものです。 基本的には、バッファを1文字ずつ順に処理しながら、SQL文の文字列を構築していきます。
いずれの場合も、システムは特定の文字が含まれているかどうかを確認しますので、ご注意ください。 24行目では、タブ文字があるかどうかを確認します。 現時点では、この文字は単に無視されます。 26行目で、改行文字があるかどうかを確認します。 この文字が検出されると、行カウンタがインクリメントされます。これは27行目で実行される処理です。 なお、28行目では、復帰文字があるかどうかを確認しています。
29行目では、復帰文字と改行文字の両方が同じように処理されます。 ただし、追加の処理で行カウンタをインクリメントするのは、改行文字の場合だけです。 SQLスクリプトの作成に使用しているエディタが改行文字を使用していない場合(これはかなり珍しいことですが)、行カウンタをインクリメントするには復帰文字を使用する必要があります。 いずれにせよ、それを変える必要はないと思います。
30行目では、SQL文の終わりを示すものとして想定していた文字が現れます。 なお、ここではSQL文が見つかったことを示すために変数を使用しています。 ただし、SQL文をSQLに送信する際にはこの文字も含める必要があるため、ブロックの最後にbreak文を記述しません。 したがって、実行はdefaultブロックへフォールスルーします。 このブロックは、これまで処理されていないすべての文字を処理します。 では、どのように処理されるか見てみましょう。
33行目では、スペース以外の文字が見つかったかどうかを確認します。 これは、SQL文の先頭にスペースが不要なためです。 スペース以外の文字が現れたら、35行目でそのことを示すフラグを設定し、その直後にSQL文が始まる行番号を記録します。
38行目では、バッファ内の現在の文字を文字列の末尾に追加しています。 ただし、注意すべき重要な点が1つあります。それは、SQL文の文字列には、すでに少なくとも1文字が含まれている場合にのみ、文字が追加されるということです。 そうでなければ、文字が現れるまで待機します。 最後に、40行目では、SQL文が完全に取得されたことが確認されると、そのSQL文が保存され、プロセスが再開されて次のSQL文が検索されます。
コンストラクタとデストラクタについては、コードがかなりわかりやすいので、特に説明する必要はないと思います。 ただし、コードの73行目には、説明が必要ないくつかの点があります。 それらを見てみましょう。 78行目には、かなり奇妙なforループが見られます。 これは、カウントがゼロから始まり、徐々に増えていくためです。 しかし、多くの人が思うような無限のものではありません。 変数の値が負になると、処理は終了します。 この変数は符号付き整数であるため、いずれ値が負になります。
しかし、その前に、80行目で、先ほど保存しておいたSQL文を取得することができます。 なお、81行目では、指定された行番号が負の数であるかどうかを確認しています。 この場合、83行目が実行され、78行目のループが終了します。 保存されているデータがあれば、82行目でログに記録します。 このような仕組みです。
なお、SQL文をターミナルに出力する代わりに、C_DB_SQLiteクラスに送信すれば、この時点でSQLスクリプトファイルに含まれるSQL文を実行することができます。 本当にとても便利です。 しかし、実際に動作を確認する前に、MQL5のメインコードが最終的にどのような形になったのかを見てみましょう。 以下をご覧ください。
01. //+------------------------------------------------------------------+ 02. #property copyright "Daniel Jose" 03. #property description "Basic script for SQL database written in MQL5" 04. #property version "1.00" 05. #property script_show_inputs 06. //+------------------------------------------------------------------+ 07. #include <Market Replay\SQL\C_ScriptSQL.mqh> 08. //+------------------------------------------------------------------+ 09. input string user01 = "DataBase01"; //Database File Name 10. input string user02 = "Script 01.sql"; //SQL Script File Name 11. //+------------------------------------------------------------------+ 12. void OnStart() 13. { 14. C_ScriptSQL *SQL; 15. 16. SQL = new C_ScriptSQL(user02, user01); 17. 18. (*SQL).Execute(); 19. 20. delete SQL; 21. } 22. //+------------------------------------------------------------------+
MQL5スクリプトのコード
このファイルをMetaTrader 5ターミナルで実行すると、次のような結果が得られます。

なお、出力には、SQL文が始まる行番号と、システムによって識別されたその文が表示されます。 つまり、必要なものはすでに揃っているため、SQL文をターミナルに出力する代わりに、C_DB_SQLiteクラスに送信することができます。 しかし、まずはSQLスクリプトファイル内のコメントをどのように扱うかを確認しておきましょう。 SQLでサポートされているコメントを処理するには、C_ScriptSQLクラスのConvertメソッドに戻り、いくつかの変更と追加をおこなう必要があります。
要するに、処理中の位置が文字列の内側にあるのか外側にあるのかを判断する必要があります。 一見すると、とてもシンプルに思えます。 しかし、SQLとなると、話は少し複雑になります。 SQLではシングルクォート「'」とダブルクォート「"」の両方が使用できるからです。 また、スクリプトが文字列の区切りにシングルクォートを使うのかダブルクォートを使うのか、確実に知る方法はありません。 したがって、両方のケースを考慮する必要があります。 ただ、それが最も難しい部分というわけではありません。実のところ、主な問題は別のところにあるのです。 とはいえ、目標を達成するためにコードがどのように変更されたのかを見てみましょう。 以下にコードを示します:
001. //+------------------------------------------------------------------+ 002. #property copyright "Daniel Jose" 003. //+------------------------------------------------------------------+ 004. #include "C_DB_SQLite.mqh" 005. #include "..\Service Graphics\Support\C_Array.mqh" 006. //+------------------------------------------------------------------+ 007. class C_ScriptSQL : private C_DB_SQLite 008. { 009. private : 010. C_Array m_Arr; 011. char m_Buff[]; 012. int m_Size; 013. //+------------------------------------------------------------------+ 014. void Convert(void) 015. { 016. string sz0 = ""; 017. bool b0, b1, bs1, bs2, bc0, bc1, bc; 018. int nLine = 1; 019. 020. b0 = b1 = bs1 = bs2 = bc0 = bc1 = bc = false; 021. for (int count = 0, nC0 = nLine; count < m_Size; count++) 022. { 023. switch (m_Buff[count]) 024. { 025. case '\t': 026. sz0 += (bs1 || bs2 ? "\t" : ""); 027. break; 028. case '\n': 029. nC0++; 030. case '\r': 031. bc0 = false; 032. break; 033. case ';': 034. b0 = (bs1 || bs2 || bc0 || bc1 ? b0 : true); 035. default: 036. switch (m_Buff[count]) 037. { 038. case '"': 039. bs1 = (bs2 || bc0 || bc1 ? bs1 : !bs1); 040. break; 041. case '\'': 042. bs2 = (bs1 || bc0 || bc1 ? bs2 : !bs2); 043. break; 044. } 045. if (((count + 1) < m_Size) && (!bs1) && (!bs2)) 046. { 047. if (bc = ((m_Buff[count] == '-') && (m_Buff[count + 1] == '-'))) bc0 = true; 048. if (bc = ((m_Buff[count] == '/') && (m_Buff[count + 1] == '*'))) bc1 = true; 049. if (bc = ((m_Buff[count] == '*') && (m_Buff[count + 1] == '/'))) bc1 = false; 050. if (bc) 051. { 052. count += 1; 053. bc = false; 054. continue; 055. } 056. } 057. if (!(bc0 || bc1)) 058. { 059. if ((!b1) && (m_Buff[count] > ' ')) 060. { 061. b1 = true; 062. nLine = nC0; 063. } 064. sz0 += (b1 ? StringFormat("%c", m_Buff[count]) : ""); 065. } 066. } 067. if (b0) 068. { 069. m_Arr.Add(sz0, nLine); 070. sz0 = ""; 071. b0 = b1 = false; 072. } 073. } 074. } 075. //+------------------------------------------------------------------+ 076. public : 077. //+------------------------------------------------------------------+ 078. C_ScriptSQL(const string szFileScript, const string szFileDataBase) 079. :C_DB_SQLite(szFileDataBase), 080. m_Size(-1) 081. { 082. int handle; 083. 084. if ((handle = FileOpen(szFileScript, FILE_READ | FILE_BIN)) == INVALID_HANDLE) 085. { 086. Print("Unable to open script file: ", szFileScript); 087. return; 088. } 089. ArrayResize(m_Buff, m_Size = (int) FileSize(handle)); 090. FileReadArray(handle, m_Buff); 091. FileClose(handle); 092. Convert(); 093. } 094. //+------------------------------------------------------------------+ 095. ~C_ScriptSQL() 096. { 097. ArrayFree(m_Buff); 098. } 099. //+------------------------------------------------------------------+ 100. bool Execute(void) 101. { 102. int nLine; 103. string szInfo; 104. 105. for (int c = 0; c >= 0; c++) 106. { 107. szInfo = m_Arr.At(c, nLine); 108. if (nLine > 0) 109. Print(nLine, ">>", szInfo); 110. else break; 111. } 112. return false; 113. } 114. //+------------------------------------------------------------------+ 115. }; 116. //+------------------------------------------------------------------+
C_ScriptSQL.mqhのソースコード
コードが以前よりもはるかに複雑になっている点に注目してください。 まさにそれが、先ほど仕組みについて説明した理由です。前のバージョンを理解していなければ、このコメント処理のコードを理解するのははるかに難しくなるでしょう。 ご注意ください。さらに多くの変数が追加されました。 また、以前は無視されていたタブ文字も、今後は常に無視されるわけではない点に注意してください。 タブ文字が無視されるのは、特定の場合、つまり文字列の外側にある場合だけです。 文字列内では、タブ文字は保持されます。
また、31行目に示す処理も追加する必要がありました。 ここでは、改行文字が検出されると、コメント内であることを示す値をリセットします。 セミコロンが見つかったときは、コメント内または文字列内かどうかをチェックする点に注意してください。 これは、SQL文が途中で打ち切られるのを防ぐために必要です。 また、36行目にswitch文を追加した点にもご留意ください。 これは引用符を処理するためのものです。 しかし、なぜこの処理をメインのコードに残しておかなかったのでしょうか。 その理由は、この処理をメインのコード内で実行した場合、SQLスクリプトの整合性を維持するために追加の作業が必要になってしまうということです。
しかし、読者の皆様にぜひ注目していただきたいのは、45行目のコードです。 ここから、SQLコード内のコメントのチェックを開始します。 各行では、コメントを特定する条件がチェックされます。 そして、これらすべてに共通する点が一つあります。それは、変数bcです。 この変数がtrueの場合、コメント内であり、すべての内容を無視すべきであることを示します。 さて、これがどう機能するのか見てみましょう。 47行目では、二重ハイフンをチェックしています。SQLでは、これは現在の行の末尾まで続くコメントを示すものです。 48行目では、ブロックコメントの開始箇所をチェックしています。 49行目では、ブロックコメントの終了を確認しています。
これらのチェックはいずれも非常に単純です。 ただし、文字列内では常にそれらを無視することに注意してください。 また、コメント内にある場合は、文字列の検出を無視します。 要するに、これによりスクリプトは、SQL文の一部ではないものはすべて読み込んで破棄するようになります。 コメントや文字列を含めたSQLスクリプトを作成してみてください。 MetaTrader 5でMQL5スクリプトのコードを実行し、すべてが期待通りに動作していることを確認してください。 C_ScriptSQLクラスのメソッドによってコードが正しく処理されていることを、細部まで注意深く確認してください。 これは、この解析が正常に完了すれば、100行目のコードを以下のコードに置き換えることができるためです。 その結果、SQLスクリプトはMetaTrader 5ターミナルに表示されるのではなく、実際に実行されることになります。 こうして、私たちは目標を達成しました。
099. //+------------------------------------------------------------------+ 100. bool Execute(void) 101. { 102. int nLine; 103. string szInfo; 104. 105. for (int c = 0; c >= 0; c++) 106. { 107. szInfo = m_Arr.At(c, nLine); 108. if (nLine < 0) return c > 0; 109. if (!this.Command(szInfo)) return false; 110. } 111. return false; 112. } 113. //+------------------------------------------------------------------+
C_ScriptSQL.mqhファイルからの抜粋
以下のコードを追加して、メインファイルも忘れずに更新してください。
01. //+------------------------------------------------------------------+ 02. #property copyright "Daniel Jose" 03. #property description "Basic script for SQL database written in MQL5" 04. #property version "1.00" 05. #property script_show_inputs 06. //+------------------------------------------------------------------+ 07. #include <Market Replay\SQL\C_ScriptSQL.mqh> 08. //+------------------------------------------------------------------+ 09. input string user01 = "DataBase01"; //Database File Name 10. input string user02 = "Script 01.sql"; //SQL Script File Name 11. //+------------------------------------------------------------------+ 12. void OnStart() 13. { 14. C_ScriptSQL *SQL; 15. 16. SQL = new C_ScriptSQL(user02, user01); 17. 18. Print("Result of executing the SQL script: ", (*SQL).Execute() ? "Success" : "Failed", "..."); 19. 20. delete SQL; 21. } 22. //+------------------------------------------------------------------+
MQL5スクリプトのソースコード
また、SQLスクリプトを使って多くのテストを実行したい場合は、以下のコードを使用して更新してください。
01. PRAGMA FOREIGN_KEYS = ON; 02. 03. DROP TABLE IF EXISTS tb_Symbols; 04. DROP TABLE IF EXISTS tb_Quotes; 05. 06. CREATE TABLE IF NOT EXISTS tb_Symbols 07. ( 08. id PRIMARY KEY, 09. symbol NOT NULL UNIQUE 10. ); 11. 12. CREATE TABLE IF NOT EXISTS tb_Quotes 13. ( 14. of_day NOT NULL, 15. price NOT NULL, 16. fk_id NOT NULL, 17. FOREIGN KEY (fk_id) REFERENCES tb_Symbols(id) 18. );
SQLiteのコード
まとめ
この記事では、MQL5とSQLの少しの知識があれば、スクリプトを使ってSQLコードを実行できることを紹介しました。 別の言い方をすれば、SQLコードが記述されたファイルを使用し、必要な情報を指定することで、そのSQLスクリプトファイルに含まれるコードをそのまま実行することができます。
実際、外部ファイルの使用を問題だと考える人は多いかもしれません。 クライアントに常にSQLファイルを提供しなければならないためです。 また、クライアントがSQLファイルに含まれるコードを改ざんしたり変更したりしないと信じる必要があります。 このような状況で、具体的にどう対処すべきかがわからなければ、確かに問題になります。 しかし、ここで紹介した内容を気に入ったものの、SQLを実行するコードを誰かに変更・改変されるのではないかと懸念している方も、心配はいりません。
このSQLコードを含むファイルを、MQL5で作成した実行ファイルに埋め込む方法がわからない場合は、次の記事をお見逃しなく。 次の記事でその方法をご紹介します。 さらに、MQL5からSQLを操作することに関連するトピックを、より幅広く取り上げていきます。
| ファイル | 説明 |
|---|---|
| Experts\Expert Advisor.mq5 | Chart TradeとEAの連携を示します(操作にはMouse Studyが必要)。 |
| Indicators\Chart Trade.mq5 | 送信する注文を設定するためのウィンドウを作成します(操作にはMouse Studyが必要)。 |
| Indicators\Market Replay.mq5 | リプレイ/シミュレーションサービスを操作するためのコントロールを作成します(操作にはMouse Studyが必要)。 |
| Indicators\Mouse Study.mq5 | グラフィカルなコントロールとユーザーとの対話を実現します。リプレイ/シミュレーションシステムと実際の市場の両方で必要です。 |
| Services\Market Replay.mq5 | 市場のリプレイ/シミュレーションサービスを作成し、管理する、システム全体の中核となるファイルです。 |
| Code VS C++\Servidor.cpp | C++で開発されたサーバーソケットを作成し、管理します(ミニチャット版)。 |
| Code in Python\Server.py | MetaTrader 5とExcelの間で通信するためのPythonソケットを作成し、管理します。 |
| Indicators\Mini Chat.mq5 | インジケータを通じてミニチャットを実装できるようにします(実行にはサーバーが必要)。 |
| Experts\Mini Chat.mq5 | EAを通じてミニチャットを実装できるようにします(実行にはサーバーが必要)。 |
| Scripts\SQLite.mq5 | MQL5でSQLスクリプトを使用する方法を実演します。 |
| Files\Script 01.sql | 外部キーを持つシンプルなテーブルの作成方法を示します。 |
| Files\Script 02.sql | テーブルへの値の追加方法を示します。 |
MetaQuotes Ltdによりポルトガル語から翻訳されました。
元の記事: https://www.mql5.com/pt/articles/13078
警告: これらの資料についてのすべての権利はMetaQuotes Ltd.が保有しています。これらの資料の全部または一部の複製や再プリントは禁じられています。
この記事はサイトのユーザーによって執筆されたものであり、著者の個人的な見解を反映しています。MetaQuotes Ltdは、提示された情報の正確性や、記載されているソリューション、戦略、または推奨事項の使用によって生じたいかなる結果についても責任を負いません。