DocumentationSections
Référence MQL5Calendrier EconomiqueCalendarCountryById 

CalendarCountryById

Retourne la description d'un pays par son identifiant.

bool  CalendarCountryById(
   const long           country_id,     // identifiant du pays
   MqlCalendarCountry&  country         // variable pour récupérer la description du pays
   );

Paramètres

country_id

[in]  Identifiant du pays (ISO 3166-1).

country

[out]  Variable de type MqlCalendarCountry pour retourner la description du pays.

Valeur de Retour

Retourne true en cas de succès, sinon retourne false. Pour obtenir des informations sur une erreur, appelez la fonction GetLastError(). Erreurs possibles :

  • 4001 — ERR_INTERNAL_ERROR  (erreur générale d'exécution),
  • 5402 — ERR_CALENDAR_NO_DATA (pays non trouvé),
  • 5401 — ERR_CALENDAR_TIMEOUT (limite de temps de traitement de la requête atteinte).

Exemple :

//+------------------------------------------------------------------+
//| Fonction de lancement du programme                               |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- obtient la liste des pays du calendrier économique
   MqlCalendarCountry countries[];
   int count=CalendarCountries(countries);
//--- vérifie le résultat
   if(count==0)
      PrintFormat("CalendarCountries() a retourné 0 ! Error %d",GetLastError());
//--- s'il y a plus de 2 pays
   if(count>=2)
     {
      MqlCalendarCountry country;
      //--- obtient maintenant la description du pays par son identifiant
      if(CalendarCountryById(countries[1].id, country))
        {
         //--- prépare la description du pays
         string descr="id = "+IntegerToString(country.id)+"\n";
         descr+=("nom = " + country.name+"\n");
         descr+=("code = " + country.code+"\n");
         descr+=("devise = " + country.currency+"\n");
         descr+=("symbol_devise = " + country.currency_symbol+"\n");
         descr+=("nom_url = " + country.url_name);         
         //--- affiche la description du pays
         Print(descr);
        }
      else
         Print("Echec de CalendarCountryById(). Erreur ",GetLastError());
     }
//---
  }
/*
  Résultat :
   id = 999
   nom = European Union
   code = EU
  devise = EUR
  symbole_devise = €
   nom_url = european-union
*/

Voir aussi

CalendarCountries, CalendarEventByCountry