CalendarCountryById

Obtiene la descripción del país según su identificador.

bool  CalendarCountryById(
   const long           country_id,     // identificador del país
   MqlCalendarCountry&  country         // variable para obtener la descripción del país
   );

Parámetros

country_id

[in]  Identificador del país según el estándar ISO 3166-1.

country

[out]  Variable del tipo MqlCalendarCountry para obtener la descripción del país.

Valor retornado

Retorna true en el caso de éxito, de lo contrario, false. Para obtener información sobre el error, necesitamos llamar la función GetLastError(). Posibles errores:

  • 4001 — ERR_INTERNAL_ERROR  (error general del sistema de ejecución),
  • 5402 — ERR_CALENDAR_NO_DATA (el país no ha sido encontrado),
  • 5401 — ERR_CALENDAR_TIMEOUT (se ha superado el límite de solicitud por tiempo).

Ejemplo:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- obtenemos la lista de países del Calendario Económico
   MqlCalendarCountry countries[];
   int count=CalendarCountries(countries);
//--- comprobamos el resultado
   if(count==0)
      PrintFormat("CalendarCountries() returned 0! Error %d",GetLastError());
//--- si tenemos dos o más países
   if(count>=2)
     {
      MqlCalendarCountry country;
      //--- ahora obtenemos la descripción del país según su identificador 
      if(CalendarCountryById(countries[1].id, country))
        {
         //--- preparamos la descripción del país
         string descr="id = "+IntegerToString(country.id)+"\n";
         descr+=("name = " + country.name+"\n");
         descr+=("code = " + country.code+"\n");
         descr+=("currency = " + country.currency+"\n");
         descr+=("currency_symbol = " + country.currency_symbol+"\n");
         descr+=("url_name = " + country.url_name);         
         //---mostramos la descripción del país
         Print(descr);
        }
      else
         Print("CalendarCountryById() failed. Error ",GetLastError());
     }
//---
  }
/*
  Resultado:
   id = 999
   name = European Union
   code = EU
   currency = EUR
   currency_symbol = €
   url_name = european-union
*/

Ver también

CalendarCountries, CalendarEventByCountry