DokumentationKategorien
Nachschlagewerk MQL5Marktinformation erhaltenSymbolSelect 

SymbolSelect

Wählt das Symbol im Fenster der Marktübersicht oder entfernt das Symbol aus dem Fenster.

bool  SymbolSelect(
   string  name,       // Symbolname
   bool    select      // hinzufügen oder entfernen 
   );

Parameter

name

[in]  Symbolname.

select

[in]  Schalter. Wenn der Wert false ist, muss das Symbol aus dem Fenster der Marktübersicht entfernt werden, anderenfalls muss das Symbol im Fenster Marktübersicht ausgewählt werden. Symbol kann nicht entfernt werden, wenn es für dieses Symbol offene Charts oder offene Positionen gibt.  

Rückgabewert

Im Fall des Misserfolges gibt die Funktion false zurück.

Beispiel:

#define SYMBOL_NAME "GBPHKD"
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Prüfung, ob ein Symbol in den Listen vorhanden ist, wenn nicht, dieses melden und die Arbeit beenden
   bool custom = false;
   if(!SymbolExist(SYMBOL_NAME, custom))
     {
      PrintFormat("'%s' symbol not found in the lists", SYMBOL_NAME);
      return;
     }
     
//--- ein Symbol zum Fenster der Marktübersicht hinzufügen
   ResetLastError();
   if(!SymbolSelect(SYMBOL_NAME, true))
     {
      Print("SymbolSelect() failed. Error ", GetLastError());
      return;
     }
//--- wenn ein Symbol erfolgreich zur Liste hinzugefügt wurde, rufen wir seinen Index im Fenster der Marktübersicht ab und senden das Ergebnis an das Journal senden
   int index = SymbolIndex(SYMBOL_NAME);
   PrintFormat("The '%s' symbol has been added to the MarketWatch list. Symbol index in the list: %d", SYMBOL_NAME, index);
     
//--- jetzt wird das Symbol aus dem Fenster der Marktübersicht entfernt
   ResetLastError();
   if(!SymbolSelect(SYMBOL_NAME, false))
     {
      Print("SymbolSelect() failed. Error ", GetLastError());
      return;
     }
//--- wenn ein Symbol erfolgreich aus der Liste entfernt wurde, ist sein Index im Fenster der Marktübersicht -1, wir senden das Ergebnis der Löschung an das Journal
   index = SymbolIndex(SYMBOL_NAME);
   PrintFormat("The '%s' symbol has been removed from the MarketWatch list. Symbol index in the list: %d", SYMBOL_NAME, index);
   
   /*
  Ergebnis:
   The 'GBPHKD' symbol has been added to the MarketWatch list. Symbol index in the list: 12
   The 'GBPHKD' symbol has been removed from the MarketWatch list. Symbol index in the list: -1
   */
  }
//+------------------------------------------------------------------+
//| Return the symbol index in the Market Watch symbol list          |
//+------------------------------------------------------------------+
int SymbolIndex(const string symbol)
  {
   int total = SymbolsTotal(true);
   for(int i=0; i<total; i++)
     {
      string name = SymbolName(i, true);
      if(name == symbol)
         return i;
     }
   return(WRONG_VALUE);
  }