DocumentaçãoSeções
Referência MQL5Indicadores CustomizadosPlotIndexGetInteger 

PlotIndexGetInteger

A função define o valor da propriedade correspondente da linha do indicador correspondente. A propriedade do indicador deve ser do tipo int, color, bool ou char. Existem 2 variantes da função.

Chamar indicando o identificador da propriedade.

int  PlotIndexGetInteger(
   int  plot_index,        // plotagem do índice do estilo
   int  prop_id,           // propriedade identificador
   );

Chamar indicando o identificador e o modificador da propriedade.

int  PlotIndexGetInteger(
   int  plot_index,        // plotagem do índice
   int  prop_id,           // propriedade identificador
   int  prop_modifier      // propriedade modificador
   )

Parâmetros

plot_index

[in]  Índice de plotagem gráfica

prop_id

[in] O valor pode ser um dos valores do enumerador ENUM_PLOT_PROPERTY_INTEGER.

prop_modifier

[in]  Modificador da propriedade específica. Propriedades de índice de cor apenas requerem um modificador.

Observação

Função é projetado para extrair as configurações do desenho da linha da indicador apropriada. A função trabalha em conjunto com a função PlotIndexSetInteger para copiar as propriedades de desenho de uma linha para outra.

Exemplo: um indicador que colore as velas dependendo do dia da semana. Cores para cada dia são criados de uma maneira programada.

Candlesticks coloridos de acordo com o número de dias da semana

 

#property indicator_separate_window
#property indicator_buffers 5
#property indicator_plots   1
//---- plotar ColorCandles
#property indicator_label1  "ColorCandles"
#property indicator_type1   DRAW_COLOR_CANDLES
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- buffers do indicador
double         OpenBuffer[];
double         HighBuffer[];
double         LowBuffer[];
double         CloseBuffer[];
double         ColorCandlesColors[];
color          ColorOfDay[6]={CLR_NONE,clrMediumSlateBlue,
                              clrDarkGoldenrod,clrForestGreen,clrBlueViolet,clrRed};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,OpenBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,HighBuffer,INDICATOR_DATA);
   SetIndexBuffer(2,LowBuffer,INDICATOR_DATA);
   SetIndexBuffer(3,CloseBuffer,INDICATOR_DATA);
   SetIndexBuffer(4,ColorCandlesColors,INDICATOR_COLOR_INDEX);
//--- definir o número de cores em buffer de cor
   PlotIndexSetInteger(0,PLOT_COLOR_INDEXES,6);
//--- definir cores para o buffer de cores
   for(int i=1;i<6;i++)
      PlotIndexSetInteger(0,PLOT_LINE_COLOR,i,ColorOfDay[i]);
//--- define acuracidade
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
   printf("We have %u colors of days",PlotIndexGetInteger(0,PLOT_COLOR_INDEXES));
//---
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   int i;
   MqlDateTime t;
//----
   if(prev_calculated==0) i=0;
   else i=prev_calculated-1;
//----
   while(i<rates_total)
     {
      OpenBuffer[i]=open[i];
      HighBuffer[i]=high[i];
      LowBuffer[i]=low[i];
      CloseBuffer[i]=close[i];
      //--- definir a cor de cada vela
      TimeToStruct(time[i],t);
      ColorCandlesColors[i]=t.day_of_week;
      //---
      i++;
     }
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }
//+------------------------------------------------------------------+