DokümantasyonBölümler
MQL5 ReferansıMatematik FonksiyonlarıMathMin 

MathMin

Fonksiyon, iki değer arasındaki en küçük değere dönüş yapar.

double  MathMin(
   double  value1,     // ilk değer
   double  value2      // ikinci değer
   );

Parametreler

value1

[in]  İlk sayısal değer.

value2

[in]  İkinci sayısal değer.

Dönüş değeri

İki değer arasında en büyük olana dönüş yapar.

Not

MathMin() fonksiyonunun yerine fmin() kullanabilirsiniz. fmax(), fmin(), MathMax(), MathMin() fonksiyonları, double tip dönüşümü yapılmaksızın tamsayı tipleriyle de kullanılabilir.

Fonksiyon farklı tiplerde parametreler ile kullanıldığında, daha küçük tipli parametre, otomatik olarak büyük tipe dönüştürülür. Dönüş değerinin tipi büyük tipe karşılık gelir.

Aynı tipteki veriler için dönüşüm gerçekleştirilmez.

 

Örnek:

//--- girdi parametreleri
input uint  InpBars  =  100000;  // İstenen çubuk sayısı
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- sunucudaki mevcut çubuk sayısını al
   uint bars_total = Bars(Symbol(),Period());
   if(bars_total==0)
     {
      PrintFormat("Data for timeseries %s %s not yet generated in the terminal. Please try again later.",Symbol(),StringSubstr(EnumToString(Period()),7));
      return;
     }
//--- minimum çubuk sayısını şu iki değerden al - sunucuda mevcut olan ve ayarlarda istenen sayı
   int bars = (int)MathMin(bars_total,InpBars);
//--- sunucuda mevcut olandan daha fazla çubuk talep edilirse, bunu günlükte bildir
   if(bars_total<InpBars)
      PrintFormat("Number of bars on the server (%u) is less than requested (%u)",bars_total,InpBars);
//--- çalışma için mevcut çubuk sayısını günlükte görüntüle
   Print("Bars available for work: ",bars);
  }